C_PartnerFuncBySalesDocCatVH

@AbapCatalog: {
  sqlViewName:'CPRTFNCSDOCCATVH',
  compiler.compareFilter: true,
  preserveKey: true
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION

@Search: {
  searchable: true
}

@ObjectModel:{
  usageType:{
    dataClass: #CUSTOMIZING,
    serviceQuality: #B,
    sizeCategory: #L
  },
  dataCategory: #VALUE_HELP
  //,

  //resultSet.sizeCategory: #XS

}

@AccessControl.authorizationCheck: #NOT_REQUIRED

@ObjectModel.representativeKey: 'PartnerFunction'
@Consumption.valueHelpDefault.fetchValues:#AUTOMATICALLY_WHEN_DISPLAYED
@Consumption.ranked: true

@EndUserText.label: 'Partner Function By Sales Doc Category'
define view C_PartnerFuncBySalesDocCatVH
  as select distinct from I_SalesDocumentType        as SalesDocumentType
    inner join            I_PartFuncByPartDetnProced as PartFuncByPartDetnProced on SalesDocumentType.PartnerDeterminationProcedure = PartFuncByPartDetnProced.PartnerDeterminationProcedure

  association [0..1] to C_PartnerFunctionUnconverted as _PartnerFunction on $projection.PartnerFunction = _PartnerFunction.PartnerFunction

{

      @UI.hidden: true
  key SalesDocumentType.SDDocumentCategory,

      @UI.hidden: true
      @ObjectModel.text.element: ['PartnerFunctionName']
      @UI.textArrangement: #TEXT_ONLY
  key PartFuncByPartDetnProced.PartnerFunction,

      @Semantics.text:true
      @Search.defaultSearchElement: true
      _PartnerFunction._Text[1: Language=$session.system_language].PartnerFunctionName,

      _PartnerFunction.SDDocumentPartnerType,

      @Semantics.booleanIndicator: true
      @Consumption.filter.hidden
      @UI.hidden: true
      cast(
        case
          when _PartnerFunction.SDDocumentPartnerType = 'KU'
          then ''
        else 'X'
        end as boole_d ) as UICT_Customer,

      @Semantics.booleanIndicator: true
      @Consumption.filter.hidden
      @UI.hidden: true
      cast(
        case
          when _PartnerFunction.SDDocumentPartnerType = 'AP'
          then ''
        else 'X'
        end as boole_d ) as UICT_ContactPerson,

      @Semantics.booleanIndicator: true
      @Consumption.filter.hidden
      @UI.hidden: true
      cast(
        case
          when _PartnerFunction.SDDocumentPartnerType = 'PE'
          then ''
        else 'X'
        end as boole_d ) as UICT_Personnel,

      @Semantics.booleanIndicator: true
      @Consumption.filter.hidden
      @UI.hidden: true
      cast(
        case
          when _PartnerFunction.SDDocumentPartnerType = 'LI'
          then ''
        else 'X'
        end as boole_d ) as UICT_Supplier,

      @Consumption.filter.hidden
      @UI.hidden: true
      @Semantics.booleanIndicator: true
      PartFuncByPartDetnProced.PartnerIsNotChangeable

}
//where

//  PartFuncByPartDetnProced.PartnerIsNotChangeable = ''

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_PARTNERFUNCTIONUNCONVERTED",
"I_PARTFUNCBYPARTDETNPROCED",
"I_PARTNERFUNCTIONTEXT",
"I_SALESDOCUMENTTYPE"
],
"ASSOCIATED":
[
"C_PARTNERFUNCTIONUNCONVERTED"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/