C_OperationActivityCompInstce

@AbapCatalog.sqlViewName: 'CMPEOACOMPINSTCE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@EndUserText.label: 'Operation Activity Component Instance'
define view C_OperationActivityCompInstce
  as select from I_OpActyCompInstceAssignment as OpActyCompInstceAssignment
{
  key OpActyCompInstceAssignment.Reservation,
  key OpActyCompInstceAssignment.ReservationItem,
  key OpActyCompInstceAssignment.RecordType,
      @UI.hidden: true
  key OpActyCompInstceAssignment.OpActyNtwkInstance,
      @UI.hidden: true
  key OpActyCompInstceAssignment.OpActyNtwkElement,
      @UI.hidden: true
  key OpActyCompInstceAssignment.OriglDgtlMockUpCharcsUUID,
      @UI.hidden: true
      OpActyCompInstceAssignment.DgtlMockUpCharcsUUID,
      @UI.hidden: true
      OpActyCompInstceAssignment.ReltdOriglDgtlMockUpCharcsUUID,
      @UI.hidden: true
      OpActyCompInstceAssignment.MfgRefStrucBOMLeafAssgmtUUID,
      @UI.hidden: true
      OpActyCompInstceAssignment.MfgRefStructureItemDetailUUID,
      @UI.hidden: true
      OpActyCompInstceAssignment.MfgRefStrucItmDetIsContextual,
      cast(case
        when OpActyCompInstceAssignment.MfgRefStrucItmDetIsContextual = 'X'
        and OpActyCompInstceAssignment._MfgRefHierItemWithDetails.HierMfgReferenceDesignatorName is not null
        and OpActyCompInstceAssignment._MfgRefHierItemWithDetails.HierMfgReferenceDesignatorName <> ''
          then OpActyCompInstceAssignment._MfgRefHierItemWithDetails.HierMfgReferenceDesignatorName
        when OpActyCompInstceAssignment.MfgRefStrucItmDetIsContextual = ''
        and OpActyCompInstceAssignment._MfgRefStrucItemWithDetails.MfgRefStrucItmRefDsgntrName is not null
        and OpActyCompInstceAssignment._MfgRefStrucItemWithDetails.MfgRefStrucItmRefDsgntrName <> ''
          then OpActyCompInstceAssignment._MfgRefStrucItemWithDetails.MfgRefStrucItmRefDsgntrName
        when OpActyCompInstceAssignment._InstanceReferenceDesignator.ReferenceDesignatorValue is not null
        or   OpActyCompInstceAssignment._InstanceReferenceDesignator.ReferenceDesignatorValue <> ''
          then OpActyCompInstceAssignment._InstanceReferenceDesignator.ReferenceDesignatorValue
      -- If no RefDes exists, use GUID as Fallback (instead of having empty RefDes)
        else bintohex( OpActyCompInstceAssignment.OriglDgtlMockUpCharcsUUID )
      end as vmp_ref_des) as ReferenceDesignatorName,
      OpActyCompInstceAssignment._InstanceReferenceDesignator.ReferenceDesignatorValue,
      @ObjectModel.text.element: 'MfgRefStrucItmRefDsgntrDesc'
      cast( case OpActyCompInstceAssignment.MfgRefStrucItmDetIsContextual
        when 'X' then OpActyCompInstceAssignment._MfgRefHierItemWithDetails.MfgRefStrucItmRefDesignator
        else OpActyCompInstceAssignment._MfgRefStrucItemWithDetails.MfgRefStrucItmRefDesignator
        end as mpe_mrs_designator preserving type )           as MfgRefStrucItmRefDesignator,
      @UI.hidden: true
      cast( case OpActyCompInstceAssignment.MfgRefStrucItmDetIsContextual
        when 'X' then OpActyCompInstceAssignment._MfgRefHierItemWithDetails._MfgReferenceHierarchyItmTxt[1: Language=$session.system_language].HierMfgRefDesignatorDesc
        else OpActyCompInstceAssignment._MfgRefStrucItemWithDetails._MfgReferenceStructureItmTxt[1: Language=$session.system_language].MfgRefStrucItmRefDsgntrDesc
      end as mpe_mrs_designator_description preserving type ) as MfgRefStrucItmRefDsgntrDesc,
      cast( case OpActyCompInstceAssignment.MfgRefStrucItmDetIsContextual
        when 'X' then OpActyCompInstceAssignment._MfgRefHierItemWithDetails.HierMfgReferenceDesignatorName
        else OpActyCompInstceAssignment._MfgRefStrucItemWithDetails.MfgRefStrucItmRefDsgntrName
      end as mpe_mrs_designator_name preserving type )        as MfgRefStrucItmRefDsgntrName,
      OpActyCompInstceAssignment._OpActyComponentAssignment,
      OpActyCompInstceAssignment._OpActyNtwkInstance,
      OpActyCompInstceAssignment._OpActyNtwkInstanceBasic,
      OpActyCompInstceAssignment._OperationActivityInstance,
      OpActyCompInstceAssignment._ReservationHeader
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSTANCEREFERENCEDESIGNATOR",
"I_MFGREFERENCEHIERARCHYITMTXT",
"I_MFGREFERENCESTRUCTUREITMTXT",
"I_MFGREFHIERITEMWITHDETAILS",
"I_MFGREFSTRUCITEMWITHDETAILS",
"I_OPACTYCOMPINSTCEASSIGNMENT"
],
"ASSOCIATED":
[
"I_OPACTYCOMPONENTASSIGNMENT",
"I_OPACTYNTWKINSTANCE",
"I_OPACTYNTWKINSTANCEBASIC",
"I_OPERATIONACTIVITYINSTANCE",
"I_RESERVATIONDOCUMENTHEADER"
],
"BASE":
[
"I_OPACTYCOMPINSTCEASSIGNMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/