C_OperationActivityWorklistTP

@AbapCatalog: {
  sqlViewName: 'CMFGOPAWTP',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_SASSchema']
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
  compositionRoot: true,
  transactionalProcessingDelegated: true,
  createEnabled: false,
  updateEnabled: false,
  deleteEnabled: false,
  draftEnabled: false,
  semanticKey: ['OpActyNtwkElementExternalID'],
  usageType: {
    serviceQuality: #D,
    sizeCategory:   #XL,
    dataClass:      #MIXED
  }
}
@VDM.viewType: #CONSUMPTION
@Metadata.allowExtensions: true
@Search.searchable: true
define view C_OperationActivityWorklistTP
  as select from           I_OperationActivityWorklistTP as oaw
    inner join             I_ManufacturingOrder          as MfgOrder                    on MfgOrder.ManufacturingOrder = oaw.ManufacturingOrder
    left outer to one join I_OpActyWorkInstructionAssgmt as OpActyWorkInstructionAssgmt on  OpActyWorkInstructionAssgmt.OperationActivity           = oaw.OperationActivity
                                                                                        and OpActyWorkInstructionAssgmt.OperationActyVersionCounter = oaw.OperationActyVersionCounter
    left outer to one join P_OpActNrOfActiveSFI          as OpActNrOfActiveSFI          on  OpActNrOfActiveSFI.OpActyNtwkInstance = oaw.OpActyNtwkInstance
                                                                                        and OpActNrOfActiveSFI.OpActyNtwkElement  = oaw.OpActyNtwkElement
                                                                                        and oaw.OpActyConfIsSFIBased              = 'X'
    left outer to one join P_OpActyNrOfOpActySFIGrp      as OpActyNrOfOpActySFIGrp      on  OpActyNrOfOpActySFIGrp.OpActyNtwkInstance = oaw.OpActyNtwkInstance
                                                                                        and OpActyNrOfOpActySFIGrp.OpActyNtwkElement  = oaw.OpActyNtwkElement
  // Needed to identify whether the session user is labored on to the Operation Activity (or an SFI at that Operation Activity)

    left outer to one join P_OpActyAggrgdOpnLaborTrckg   as OpActySsnUsrOpnLaborTrckg   on  OpActySsnUsrOpnLaborTrckg.OpActyNtwkInstance     = oaw.OpActyNtwkInstance
                                                                                        and OpActySsnUsrOpnLaborTrckg.OpActyNtwkElement      = oaw.OpActyNtwkElement
                                                                                        and OpActySsnUsrOpnLaborTrckg.ShopFloorExecutionUser = $session.user
  // Needed to calculate OpActyHasMissingComponents

    left outer to one join P_OpActyInstceWithMissingComp as OpActyInstceWithMissingComp on  OpActyInstceWithMissingComp.OpActyNtwkInstance = oaw.OpActyNtwkInstance
                                                                                        and OpActyInstceWithMissingComp.OpActyNtwkElement  = oaw.OpActyNtwkElement
  // Joins to retrieve dedicated order statuses to allow filtering by order status

    left outer to one join I_StatusObjectStatusBasic     as isTechCompl                 on  isTechCompl.StatusObject     = MfgOrder.ObjectInternalID
                                                                                        and isTechCompl.StatusCode       = 'I0045'
                                                                                        and isTechCompl.StatusIsInactive = ''

  association [0..1] to I_OpActyNtwkElement            as _OpActyNtwkElement            on  $projection.OperationActivityNetwork = _OpActyNtwkElement.OperationActivityNetwork
                                                                                        and $projection.OpActyNtwkVersionCounter = _OpActyNtwkElement.OpActyNtwkVersionCounter
                                                                                        and $projection.OpActyNtwkElement        = _OpActyNtwkElement.OpActyNtwkElement
  association [0..*] to I_SASStatusText                as _SASStatusText                on  $projection.StatusAndActionSchemaStatus = _SASStatusText.StatusAndActionSchemaStatus
  association [0..*] to I_SASStatusCategoryText        as _SASStatusCategoryText        on  $projection.SASStatusCategory = _SASStatusCategoryText.SASStatusCategory
  association [0..1] to I_OANSegmentType               as _OANSegmentType               on  $projection.OpActyNtwkSegmentType = _OANSegmentType.OpActyNtwkSegmentType
  association [0..*] to I_WorkCenterText               as _WorkCenterText               on  $projection.WorkCenterTypeCode   = _WorkCenterText.WorkCenterTypeCode
                                                                                        and $projection.WorkCenterInternalID = _WorkCenterText.WorkCenterInternalID
  association [0..*] to C_OperationActivityComponent   as _OperationActivityComponent   on  $projection.OpActyNtwkInstance = _OperationActivityComponent.OpActyNtwkInstance
                                                                                        and $projection.OpActyNtwkElement  = _OperationActivityComponent.OpActyNtwkElement
  association [0..*] to C_ShopFloorItemAtOpActy        as _ShopFloorItemAtOpActy        on  $projection.OpActyNtwkInstance = _ShopFloorItemAtOpActy.OpActyNtwkInstance
                                                                                        and $projection.OpActyNtwkElement  = _ShopFloorItemAtOpActy.OpActyNtwkElement
  association [0..*] to C_OperationActyPRTAssignment   as _OperationActyPRTAssignment   on  $projection.OpActyNtwkInstance = _OperationActyPRTAssignment.OpActyNtwkInstance
                                                                                        and $projection.OpActyNtwkElement  = _OperationActyPRTAssignment.OpActyNtwkElement
                                                                                        and $projection.OrderInternalID    = _OperationActyPRTAssignment.OrderInternalID
  association [0..*] to C_OpActyInstcePlndPRTNoDoc     as _OpActyInstcePlndPRTNoDoc     on  $projection.OpActyNtwkInstance = _OpActyInstcePlndPRTNoDoc.OpActyNtwkInstance
                                                                                        and $projection.OpActyNtwkElement  = _OpActyInstcePlndPRTNoDoc.OpActyNtwkElement
                                                                                        and $projection.OrderInternalID    = _OpActyInstcePlndPRTNoDoc.OrderInternalID
  association [0..*] to C_ShopFloorOrderDefect         as _MfgOrderDefect               on  $projection.OpActyNtwkInstance = _MfgOrderDefect.OpActyNtwkInstance
                                                                                        and $projection.OpActyNtwkElement  = _MfgOrderDefect.OpActyNtwkElement
  association [0..1] to I_MfgWorkInstructionVersion    as _MfgWorkInstructionVersion    on  $projection.WorkInstruction               = _MfgWorkInstructionVersion.MfgWorkInstruction
                                                                                        and $projection.WorkInstructionVersionCounter = _MfgWorkInstructionVersion.MfgWorkInstructionVersCounter
                                                                                        and _MfgWorkInstructionVersion.Language       = $session.system_language
  association [0..*] to C_MfgQualifnOpActyAssgmt       as _MfgQualifnOpActyAssgmt       on  $projection.OpActyNtwkInstance = _MfgQualifnOpActyAssgmt.OpActyNtwkInstance
                                                                                        and $projection.OpActyNtwkElement  = _MfgQualifnOpActyAssgmt.OpActyNtwkElement
  association [0..*] to C_OperationActivityPlndMatlRet as _OperationActivityPlndMatlRet on  $projection.OpActyNtwkInstance = _OperationActivityPlndMatlRet.OpActyNtwkInstance
                                                                                        and $projection.OpActyNtwkElement  = _OperationActivityPlndMatlRet.OpActyNtwkElement
  association [0..1] to P_MatlNmbrOfProdnHolds         as _MatlNmbrOfProdnHolds         on  $projection.Material = _MatlNmbrOfProdnHolds.Material
  association [0..1] to P_MfgOrderNmbrOfOrderHolds     as _MfgOrderNmbrOfOrderHolds     on  $projection.ManufacturingOrder = _MfgOrderNmbrOfOrderHolds.ManufacturingOrder
  association [0..1] to P_OperNmbrOfProdnHolds         as _OperNmbrOfProdnHolds         on  $projection.OrderInternalID          = _OperNmbrOfProdnHolds.OrderInternalID
                                                                                        and $projection.OrderOperationInternalID = _OperNmbrOfProdnHolds.OrderOperationInternalID
  association [0..1] to P_WrkCtrNmbrOfProdnHolds       as _WrkCtrNmbrOfProdnHolds       on  $projection.WorkCenterInternalID = _WrkCtrNmbrOfProdnHolds.WorkCenterInternalID
                                                                                        and $projection.WorkCenterTypeCode   = _WrkCtrNmbrOfProdnHolds.WorkCenterTypeCode
  association [0..1] to P_OpActyNumberOfProdnHold      as _OpActyNumberOfProdnHold      on  $projection.OpActyNtwkInstance = _OpActyNumberOfProdnHold.OpActyNtwkInstance
                                                                                        and $projection.OpActyNtwkElement  = _OpActyNumberOfProdnHold.OpActyNtwkElement
  association [0..*] to C_OpActyUserAssgmtTP           as _OpActyUserAssgmtTP           on  $projection.OpActyNtwkInstance = _OpActyUserAssgmtTP.OpActyNtwkInstance
                                                                                        and $projection.OpActyNtwkElement  = _OpActyUserAssgmtTP.OpActyNtwkElement
  association [0..*] to C_OpActyTeamAssgmtTP           as _OpActyTeamAssgmtTP           on  $projection.OpActyNtwkInstance = _OpActyTeamAssgmtTP.OpActyNtwkInstance
                                                                                        and $projection.OpActyNtwkElement  = _OpActyTeamAssgmtTP.OpActyNtwkElement
  association [0..1] to I_RespyMgmtTeamHeaderDetail    as _RespyMgmtTeamHeaderDetail    on  $projection.RespyMgmtTeamID = _RespyMgmtTeamHeaderDetail.RespyMgmtTeamID
  //SFI@OA Group

  association [0..*] to C_OpActySFIGroupAtOpActivity   as _OpActySFIGroupAtOpActivity   on  $projection.OpActyNtwkInstance = _OpActySFIGroupAtOpActivity.OpActyNtwkInstance
                                                                                        and $projection.OpActyNtwkElement  = _OpActySFIGroupAtOpActivity.OpActyNtwkElement
{
  key oaw.OpActyNtwkInstance,
  key oaw.OpActyNtwkElement,
      @ObjectModel.readOnly: true
      @Environment.sql.passValue: true
      cast(case
        when OpActySsnUsrOpnLaborTrckg.ShopFloorExecutionUser is not null then 'X'
      //        else ''

      end as xfeld preserving type)                                                                                         as UserIsLaboredOn,
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.96
      }
      @ObjectModel.text.element: ['ManufacturingOrderText']
      oaw.ManufacturingOrder,
      @Semantics.text: true
      MfgOrder.ManufacturingOrderText,
      MfgOrder.ExtdQualityCheckIsRequired,
      cast(case MfgOrder.ExtdQualityCheckIsRequired
        when 'X' then 2
        else 0
      end as mpe_criticality_type preserving type)                                                                          as ExtdQualityCheckCriticality,
      MfgOrder.ManufacturingOrderImportance,
      @Environment.sql.passValue: true
      cast(case
        when isTechCompl.StatusCode is not null then  'X'
        else ''
      end as orderistechnicallycompleted preserving type)                                                                   as OrderIsTechnicallyCompleted,
      @ObjectModel.text.element: ['MfgOrderOperationText']
      @Search.defaultSearchElement: true
      cast(oaw.ManufacturingOrderOperation as mpe_vornr_char preserving type)                                               as ManufacturingOrderOperation,
      oaw.MfgOrderOperationText,
      oaw.StatusAndActionSchema,
      @ObjectModel.text.element: ['SASStatusName']
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.96
      }
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_SASStatusVH', element: 'StatusAndActionSchemaStatus' } } ]
      oaw.StatusAndActionSchemaStatus,
      cast(_SASStatusText[1: Language=$session.system_language].SASStatusName as mpe_oa_status_description preserving type) as SASStatusName,
      @ObjectModel.text.element: ['SASStatusCategoryName']
      @Consumption.valueHelpDefinition: [ { entity: { name: 'C_OpActySASStatusCategory', element: 'SASStatusCategory' } } ]
      @Environment.sql.passValue: true
      oaw.SASStatusCategory,
      _SASStatusCategoryText[1: Language=$session.system_language].SASStatusCategoryName,
      oaw.ProductionUnit,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      oaw.OpPlannedYieldQuantity,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      oaw.OpPlannedScrapQuantity,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      oaw.OperationExecutionAvailableQty,
      oaw.OpActyExpdExecutionDuration,
      oaw.OpActyExpdExecutionLaborDurn,
      oaw.DurationUnit,
      oaw.OpActyExpdExecDurnInSeconds,
      oaw.OpActyExpdExecLaborDurnInSecs,
      @ObjectModel.text.element: ['OperationActivityName']
      @Search.defaultSearchElement: true
      cast(oaw.OpActyNtwkElementExternalID as mpe_oa_number_ext preserving type)                                            as OpActyNtwkElementExternalID,
      oaw.OperationActivityNetwork,
      oaw.OpActyNtwkVersionCounter,
      oaw._OperationActivityText[1: Language=$session.system_language].OperationActivityName,
      @ObjectModel.text.element: ['OpActyNtwkSegmentTypeText']
      @Search.defaultSearchElement: true
      @Consumption.valueHelpDefinition: [{ entity: { name: 'C_MfgOpActyNtwkSegmentTypeVH', element: 'OpActyNtwkSegmentType'} }]
      oaw.OpActyNtwkSegmentType,
      _OANSegmentType._Text[1: Language=$session.system_language].OpActyNtwkSegmentTypeText                                 as OpActyNtwkSegmentTypeText,
      oaw.OpActyConfIsSFIBased,
      coalesce(OpActNrOfActiveSFI.NumberOfActiveShopFloorItems, 0)                                                          as NumberOfActiveShopFloorItems,
      oaw.OpActyIsSeldForRtactvPostg,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      @ObjectModel: {
        foreignKey.association: '_Material',
        text.element: ['MaterialName']
      }
      @Search.defaultSearchElement: true
      MfgOrder.Material                                                                                                     as Material,
      MfgOrder._Material._Text[1: Language=$session.system_language].MaterialName                                           as MaterialName,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WBSElementBasicDataStdVH', element: 'WBSElementExternalID' } } ]
      @ObjectModel.text.element: ['WBSDescription']
      MfgOrder._WBSElementBasicData2.WBSElementExternalID                                                                   as WBSElementExternalID,
      @UI.hidden: true
      MfgOrder.WBSElementInternalID_2                                                                                       as WBSElementInternalID,
      @UI.hidden: true
      MfgOrder._WBSElementBasicData2.WBSDescription                                                                         as WBSDescription,
      oaw.WorkCenterInternalID,
      oaw.WorkCenterTypeCode,
      @ObjectModel.text.element: ['WorkCenterText']
      @Search.defaultSearchElement: true
      oaw.WorkCenter,
      _WorkCenterText[1: Language=$session.system_language].WorkCenterText                                                  as WorkCenterText,
      @Search.defaultSearchElement: true
      oaw.ProductionPlant,
      oaw.NrOfOpActyUserAssignments                                                                                         as NrOfOpActyUserAssignments,
      @UI.hidden: true
      oaw.UserID                                                                                                            as UserID,
      oaw._User.UserDescription                                                                                             as UserDescription,
      oaw.NrOfOpActyTeamAssignments                                                                                         as NrOfOpActyTeamAssignments,
      oaw.RespyMgmtTeamID                                                                                                   as RespyMgmtTeamID,
      cast
        (coalesce(_RespyMgmtTeamHeaderDetail.TeamName, '')
        as hr_mcstext preserving type )                                                                                     as TeamName,
      cast(case
        when OpActyInstceWithMissingComp.OpActyNtwkInstance is null then ''
        else 'X'
        end as xfeld preserving type )                                                                                      as OpActyHasMissingComponents,
      cast( case
        when _MatlNmbrOfProdnHolds.NumberOfHolds is null
        and   _MfgOrderNmbrOfOrderHolds.NumberOfHolds is null
        and   _OperNmbrOfProdnHolds.NumberOfHolds is null
        and   _WrkCtrNmbrOfProdnHolds.NumberOfHolds is null
        and   _OpActyNumberOfProdnHold.NumberOfHolds is null then ''
        else 'X'
      end as xfeld preserving type )                                                                                        as OperationActivityHasProdnHold,
      oaw.OrderInternalID,
      oaw.OrderOperationInternalID,
      oaw.OperationActivity,
      oaw.OperationActyVersionCounter,

      cast(coalesce(OpActyNrOfOpActySFIGrp.NumberOfOpActySFIGroups, 0) as mpe_nr_of_sfi_at_oai_grps preserving type)        as NumberOfOpActySFIGroups,
      @ObjectModel.text.element: ['OpActySFIGroupName']
      cast(coalesce(OpActyNrOfOpActySFIGrp.OperationActivitySFIGroup, 0) as mpe_sfi_at_oai_group_id preserving type)        as OperationActivitySFIGroup,
      OpActyNrOfOpActySFIGrp._OperationActivitySFIGroup.OpActySFIGroupName,

      //_MfgOrderOpAdaptedDates

      //Scheduled Timestamps

      @Consumption.filter.selectionType: #INTERVAL
      oaw.OpLtstSchedldExecStrtDteTme,
      @Consumption.filter.selectionType: #INTERVAL
      oaw.OpLtstSchedldExecEndDteTme,

      //Actual Timestamps

      @Consumption.filter.selectionType: #INTERVAL
      oaw.OpActualExecutionStartDateTime,
      @Consumption.filter.selectionType: #INTERVAL
      oaw.OpActualExecutionEndDateTime,

      //Work Instructions

      @UI.hidden: true
      OpActyWorkInstructionAssgmt.WorkInstruction,

      @UI.hidden: true
      OpActyWorkInstructionAssgmt.WorkInstructionVersionCounter,

      oaw.ProductionHold,

      @UI.hidden: true
      @ObjectModel: {
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_MPE_CREATE_WI_HTML_CONTENT'
      }
      _MfgWorkInstructionVersion.MfgWorkInstructionContent                                                                  as MfgWorkInstructionContent,

      // Effectivity

      -- Effectivity Parameter
      MfgOrder.EffectivityParameterVariant,
      @ObjectModel: {
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_MPE_GET_EFFECTIVITY_VALUE'
      }
      cast('' as mpe_effectivity_parameter_desc)                                                                            as EffectivityParameterDesc,

      oaw.MfgOpActyExecutionPriority,

      /* Associations */
      @Consumption.filter.hidden: true
      oaw._OpActyNtwkInstance,
      --  @Consumption.filter.hidden: true
      --  _User,
      @Consumption.filter.hidden: true
      oaw._MfgOrder,
      @Consumption.filter.hidden: true
      MfgOrder._Material,
      @Consumption.filter.hidden: true
      oaw._OpActyNtwkInternalId,
      @Consumption.filter.hidden: true
      oaw._OperationActivityNetwork,
      @Consumption.filter.hidden: true
      oaw._SASSchema,
      @Consumption.filter.hidden: true
      oaw._UnitOfMeasure,
      @Consumption.filter.hidden: true
      oaw._SASStatus,
      @Consumption.filter.hidden: true
      _OpActyNtwkElement,
      @Consumption.filter.hidden: true
      _OANSegmentType,
      @Consumption.filter.hidden: true
      _SASStatusText,
      @Consumption.filter.hidden: true
      oaw._ProductionPlant,
      @Consumption.filter.hidden: true
      MfgOrder._WBSElementBasicData2                                                                                        as _WBSElementBasicData,
      @Consumption.filter.hidden: true
      oaw._WorkCenterBySemanticKey,
      @Consumption.filter.hidden: true
      oaw._WorkCenterType,
      @Consumption.filter.hidden: true
      _WorkCenterText,
      @Consumption.filter.hidden: true
      oaw._OpActyUserAssgmt,
      @Consumption.filter.hidden: true
      _OperationActivityComponent,
      @Consumption.filter.hidden: true
      _ShopFloorItemAtOpActy,
      @Consumption.filter.hidden: true
      _OperationActyPRTAssignment,
      @Consumption.filter.hidden: true
      _OpActyInstcePlndPRTNoDoc,
      @Consumption.filter.hidden: true
      _MfgOrderDefect,
      @Consumption.filter.hidden: true
      _MfgWorkInstructionVersion,
      @Consumption.filter.hidden: true
      _MfgQualifnOpActyAssgmt,
      @Consumption.filter.hidden: true
      _OperationActivityPlndMatlRet,
      @Consumption.filter.hidden: true
      _OpActyUserAssgmtTP,
      @Consumption.filter.hidden: true
      _OpActyTeamAssgmtTP,
      @Consumption.filter.hidden: true
      oaw._OpActyRespyMgmtTeamAssgmt,
      @Consumption.filter.hidden: true
      _OpActySFIGroupAtOpActivity

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MANUFACTURINGORDER",
"I_MATERIAL",
"I_MATERIALTEXT",
"I_MFGWORKINSTRUCTIONVERSION",
"I_OANSEGMENTTYPE",
"I_OANSEGMENTTYPETEXT",
"I_OPACTYWORKINSTRUCTIONASSGMT",
"I_OPERATIONACTIVITYSFIGROUP",
"I_OPERATIONACTIVITYTEXT",
"I_OPERATIONACTIVITYWORKLISTTP",
"I_RESPYMGMTTEAMHEADERDETAIL",
"I_SASSTATUSCATEGORYTEXT",
"I_SASSTATUSTEXT",
"I_STATUSOBJECTSTATUSBASIC",
"I_USER",
"I_WBSELEMENTBASICDATA",
"I_WORKCENTERTEXT",
"P_MATLNMBROFPRODNHOLDS",
"P_MFGORDERNMBROFORDERHOLDS",
"P_OPACTNROFACTIVESFI",
"P_OPACTYAGGRGDOPNLABORTRCKG",
"P_OPACTYINSTCEWITHMISSINGCOMP",
"P_OPACTYNROFOPACTYSFIGRP",
"P_OPACTYNUMBEROFPRODNHOLD",
"P_OPERNMBROFPRODNHOLDS",
"P_WRKCTRNMBROFPRODNHOLDS"
],
"ASSOCIATED":
[
"C_MFGQUALIFNOPACTYASSGMT",
"C_OPACTYINSTCEPLNDPRTNODOC",
"C_OPACTYSFIGROUPATOPACTIVITY",
"C_OPACTYTEAMASSGMTTP",
"C_OPACTYUSERASSGMTTP",
"C_OPERATIONACTIVITYCOMPONENT",
"C_OPERATIONACTIVITYPLNDMATLRET",
"C_OPERATIONACTYPRTASSIGNMENT",
"C_SHOPFLOORITEMATOPACTY",
"C_SHOPFLOORORDERDEFECT",
"I_MATERIAL",
"I_MFGORDER",
"I_MFGWORKINSTRUCTIONVERSION",
"I_OANSEGMENTTYPE",
"I_OPACTYNTWKELEMENT",
"I_OPACTYNTWKINSTANCE",
"I_OPACTYNTWKINTERNALID",
"I_OPACTYRESPYMGMTTEAMASSGMT",
"I_OPACTYUSERASSGMT",
"I_OPERATIONACTIVITYNETWORK",
"I_PLANT",
"I_RESPYMGMTTEAMHEADERDETAIL",
"I_SASSCHEMA",
"I_SASSTATUS",
"I_SASSTATUSCATEGORYTEXT",
"I_SASSTATUSTEXT",
"I_UNITOFMEASURE",
"I_WBSELEMENTBASICDATA",
"I_WORKCENTERBYSEMANTICKEY",
"I_WORKCENTERTEXT",
"I_WORKCENTERTYPE",
"P_MATLNMBROFPRODNHOLDS",
"P_MFGORDERNMBROFORDERHOLDS",
"P_OPACTYNUMBEROFPRODNHOLD",
"P_OPERNMBROFPRODNHOLDS",
"P_WRKCTRNMBROFPRODNHOLDS"
],
"BASE":
[
"I_MANUFACTURINGORDER",
"I_OPERATIONACTIVITYWORKLISTTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/