C_Openbillingrequest

@AbapCatalog.sqlViewName: 'COPENBILLINGREQ'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@OData.publish: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Open Billing Request'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@AccessControl.personalData.blocking: #REQUIRED
@VDM.lifecycle.status: #DEPRECATED
/* As of 2302 release, this view is deprecated. Please do not use this view. */ 

define view C_Openbillingrequest
  as select from I_BillingDueListItem as BillingDocument

    inner join   I_SalesDocument      as SalesDocument on  SalesDocument.SalesDocument            = BillingDocument.ReferenceSDDocument
                                                       and SalesDocument.SalesDocumentType        = 'DMR1'
                                                       and SalesDocument.HeaderBillingBlockReason = '06'
  association [0..*] to I_EngagementProjectItem as _Item                on  $projection.SalesDocument       = _Item.EngagementProjectItem
                                                                        and _Item.EngagementProjectItemType = '0SOH'




  association [0..1] to I_Customer_VH           as _Customer            on  $projection.SoldToParty = _Customer.Customer
  association [0..1] to I_BillingDocumentType   as _BillingDocumentType on  $projection.BillingDocumentType = _BillingDocumentType.BillingDocumentType

{
  key BillingDocument.BillingDocumentCategory                         as BillingDocumentCategory,
  key BillingDocument.BillingDocumentType                             as BillingDocumentType,
  key BillingDocument.BillingDocumentDate                             as BillingDocumentDate,
  key BillingDocument.SalesOrganization                               as SalesOrganization,
      @Consumption.valueHelp: '_Customer'
      @EndUserText.label: 'Customer'
      @EndUserText.quickInfo: 'Customer'
  key BillingDocument.Customer                                        as SoldToParty,
  key BillingDocument.DestinationCountry                              as DestinationCountry,
      @EndUserText.label: 'Document Number'
      @UI.lineItem.position: 1
  key BillingDocument.ReferenceSDDocument                             as ReferenceSDDocument,

      SalesDocument.ReferenceSDDocument                               as SalesDocument,
      BillingDocument.ReferenceSDDocumentCategory                     as ReferenceSDDocumentCategory,
      @EndUserText.label: 'Net Amount'
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BillingDocument.NetAmount                                       as NetAmount,
      @Semantics.currencyCode: true
      BillingDocument.TransactionCurrency                             as TransactionCurrency,
      @EndUserText.label: 'Customer Name'
      BillingDocument._Customer.CustomerName                       as CustomerName,
      SalesDocument.SalesDocumentType                                 as SalesDocumentType,
      SalesDocument.OrganizationDivision                              as OrganizationDivision,
      SalesDocument.DistributionChannel                               as DistributionChannel,
      @UI.hidden: true
      _Item.EngagementProjectUUID                                     as EngagementProjectUUID,
      @EndUserText.label: 'Project ID'
      _Item._EngagementProject.EngagementProject                      as EngagementProject,
      @EndUserText.label: 'Project Name'
      _Item._EngagementProject.EngagementProjectName                  as EngagementProjectName,


      //Association

      @Consumption.hidden: true
      _Customer,

      @Consumption.hidden: true
      _BillingDocumentType,

      @Consumption.hidden: true
      _Item,

      @Consumption.hidden: true
      BillingDocument._ReferenceSDDocumentCategory
}

where
  (
    BillingDocument.BillingDocumentCategory     = 'A'
  )
  and(
    BillingDocument.ReferenceSDDocumentCategory = 'L'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLINGDUELISTITEM",
"I_CUSTOMER",
"I_ENGAGEMENTPROJECT",
"I_ENGAGEMENTPROJECTITEM",
"I_SALESDOCUMENT"
],
"ASSOCIATED":
[
"I_BILLINGDOCUMENTTYPE",
"I_CUSTOMER_VH",
"I_ENGAGEMENTPROJECTITEM",
"I_SDDOCUMENTCATEGORY"
],
"BASE":
[
"I_BILLINGDUELISTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/