C_PODeliveryAddressFactSheet

@AbapCatalog.sqlViewName: 'CPODELADDTPFS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Purchase Order Fact Sheet Delivery Address'
@ObjectModel: {
    semanticKey: ['PurchaseOrder', 'PurchaseOrderItem'],
    representativeKey: 'PurchaseOrder',
    usageType.serviceQuality: #C,
    usageType.sizeCategory: #M,
    usageType.dataClass: #MIXED
}
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
define view C_PODeliveryAddressFactSheet
  as select from I_PurOrdItemDeliveryAddress
  association [1..1] to C_PurOrdDeliveryAddressTP as PurOrdDeliveryAddressTP on  PurOrdDeliveryAddressTP.PurchaseOrder     = $projection.PurchaseOrder
                                                                             and PurOrdDeliveryAddressTP.PurchaseOrderItem = $projection.PurchaseOrderItem
{

  key I_PurOrdItemDeliveryAddress.PurchaseOrder,

  key I_PurOrdItemDeliveryAddress.PurchaseOrderItem,

      @UI.hidden:true
      Plant,
      @UI.hidden:true
      ItemDeliveryAddressID,
      @UI.fieldGroup: [ { position: 10, qualifier: 'DeliveryAddress1' } ]
      I_PurOrdItemDeliveryAddress._Address_2.AddresseeFullName,
      @UI.fieldGroup: [ { position: 20, qualifier: 'DeliveryAddress1' } ]
      I_PurOrdItemDeliveryAddress._Address_2.StreetName,
      @UI.fieldGroup: [ { position: 30, qualifier: 'DeliveryAddress1' } ]
      I_PurOrdItemDeliveryAddress._Address_2.HouseNumber,
      @UI.fieldGroup: [ { position: 10, qualifier: 'DeliveryAddress2' } ]
      I_PurOrdItemDeliveryAddress._Address_2.PostalCode,
      @UI.fieldGroup: [ { position: 20, qualifier: 'DeliveryAddress2' } ]
      I_PurOrdItemDeliveryAddress._Address_2.CityName,
      PurOrdDeliveryAddressTP.PhoneNumber,
      I_PurOrdItemDeliveryAddress._Address_2._CurrentDfltFaxNumber.InternationalFaxNumber,
      @UI.fieldGroup: [ { position: 10, qualifier: 'DeliveryAddress3' } ]
      @Consumption.valueHelp: 'C_MM_RegionValueHelp'
      @ObjectModel.text.element: ['RegionName']
      I_PurOrdItemDeliveryAddress._Address_2.Region,
      @UI.fieldGroup: [ { position: 10, qualifier: 'DeliveryAddress3' } ]
      @Consumption.valueHelp: 'C_MM_CountryValueHelp'
      @ObjectModel.text.element: ['CountryName']
      I_PurOrdItemDeliveryAddress._Address_2.Country,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      PurOrdDeliveryAddressTP.CountryName,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      PurOrdDeliveryAddressTP.RegionName,
      _PurchaseOrder
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_PURORDDELIVERYADDRESSTP",
"I_ADDRCURDEFAULTFAXNUMBER",
"I_ADDRESS_2",
"I_PURORDITEMDELIVERYADDRESS"
],
"ASSOCIATED":
[
"C_PURORDDELIVERYADDRESSTP",
"I_PURCHASEORDER"
],
"BASE":
[
"I_PURORDITEMDELIVERYADDRESS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/