C_PPS_SupplierDetail

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Supplier Details'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #XL,
  dataClass: #MIXED
} 
@ObjectModel.representativeKey: 'Supplier'
@UI.headerInfo: {
  typeImageUrl: 'sap-icon://supplier'

}
@VDM.viewType: #CONSUMPTION
// @JIRA-KEY S4PPS-8079

define view entity C_PPS_SupplierDetail
  as select from I_Supplier
{
      @UI.facet: [ {
                     purpose:    #QUICK_VIEW, //Enabling Quick View for Smart Link Navigation

                     type:       #FIELDGROUP_REFERENCE,
                     targetQualifier: 'SupplierContactCard'
                   } ]

      @UI.fieldGroup: [ {
                     position: 1,
                     qualifier: 'SupplierContactCard',
                     label: 'Supplier',
                     type: #STANDARD
                     }]
      @ObjectModel: { text.element: [ 'SupplierFullName' ] }
      @Consumption.filter.hidden: true
  key Supplier,

      @Semantics.name.fullName: true
      @Semantics.text: true
      @Consumption.filter.hidden: true
      SupplierName                                                                        as SupplierFullName,

      @UI.hidden: true
      @Consumption.filter.hidden: true
      AddressID,

      @UI.fieldGroup: [ {
                     position: 2,
                     qualifier: 'SupplierContactCard',
                     label: 'Address',
                     type: #STANDARD
                     } ]
      @ObjectModel: { virtualElement,
                      virtualElementCalculatedBy: 'ABAP:CL_VDM_CC_ADDRESS_FORMAT',
                      readOnly: true }
      @Semantics.address.label: true
      @Consumption.filter.hidden: true
      cast('' as contactcardformattedaddress)                                             as FormattedAddress,
      
      @Consumption.filter.hidden: true 
      @Semantics.address.street: true
      StreetName,

      @Semantics.address.number: true
      @Consumption.filter.hidden: true
      _StandardAddress.HouseNumber,

      @Semantics.address.postBox: true
      @Consumption.filter.hidden: true
      PostalCode,

      @Semantics.address.city: true
      @Consumption.filter.hidden: true
      CityName,

      @Semantics.address.country: true
      @ObjectModel: { text.element: [ 'CountryName' ] }
      @Consumption.filter.hidden: true
      Country,
      
      @Semantics.text: true
      @Consumption.filter.hidden: true
      _StandardAddress._Country._Text[1: Language = $session.system_language].CountryName as CountryName,

      @Semantics.address.region: true
      @Consumption.filter.hidden: true
      Region,

      @UI.fieldGroup: [ {
                     position: 8,
                     qualifier: 'SupplierContactCard',
                     label: 'Telephone',
                     type: #STANDARD
                     } ]
      @Semantics.telephone.type: [#CELL]
      @Consumption.filter.hidden: true
      _StandardAddress.PhoneNumber,

      @UI.fieldGroup: [ {
                     position: 9,
                     qualifier: 'SupplierContactCard',
                     label: 'Fax',
                     type: #STANDARD
                     } ]
      @Semantics.telephone.type: [#FAX]
      @Consumption.filter.hidden: true
      FaxNumber,

      @UI.fieldGroup: [ {
                     position: 10,
                     qualifier: 'SupplierContactCard',
                     label: 'Email Address',
                     type: #STANDARD
                     } ]
      @Semantics.eMail.address: true
      @Semantics.eMail.type: [#WORK]
      @Consumption.filter.hidden: true
      _CurrentDfltEmailAddress.EmailAddress,
      
      //added only for DCL check

    @UI.hidden: true
    @Consumption.filter.hidden: true     
      DataControllerSet,                                                                                                                                                                                                                                                                                           
//added only for DCL check

    @UI.hidden: true
    @Consumption.filter.hidden: true    
      DataController1,                                                                                                                                                                                                                                                                                      
//added only for DCL check

    @UI.hidden: true
    @Consumption.filter.hidden: true  
      DataController2,   
//added only for DCL check

    @UI.hidden: true
    @Consumption.filter.hidden: true   
      DataController3,   
//added only for DCL check

    @UI.hidden: true
    @Consumption.filter.hidden: true   
      DataController4,    
//added only for DCL check

    @UI.hidden: true
    @Consumption.filter.hidden: true    
      DataController5,  
//added only for DCL check

    @UI.hidden: true
    @Consumption.filter.hidden: true     
      DataController6, 
//added only for DCL check

    @UI.hidden: true
    @Consumption.filter.hidden: true    
      DataController7,   
 //added only for DCL check

    @UI.hidden: true
    @Consumption.filter.hidden: true     
      DataController8,  
//added only for DCL check

    @UI.hidden: true
    @Consumption.filter.hidden: true  
      DataController9,     
//added only for DCL check

    @UI.hidden: true
    @Consumption.filter.hidden: true      
      DataController10,
//added only for DCL check

    @UI.hidden: true
    @Consumption.filter.hidden: true
    SupplierAccountGroup,      
//added only for DCL check

    @UI.hidden: true
    @Consumption.filter.hidden: true
    AuthorizationGroup,       
//added only for DCL check

    @UI.hidden: true
    @Consumption.filter.hidden: true
    @Semantics.booleanIndicator: true
    IsBusinessPurposeCompleted    
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRCURDEFAULTEMAILADDRESS",
"I_ADDRESS",
"I_COUNTRY",
"I_COUNTRYTEXT",
"I_SUPPLIER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/