C_PL_SAFTCompany

@AbapCatalog.sqlViewName: 'CPLSAFTCOMPANY'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'SAFT PL Company'
define view C_PL_SAFTCompany
  as select from I_CompanyCode
    inner join   I_PL_SAFTGeneralSettings on I_CompanyCode.CompanyCode = I_PL_SAFTGeneralSettings.CompanyCode
{
  key I_PL_SAFTGeneralSettings.CompanyCode,
  key I_PL_SAFTGeneralSettings.ValidityEndDate,
      I_PL_SAFTGeneralSettings.ValidityStartDate,

      I_PL_SAFTGeneralSettings.EmailAddress,
      I_PL_SAFTGeneralSettings.PL_OfficialEntityRegistration,
      I_PL_SAFTGeneralSettings.PL_CompanyDistrictName,
      I_PL_SAFTGeneralSettings.PL_CompanySubDistrictName,
      I_PL_SAFTGeneralSettings.PL_TaxOfficeCode,   
      
      concat_with_space(
        concat_with_space(
            concat_with_space(
              I_CompanyCode._Address.BusinessPartnerName1,
              I_CompanyCode._Address.BusinessPartnerName2, 1),
              I_CompanyCode._Address.BusinessPartnerName3, 1),
              I_CompanyCode._Address.BusinessPartnerName4, 1)   as CompanyName,

      I_CompanyCode._Address.CityName                           as CityName,
      I_CompanyCode._Address.PostalCode                         as PostalCode,
      I_CompanyCode._Address.StreetName                         as StreetName,
      I_CompanyCode._Address.HouseNumber                        as HouseNumber,
      I_CompanyCode._Address.HouseNumberSupplementText          as HouseNumberSupplementText,
      case when I_CompanyCode._Address.HomeCityName is initial
        then I_CompanyCode._Address.CityName
        else I_CompanyCode._Address.HomeCityName
      end                                                 as HomeCityName,
      case when I_CompanyCode._Address.Region  is initial
        then 'Nie dotyczy'
        else  I_CompanyCode._Address._Region._RegionText[1: Language = 'L'].RegionName
      end                                                 as Region,

      replace(I_CompanyCode.VATRegistration,I_CompanyCode.Country,'') as CompanyVATRegistration,

      @Semantics.currencyCode: true
      I_CompanyCode.Currency                                    as CompanyCodeCurrency,
      
      _Currency

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_COMPANYCODE",
"I_PL_SAFTGENERALSETTINGS",
"I_REGION",
"I_REGIONTEXT"
],
"ASSOCIATED":
[
"I_CURRENCY"
],
"BASE":
[
"I_COMPANYCODE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/