C_PaymentRequestSupplierVH

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.dataCategory: #VALUE_HELP

@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@Consumption.ranked: true
@EndUserText.label: 'Supplier Value Help for Payment Request'
define view entity C_PaymentRequestSupplierVH
  as select from I_Supplier

{
        @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }
  key   cast(I_Supplier.Supplier as farp_supplier_id)                                       as Supplier,
        @Search: { defaultSearchElement: true, ranking: #LOW }
  key   _SupplierCompany.CompanyCode,
  key   case
          when _SupplierBankDetails._BusinessPartnerBankAlias.BPBankAccountAliasName <> '' then ''
          else _SupplierBankDetails.BankCountry
        end                                                                                 as BankCountry,
  key   case
          when _SupplierBankDetails._BusinessPartnerBankAlias.BPBankAccountAliasName <> '' then ''
          else _SupplierBankDetails.Bank
        end                                                                                 as Bank,
        @UI.hidden: true
  key   _SupplierBankDetails.BankAccount,
        cast(
        case
          when _SupplierBankDetails.BankAccount like '<IBAN>____________' then ''
          when _SupplierBankDetails._BusinessPartnerBankAlias.BPBankAccountAliasName <> '' then ''
          else _SupplierBankDetails.BankAccount
        end as bankn)                                                                       as PayeeBankAccount,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        _SupplierBankDetails.BankDetailReference,

        SupplierName,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        VATRegistration,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        TaxJurisdiction,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        Industry,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        TaxNumber1,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        TaxNumber2,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        CityName,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        PostalCode,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        StreetName,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        Country,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        PhoneNumber1,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        PhoneNumber2,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        FaxNumber,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        TaxNumberType,

        cast(_SupplierBankDetails.BPBankAccountInternalID as farp_bvtyp)                    as BPBankAccountInternalID,

        @Search: { defaultSearchElement: true, ranking: #LOW }
        cast(_SupplierToBusinessPartner._BusinessPartner.SearchTerm1 as fap_ffp_searchterm) as SearchTerm1,

        @Search: { defaultSearchElement: true, ranking: #LOW }
        _SupplierBankDetails._BusinessPartnerBankAlias.PaymentSystem,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        _SupplierBankDetails._BusinessPartnerBankAlias.AliasType,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        _SupplierBankDetails._BusinessPartnerBankAlias.BPBankAccountAliasName,

        @UI.hidden: true
        SupplierLanguage,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        SupplierAccountGroup,

        @UI.hidden: true
        AuthorizationGroup,

        @UI.hidden: true
        IsBusinessPurposeCompleted,
        // Fields added For Data Controller in DCL .... NOT TO BE CONSUMED.

        @UI.hidden: true
        @Consumption.filter.hidden: true
        DataControllerSet,
        @UI.hidden: true
        @Consumption.filter.hidden: true
        DataController1,
        @UI.hidden: true
        @Consumption.filter.hidden: true
        DataController2,
        @UI.hidden: true
        @Consumption.filter.hidden: true
        DataController3,
        @UI.hidden: true
        @Consumption.filter.hidden: true
        DataController4,
        @UI.hidden: true
        @Consumption.filter.hidden: true
        DataController5,
        @UI.hidden: true
        @Consumption.filter.hidden: true
        DataController6,
        @UI.hidden: true
        @Consumption.filter.hidden: true
        DataController7,
        @UI.hidden: true
        @Consumption.filter.hidden: true
        DataController8,
        @UI.hidden: true
        @Consumption.filter.hidden: true
        DataController9,
        @UI.hidden: true
        @Consumption.filter.hidden: true
        DataController10,

        @Search: { defaultSearchElement: true, ranking: #LOW }
        _SupplierBankDetails.BankControlKey,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        _SupplierBankDetails._IBAN.IBAN,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        _SupplierBankDetails.BankAccountHolderName,
        @Search: { defaultSearchElement: true, ranking: #LOW }
        PaymentReason
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERBANKALIAS",
"I_IBAN",
"I_SUPPLIER",
"I_SUPPLIERBANKDETAILS",
"I_SUPPLIERCOMPANY",
"I_SUPPLIERTOBUSINESSPARTNER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/