C_PCSftyDcmpstnProdSubstanceVH

@EndUserText.label: 'Decomposition Product Substance ValueHelp'
@AbapCatalog.sqlViewName: 'CSRDCMPPTPSUBVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {
     serviceQuality:  #C,
     dataClass:       #MIXED,
     sizeCategory:    #L
   }
@ObjectModel.semanticKey:  [ 'SubstanceName' ]
@ObjectModel.representativeKey: 'SubstanceUUID'
@ObjectModel.dataCategory: #VALUE_HELP
@Metadata.ignorePropagatedAnnotations: true

@UI:
{
  presentationVariant:
  [{
      sortOrder:
      [{
          by: 'SubstanceName',
          direction: 'ASC'
      }],
      requestAtLeast: [ 'SubstanceUUID','SubstanceName' ]
  }]
}

@Search.searchable: true

/*----------------------------------------------------------------------------------------------------------------------
    Value Help view to find and assign replaced substances
------------------------------------------------------------------------------------------------------------------------*/

define view C_PCSftyDcmpstnProdSubstanceVH
  with parameters
    P_PCSftyDcmpstnProdListUUID : sysuuid_x
  -- select Substances
  as select from           I_SubstanceTP            as _Substance

  --Join data of draft Decomposition Product
    left outer to one join I_PCSftyDcmpstnProdDraft as _PCSftyDcmpstnProdDraft on  _Substance.SubstanceUUID                          = _PCSftyDcmpstnProdDraft.SubstanceUUID
                                                                               and _PCSftyDcmpstnProdDraft.PCSftyDcmpstnProdListUUID = $parameters.P_PCSftyDcmpstnProdListUUID

  association [0..*] to I_SubstanceText as _SubstanceText on $projection.SubstanceUUID = _SubstanceText.SubstanceUUID
{

      @UI.hidden: true
  key $parameters.P_PCSftyDcmpstnProdListUUID as PCSftyDcmpstnProdListUUID,

      @UI.hidden: true
      @UI.selectionField: [{ exclude: true }]
      @Consumption.semanticObject: 'SubstanceUUID'
  key _Substance.SubstanceUUID,

      @UI.hidden: true
      @UI.selectionField: [{ exclude: true }]
      _Substance.ListedSubstanceUUID,

      @UI:{
        lineItem: [{
           position:   10,
           importance: #HIGH
        }],
        identification: [{
           position:   10,
           importance: #HIGH
        }]
      }
      _Substance.SubstanceName,

      @UI: {
        lineItem: [{
           position:   20,
           importance: #HIGH
        }],
        identification: [{
           position:   20,
           importance: #HIGH
        }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold:   0.8,
        ranking: #LOW
      }
      _Substance.SubstanceInternalName,

      // used to search within listed substance names

      // Remark: Do not search on ListedSubstanceDefaultName because it is a calculated field

      @UI.hidden:true
      @Search:
      {
        defaultSearchElement: true,
        fuzzinessThreshold:   0.8,
        ranking: #MEDIUM
      }
      _Substance._ListedSubstance.CustListedSubstanceDfltName,

      // used to search within listed substance names

      // Remark: Do not search on ListedSubstanceDefaultName because it is a calculated field

      @UI.hidden:true
      @Search:
      {
        defaultSearchElement: true,
        fuzzinessThreshold:   0.8,
        ranking: #MEDIUM
      }
      _Substance._ListedSubstance.CntntListedSubstanceDfltName,

      //used to search within company substance names

      @UI.hidden:true
      @Search:
      {
        defaultSearchElement: true,
        fuzzinessThreshold:   0.8,
        ranking: #HIGH
      }
      _Substance.CompanySubstanceName,


      // used to search within listed substance names

      // Remark: Do not search on ListedSubstance because it is a calculated field

      @UI.hidden:true
      @Search:
      {
        defaultSearchElement: true,
        fuzzinessThreshold:   0.8,
        ranking: #MEDIUM
      }
      _Substance._ListedSubstance.CustListedSubstance,

      // used to search within listed substance names

      // Remark: Do not search on ListedSubstance because it is a calculated field

      @UI.hidden:true
      @Search:
      {
        defaultSearchElement: true,
        fuzzinessThreshold:   0.8,
        ranking: #MEDIUM
      }
      _Substance._ListedSubstance.CntntListedSubstance,

      @UI: {
        lineItem: [{
          position:   30,
          importance: #MEDIUM
        }]
      }
      _Substance._ListedSubstance.ECNumber,

      // used to search for EC number

      // Remark: Do not search on EC Number because it is a calculated field

      @UI.hidden:true
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold:   0.9,
        ranking: #MEDIUM
      }
      _Substance._ListedSubstance.CustECNumber,

      // used to search for EC number

      // Remark: Do not search on EC Number because it is a calculated field

      @UI.hidden:true
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold:   0.9,
        ranking: #MEDIUM
      }
      _Substance._ListedSubstance.CntntECNumber,

      @UI: {
        lineItem: [{
          position:   40,
          importance: #MEDIUM
        }]
      }
      _Substance._ListedSubstance.CASNumber,

      // used to search for EC number

      // Remark: Do not search on CAS Number because it is a calculated field

      @UI.hidden:true
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold:   0.9,
        ranking: #MEDIUM
      }
      _Substance._ListedSubstance.CustCASNumber,

      // used to search for EC number

      // Remark: Do not search on CAS Number because it is a calculated field

      @UI.hidden:true
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold:   0.9,
        ranking: #MEDIUM
      }
      _Substance._ListedSubstance.CntntCASNumber,

      // used to search for EC number

      // Remark: Do not search on MolecularFormula because it is a calculated field

      @UI.hidden:true
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold:   0.7,
        ranking: #LOW
      }
      _Substance._ListedSubstance.CustMolecularFormula,

      // used to search for EC number

      // Remark: Do not search on MolecularFormula because it is a calculated field

      @UI.hidden:true
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold:   0.7,
        ranking: #LOW
      }
      _Substance._ListedSubstance.CntntMolecularFormula,

      @UI.hidden: true
      _Substance.ResponsibleUnit,
      
      // Associations

      _SubstanceText
}
where --Select components which are not assigned
  _PCSftyDcmpstnProdDraft.PCSftyDcmpstnProdListUUID is null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PCSFTYDCMPSTNPRODDRAFT",
"I_SUBSTACTIVEDRAFTLSTDSUBST",
"I_SUBSTANCETP"
],
"ASSOCIATED":
[
"I_SUBSTANCETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/