C_PMWorkCenterVH

DDL: C_PMWORKCENTERVH SQL: CPMCHDR Type: view CONSUMPTION

Plant Maintenance Work Centers

C_PMWorkCenterVH is a Consumption CDS View that provides data about "Plant Maintenance Work Centers" in SAP S/4HANA. It reads from 1 data source (I_WorkCenter) and exposes 13 fields with key fields WorkCenterInternalID, WorkCenterTypeCode, WorkCenter.

1 data source(s) 13 fields

Data Sources (1)

SourceAliasJoin Type
I_WorkCenter I_WorkCenter from

Annotations (12)

NameValueLevelField
AbapCatalog.sqlViewName CPMCHDR view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Plant Maintenance Work Centers view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MASTER view
VDM.viewType #CONSUMPTION view
ObjectModel.dataCategory #VALUE_HELP view
Search.searchable true view
Consumption.ranked true view

Fields (13)

KeyFieldSource TableSource FieldDescription
KEY WorkCenterInternalID I_WorkCenter WorkCenterInternalID
KEY WorkCenterTypeCode I_WorkCenter WorkCenterTypeCode
KEY WorkCenter I_WorkCenter WorkCenter
Plant I_WorkCenter Plant
WorkCenterCategoryCode
hidden
WorkCenterText
WorkCenterCategoryName
_Text I_WorkCenter _Text
_WorkCenterCategory I_WorkCenter _WorkCenterCategory
_WorkCenterType _WorkCenterType
_WorkCenter _WorkCenter
_Plant _Plant 
@AbapCatalog.sqlViewName: 'CPMCHDR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Plant Maintenance Work Centers'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #S, dataClass: #MASTER}
@VDM.viewType: #CONSUMPTION
@ObjectModel.dataCategory: #VALUE_HELP
//@ObjectModel.representativeKey: ['WorkCenter']

@AccessControl.privilegedAssociations: ['_Text']
//@Analytics: { dataCategory: #DIMENSION }


@Search.searchable: true
@Consumption.ranked: true

define view C_PMWorkCenterVH
  as select from I_WorkCenter
{
      @UI.hidden: true
      @ObjectModel.text.element:  [ 'WorkCenter' ] 
  key I_WorkCenter.WorkCenterInternalID,
      @UI.hidden: true
  key I_WorkCenter.WorkCenterTypeCode,
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      @ObjectModel.text.association: '_Text'
      @Consumption.valueHelpDefinition: null
  key I_WorkCenter.WorkCenter, 
      @Search.defaultSearchElement: true
      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 1.0
      I_WorkCenter.Plant,      
      -- for DCL:
      //@UI.hidden: true

      I_WorkCenter.WorkCenterCategoryCode,
      
      -- hidden, for free-text search
      @Consumption.hidden: true
      @Search.defaultSearchElement: true
      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.8
      I_WorkCenter._Text[1: Language = $session.system_language ].WorkCenterText,
      @Search.defaultSearchElement: true
      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.8
      I_WorkCenter._WorkCenterCategory._Text[1: Language = $session.system_language ].WorkCenterCategoryName,

      I_WorkCenter._Text,
      @Consumption.filter.hidden
      I_WorkCenter._WorkCenterCategory,
      _WorkCenterType,
      @Consumption.filter.hidden
     _WorkCenter,
      @Consumption.filter.hidden
      _Plant
      
} 

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_WORKCENTER",
"I_WORKCENTERCATEGORY",
"I_WORKCENTERCATEGORYTEXT",
"I_WORKCENTERTEXT"
],
"ASSOCIATED":
[
"I_PLANT",
"I_WORKCENTERBYSEMANTICKEY",
"I_WORKCENTERCATEGORY",
"I_WORKCENTERTEXT",
"I_WORKCENTERTYPE"
],
"BASE":
[
"I_WORKCENTER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More