C_PaymentCard

@AbapCatalog.sqlViewName: 'CPAYCARD'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Consumption view for payment cards'

@Metadata.allowExtensions: true

@ObjectModel.type: #CONSUMPTION
@ObjectModel.writeEnabled: true
@ObjectModel.transactionalProcessingDelegated: true
@ObjectModel: {
    semanticKey: ['BusinessPartner','PaymentCardTypeForEdit','PaymentCardID','CardNumberForEdit' ],
    createEnabled,
    updateEnabled,
    deleteEnabled
}
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

@UI.headerInfo:{
  typeName: 'Payment Card',
  typeNamePlural: 'Payment Cards'}
  
@VDM.viewType: #CONSUMPTION

define view C_PaymentCard
  as select from I_PaymentCardTP as PaymentCard

  association [1..1] to C_BusinessPartnerCustomer as _BusinessPartnerCustomer on  $projection.BusinessPartner = _BusinessPartnerCustomer.BusinessPartner
  association [1..1] to C_BusinessPartner as _BusinessPartner on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [1..1] to C_PaymentCardMaster       as _CardDetails             on  $projection.PaymentCardType = _CardDetails.PaymentCardType
                                                                              and $projection.CardNumber      = _CardDetails.PaymentCardNumber
  association [1..1] to I_PaymentCardTypeText     as _PaymentCardTypeText     on  $projection.PaymentCardType   = _PaymentCardTypeText.PaymentCardType
                                                                              and _PaymentCardTypeText.Language = $session.system_language
                                                                              
{           
  key      PaymentCard.BusinessPartner,
  key      PaymentCard.PaymentCardID,
           @ObjectModel.readOnly: true
           @ObjectModel.text.association: '_PaymentCardTypeText'
  key      PaymentCard.PaymentCardType,
  key      PaymentCard.CardNumber,
           @ObjectModel.foreignKey.association: '_CardDetails'           
           PaymentCard.PaymentCardTypeForEdit,           
           @ObjectModel.foreignKey.association: '_CardDetails'           
           PaymentCard.CardNumberForEdit, 
           PaymentCard.PaymentCardIDForEdit,
           PaymentCard.CardDescription,
           PaymentCard.IsStandardCard,
           PaymentCard.AuthorizationGroup,
           PaymentCard.CollectionIsAuthorized,
           @ObjectModel.readOnly: true
           @ObjectModel.createEnabled: false
           _CardDetails.MaskedCardNumber,
           @ObjectModel.readOnly: true
           _CardDetails.CardHolder,
           
           @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT  ]
           _BusinessPartnerCustomer,
           @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT  ]
           _BusinessPartner,
           @ObjectModel.association.draft.enabled:true
           @ObjectModel.association.draft.fieldNamePrefix:'CARDDETAILS'
           _CardDetails,
           _PaymentCardTypeText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_PAYMENTCARDMASTER",
"I_PAYMENTCARDTP"
],
"ASSOCIATED":
[
"C_BUSINESSPARTNER",
"C_BUSINESSPARTNERCUSTOMER",
"C_PAYMENTCARDMASTER",
"I_PAYMENTCARDTYPETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/