C_PT_SAFTPaymentLineC

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #CONSUMPTION
@Analytics.internalName:#LOCAL
@Metadata.allowExtensions:true
@Analytics: { dataCategory: #CUBE }
@EndUserText.label: 'Payment Lines for SAFT PT - Cube'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity C_PT_SAFTPaymentLineC
  as select from           I_JournalEntry                as Document

    inner join             I_ClrgInfoRelationForAcctgDoc as Clear             on  Clear.ClearingInfoCompanyCode    =  Document.CompanyCode
                                                                              and Clear.ClearingAccountingDocument =  Document.AccountingDocument
                                                                              and Clear.ClearingFiscalYear         =  Document.FiscalYear
                                                                              and Clear.AccountType                =  'D' //only customers accounts

                                                                              and Clear.SpecialGLCode              <> 'F'

    inner join             P_PT_SAFTPAYORGON             as Orig              on  Orig.ClearingInfoCompanyCode    = Document.CompanyCode
                                                                              and Orig.ClearingAccountingDocument = Document.AccountingDocument
                                                                              and Orig.FiscalYear                 = Document.FiscalYear
                                                                              and Orig.DocumentItemNumber         = Clear.ClearingInformationIndex

    left outer to one join I_PT_SAFTDownPaymentFinance   as ClearingToExclude on  ClearingToExclude.CompanyCode    =  Document.CompanyCode
                                                                              and ClearingToExclude.FromFiscalYear <= Document.FiscalYear
                                                                              and ClearingToExclude.ToFiscalYear   >= Document.FiscalYear
                                                                              and ClearingToExclude.DocumentType   =  Document.AccountingDocumentType
{
  key Document.CompanyCode,
  key Document.AccountingDocument                                                 as ClearingAccountingDocument,
  key Document.FiscalYear                                                         as ClearingFiscalYear,
  key Clear.ClearingInformationIndex                                              as DocumentItemNumber,

      Clear.AccountingDocument,
      Clear.FiscalYear                                                            as FiscalYear,
      Document.PostingDate,
      Orig.ClearingInfoCompanyCode,
      Orig.OriginalReferenceDocument,
      Clear.CompanyCodeCurrency                                                   as CompanyCurrency,
      Clear.TransactionCurrency,
      @Semantics.amount.currencyCode: 'CompanyCurrency'
      case
        when Clear.DebitCreditCode = 'H'
        then
          case
            when Clear.DifferenceAmtInCoCodeCrcy is initial
            then abs(Clear.AmountInCompanyCodeCurrency - Clear.CashDiscountAmtInCoCodeCrcy )
            else abs(Clear.AmountInCompanyCodeCurrency - Clear.DifferenceAmtInCoCodeCrcy - Clear.CashDiscountAmtInCoCodeCrcy )
          end
      else cast(0 as fis_dr_hsl)
      end                                                                         as DebitAmountInCoCodeCrcy,

      @Semantics.amount.currencyCode: 'CompanyCurrency'
      case
        when Clear.DebitCreditCode = 'S'
        then
          case
            when Clear.DifferenceAmtInCoCodeCrcy is initial
            then abs(Clear.AmountInCompanyCodeCurrency - Clear.CashDiscountAmtInCoCodeCrcy )
            else abs(Clear.AmountInCompanyCodeCurrency - Clear.DifferenceAmtInCoCodeCrcy - Clear.CashDiscountAmtInCoCodeCrcy )
          end
      else cast(0 as fis_dr_hsl)
      end                                                                         as CreditAmountInCoCodeCrcy,

      Document.AbsoluteExchangeRate                                               as ExchangeRate,

      //Amount Foreign Currency

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case
        when Clear.DebitCreditCode = 'H'
        then
          case
            when Clear.DifferenceAmtInTransCrcy is initial
            then abs(Clear.AmountInTransactionCurrency - Clear.CashDiscountAmount )
            else abs(Clear.AmountInTransactionCurrency + Clear.DifferenceAmtInTransCrcy - Clear.CashDiscountAmount )
          end
      else cast(0 as fis_dr_hsl)
      end                                                                         as DebitAmountInTransCrcy,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case
        when Clear.DebitCreditCode = 'S'
        then
          case
            when Clear.DifferenceAmtInTransCrcy is initial
            then abs(Clear.AmountInTransactionCurrency - Clear.CashDiscountAmount )
            else abs(Clear.AmountInTransactionCurrency - Clear.DifferenceAmtInTransCrcy - Clear.CashDiscountAmount )
          end
      else cast(0 as fis_dr_hsl)
      end                                                                         as CreditAmountInTransCrcy,

      @Semantics.amount.currencyCode: 'CompanyCurrency'
      case
        when Clear._AccountingDocument._OperationalAcctgDocItem[FinancialAccountType = 'D'   //Partial Payment, Invoice not cleared

                                                        and ClearingJournalEntry is initial ].AccountingDocument is not initial
          or Clear.DifferenceAmtInTransCrcy is initial   //or Partial Payment, Invoice clearing line

        then Clear.CashDiscountAmtInCoCodeCrcy
      else cast(0 as fis_dr_hsl)
      end                                                                         as CashDiscountAmtInCoCodeCrcy,

      Document._OperationalAcctgDocItem[FinancialAccountType = 'D'].PaymentMethod as PaymentMethod,

      @Semantics.booleanIndicator:true
      case
        when ClearingToExclude.DownPaymentType = '2'
        then 'X'
        else 'I'
      end                                                                         as SelectedValueIsExcluded,

      Document._CompanyCode,
      Orig._BillDgtlSgntr,
      Clear._AccountingDocument.AccountingDocumentType,
      Clear._AccountingDocument.DocumentDate
}
where
  Document.IsReversal = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTINGDOCUMENT",
"I_CLRGINFORELATIONFORACCTGDOC",
"I_JOURNALENTRY",
"I_OPERATIONALACCTGDOCITEM",
"I_PT_SAFTDOWNPAYMENTFINANCE",
"P_PT_SAFTPAYORGON"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_PT_BILLGDOCDGTLSGNTR"
],
"BASE":
[
"I_JOURNALENTRY",
"P_PT_SAFTPAYORGON"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/