C_PartnerFuncBySalesDocTypeVH

DDL: C_PARTNERFUNCBYSALESDOCTYPEVH Type: view CONSUMPTION

Partner Function By Sales Doc Type

C_PartnerFuncBySalesDocTypeVH is a Consumption CDS View that provides data about "Partner Function By Sales Doc Type" in SAP S/4HANA. It reads from 2 data sources (I_PartFuncByPartDetnProced, I_SalesDocumentType) and exposes 5 fields with key fields SalesDocumentType, PartnerDeterminationProcedure, PartnerFunction. It has 3 associations to related views.

2 data source(s) 5 fields

Data Sources (2)

SourceAliasJoin Type
I_PartFuncByPartDetnProced PartFuncByPartDetnProced inner
I_SalesDocumentType SalesDocumentType from

Associations (3)

CardinalityTargetAliasCondition
[0..1] C_PartnerFunctionUnconverted _PartnerFunction $projection.PartnerFunction = _PartnerFunction.PartnerFunction
[0..1] I_AdvncdRetsMgmtSttgAtClient _ThirdPartySupplier $projection.PartnerFunction = _ThirdPartySupplier.ThirdPtySuplrPartnerFunction
[0..1] I_AdvncdRetsMgmtSttgAtClient _ThirdPartyReturnTo $projection.PartnerFunction = _ThirdPartyReturnTo.ThirdPtyRetToPartnerFunction

Annotations (17)

NameValueLevelField
AbapCatalog.sqlViewName CPRTFNCSDOCTYPVH view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
ClientHandling.algorithm #SESSION_VARIABLE view
VDM.viewType #CONSUMPTION view
Search.searchable true view
Consumption.valueHelpDefault.fetchValues #AUTOMATICALLY_WHEN_DISPLAYED view
Consumption.ranked true view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.resultSet.sizeCategory #XS view
AccessControl.authorizationCheck #NOT_REQUIRED view
ObjectModel.representativeKey PartnerFunction view
Metadata.ignorePropagatedAnnotations true view
EndUserText.label Partner Function By Sales Doc Type view

Fields (5)

KeyFieldSource TableSource FieldDescription
KEY SalesDocumentType I_SalesDocumentType SalesDocumentType
KEY PartnerDeterminationProcedure I_PartFuncByPartDetnProced PartnerDeterminationProcedure
KEY PartnerFunction I_PartFuncByPartDetnProced PartnerFunction
PartnerFunctionName
_PartnerDeterminationProcedure I_PartFuncByPartDetnProced _PartnerDeterminationProcedure 
@AbapCatalog: {
  sqlViewName:'CPRTFNCSDOCTYPVH',
  compiler.compareFilter: true,
  preserveKey: true
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION

@Search: {
  searchable: true
}

@Consumption: {
  valueHelpDefault.fetchValues:#AUTOMATICALLY_WHEN_DISPLAYED,
  ranked: true
}

@ObjectModel:{
  usageType:{
    dataClass: #CUSTOMIZING,
    serviceQuality: #C,
    sizeCategory: #XL
  },
  dataCategory: #VALUE_HELP,
  resultSet.sizeCategory: #XS
}

@AccessControl.authorizationCheck: #NOT_REQUIRED

@ObjectModel.representativeKey: 'PartnerFunction'

@Metadata.ignorePropagatedAnnotations: true

@UI.presentationVariant:[{
  sortOrder: [{ by: 'PartnerFunctionName' , direction: #ASC } ]
}]

@EndUserText.label: 'Partner Function By Sales Doc Type'
define view C_PartnerFuncBySalesDocTypeVH 
  as select from I_SalesDocumentType        as SalesDocumentType
  inner join     I_PartFuncByPartDetnProced as PartFuncByPartDetnProced on SalesDocumentType.PartnerDeterminationProcedure = PartFuncByPartDetnProced.PartnerDeterminationProcedure

  association [0..1] to C_PartnerFunctionUnconverted   as _PartnerFunction    on $projection.PartnerFunction = _PartnerFunction.PartnerFunction
  
  association [0..1] to I_AdvncdRetsMgmtSttgAtClient   as _ThirdPartySupplier on $projection.PartnerFunction = _ThirdPartySupplier.ThirdPtySuplrPartnerFunction
  
  association [0..1] to I_AdvncdRetsMgmtSttgAtClient   as _ThirdPartyReturnTo on $projection.PartnerFunction = _ThirdPartyReturnTo.ThirdPtyRetToPartnerFunction
  
{ 
  
      @UI.hidden: true
  key SalesDocumentType.SalesDocumentType,
  
      @UI.hidden: true
      @ObjectModel.foreignKey.association: '_PartnerDeterminationProcedure'
  key PartFuncByPartDetnProced.PartnerDeterminationProcedure,
  
      @ObjectModel.text.element: ['PartnerFunctionName']
      @UI.textArrangement: #TEXT_ONLY
      @Search: {
       defaultSearchElement: true,
       ranking: #HIGH,
       fuzzinessThreshold: 0.9
      }
  key PartFuncByPartDetnProced.PartnerFunction,
      
      @Semantics.text:true
      @Search: {
       defaultSearchElement: true,
       ranking: #LOW,
       fuzzinessThreshold: 0.9
      }
      _PartnerFunction._Text[1: Language=$session.system_language].PartnerFunctionName,
      
      @Consumption.filter.hidden: true
      PartFuncByPartDetnProced._PartnerDeterminationProcedure
      
} where
  PartFuncByPartDetnProced.PartnerIsNotChangeable    is initial and 
  _ThirdPartySupplier.ReturnToAddressPartnerFunction is null    and
  _ThirdPartyReturnTo.ReturnToAddressPartnerFunction is null
  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_PARTNERFUNCTIONUNCONVERTED",
"I_ADVNCDRETSMGMTSTTGATCLIENT",
"I_PARTFUNCBYPARTDETNPROCED",
"I_PARTNERFUNCTIONTEXT",
"I_SALESDOCUMENTTYPE"
],
"ASSOCIATED":
[
"C_PARTNERFUNCTIONUNCONVERTED",
"I_ADVNCDRETSMGMTSTTGATCLIENT",
"I_PARTDETERMINATIONPROCEDURE"
],
"BASE":
[
"I_PARTFUNCBYPARTDETNPROCED"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More