C_POItemCountForSuplrCube

DDL: C_POITEMCOUNTFORSUPLRCUBE SQL: CPOITMCNTCUBE Type: view CONSUMPTION

PO and Item Count for Total Supplier - Cube

C_POItemCountForSuplrCube is a Consumption CDS View (Cube) that provides data about "PO and Item Count for Total Supplier - Cube" in SAP S/4HANA. It reads from 3 data sources (I_PurchaseOrder, I_PurchaseOrderItem, P_TotalNumberOfSuppliers) and exposes 12 fields with key fields Supplier, PurchaseOrder, PurchaseOrderItem. It has 3 associations to related views.

3 data source(s) 12 fields

Data Sources (3)

SourceAliasJoin Type
I_PurchaseOrder _PurchaseOrder inner
I_PurchaseOrderItem _PurchaseOrderItem inner
P_TotalNumberOfSuppliers AvailableSupplier from

Associations (3)

CardinalityTargetAliasCondition
[1..1] I_Country _Country $projection.Country = _Country.Country
[0..1] I_Region _SupplierRegion $projection.Region = _SupplierRegion.Region and $projection.Country = _SupplierRegion.Country
[1..1] I_Supplier _Supplier $projection.Supplier = _Supplier.Supplier

Annotations (16)

NameValueLevelField
AbapCatalog.sqlViewName CPOITMCNTCUBE view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #NOT_REQUIRED view
VDM.viewType #CONSUMPTION view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #L view
Analytics.dataCategory #CUBE view
Analytics.internalName #LOCAL view
AbapCatalog.preserveKey true view
Metadata.allowExtensions true view
ObjectModel.modelingPattern #ANALYTICAL_CUBE view
Metadata.ignorePropagatedAnnotations true view
EndUserText.label PO and Item Count for Total Supplier - Cube view

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY Supplier P_TotalNumberOfSuppliers Supplier
KEY PurchaseOrder I_PurchaseOrder PurchaseOrder
KEY PurchaseOrderItem I_PurchaseOrderItem PurchaseOrderItem
SupplierAccountGroup SupplierAccountGroup
AuthorizationGroup AuthorizationGroup
Country Country
Region Region
NumberOfPurchaseOrders
NumberOfPurchaseOrderItems
_Supplier _Supplier
_Country _Country
_SupplierRegion _SupplierRegion 
@AbapCatalog.sqlViewName: 'CPOITMCNTCUBE'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory:  #L
@Analytics.dataCategory: #CUBE
@Analytics.internalName:#LOCAL
@AbapCatalog.preserveKey:true
@Metadata.allowExtensions:true
@ObjectModel.supportedCapabilities: [ #ANALYTICAL_PROVIDER]
@ObjectModel.modelingPattern: #ANALYTICAL_CUBE
@Metadata.ignorePropagatedAnnotations:true
@EndUserText.label: 'PO and Item Count for Total Supplier - Cube'
define view C_POItemCountForSuplrCube
  as select from P_TotalNumberOfSuppliers as AvailableSupplier

  inner join I_PurchaseOrder as _PurchaseOrder  on  AvailableSupplier.Supplier                          = _PurchaseOrder.Supplier
                                                           and _PurchaseOrder.PurchasingDocumentDeletionCode = ''
                                                           
  inner join I_PurchaseOrderItem as _PurchaseOrderItem  on  _PurchaseOrder.PurchaseOrder                          = _PurchaseOrderItem.PurchaseOrder
                                                           and _PurchaseOrderItem.PurchasingDocumentDeletionCode = ''                                                        

  association [1..1] to I_Country       as _Country        on  $projection.Country = _Country.Country

  association [0..1] to I_Region        as _SupplierRegion on  $projection.Region  = _SupplierRegion.Region
                                                           and $projection.Country = _SupplierRegion.Country

  association [1..1] to I_Supplier      as _Supplier       on  $projection.Supplier = _Supplier.Supplier

{
      @ObjectModel.foreignKey.association: '_Supplier'
      @Analytics.internalName:#LOCAL
  key AvailableSupplier.Supplier as Supplier,
  key _PurchaseOrder.PurchaseOrder as PurchaseOrder,
  key _PurchaseOrderItem.PurchaseOrderItem,
      
      SupplierAccountGroup,
      AuthorizationGroup,

      @ObjectModel.foreignKey.association: '_Country'
      @Analytics.internalName:#LOCAL
      Country,

      @ObjectModel.foreignKey.association: '_SupplierRegion'
      @Analytics.internalName:#LOCAL
      Region,
      
      @Aggregation.referenceElement: ['PurchaseOrder']
      @Aggregation.default: #COUNT_DISTINCT
      cast( 1 as mm_pur_ana_numbrofpurords )    as NumberOfPurchaseOrders,

      @DefaultAggregation: #SUM
      cast( 1 as mm_pur_ana_numbrofpurorditms ) as NumberOfPurchaseOrderItems,

      _Supplier,
      _Country,
      _SupplierRegion
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASEORDER",
"I_PURCHASEORDERITEM",
"P_TOTALNUMBEROFSUPPLIERS"
],
"ASSOCIATED":
[
"I_COUNTRY",
"I_REGION",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More