C_OpActyInstceReferenceCompVH

@AbapCatalog.viewEnhancementCategory: [#NONE]
@EndUserText.label: 'Reference component of an OA instance'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XL,
  dataClass: #MIXED
}
@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.representativeKey: 'BillOfMaterial'
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #MANDATORY
@Search.searchable: true

define view entity C_OpActyInstceReferenceCompVH
  as select distinct from  I_OpActyInstanceReferenceComp  as OpActyInstanceReferenceComp
    inner join             P_BOMItems                     as BOMItems                     on  BOMItems.BillOfMaterialCategory        = OpActyInstanceReferenceComp.BillOfMaterialCategory
                                                                                          and BOMItems.BillOfMaterial                = OpActyInstanceReferenceComp.BillOfMaterial
                                                                                          and BOMItems.BillOfMaterialVariant         = OpActyInstanceReferenceComp.BillOfMaterialVariant
                                                                                          and BOMItems.InheritedNodeNumberForBOMItem = OpActyInstanceReferenceComp.InheritedNodeNumberForBOMItem
                                                                                          and BOMItems.BillOfMaterialVersion         = OpActyInstanceReferenceComp.BillOfMaterialVersion
    inner join             I_MaterialBOMLink              as MaterialBOMLink              on  MaterialBOMLink.BillOfMaterial        = OpActyInstanceReferenceComp.BillOfMaterial
                                                                                          and MaterialBOMLink.BillOfMaterialVariant = OpActyInstanceReferenceComp.BillOfMaterialVariant
    left outer to one join I_DigitalMockUp                as DigitalMockUp                on DigitalMockUp.DgtlMockUpUUID = BOMItems.BillOfMaterialItemUUID
    left outer to one join I_MatlPlntCompAssembleControl as MatlPlntCompAssembleControl   on  MatlPlntCompAssembleControl.Product = BOMItems.BillOfMaterialComponent
                                                                                          and MatlPlntCompAssembleControl.Plant   = MaterialBOMLink.Plant
  association [0..1] to I_MaterialText as _MaterialText on  BOMItems.BillOfMaterialComponent = _MaterialText.Material
                                                        and _MaterialText.Language           = $session.system_language
{
      @UI.hidden: true
  key OpActyInstanceReferenceComp.OpActyNtwkInstance,
      @UI.hidden: true
  key OpActyInstanceReferenceComp.OpActyNtwkElement,
      @UI.hidden: true
  key OpActyInstanceReferenceComp.BillOfMaterialCategory,
      @UI.hidden: true
  key OpActyInstanceReferenceComp.BillOfMaterial,
      @UI.hidden: true
  key OpActyInstanceReferenceComp.BillOfMaterialVariant,
      @UI.hidden: true
  key OpActyInstanceReferenceComp.InheritedNodeNumberForBOMItem,
      @UI.hidden: true
  key OpActyInstanceReferenceComp.BillOfMaterialVersion,
      @UI.hidden: true
      OpActyInstanceReferenceComp.OperationActivity,
      @UI.hidden: true
      OpActyInstanceReferenceComp.OperationActyVersionCounter,
      @UI.hidden: true
      OpActyInstanceReferenceComp.ManufacturingOrder,
      @UI.hidden: true
      OpActyInstanceReferenceComp.OrderInternalID,
      @UI.hidden: true
      OpActyInstanceReferenceComp.OrderOperationInternalID,
      @UI.selectionField: [{position: 10 }]
      @ObjectModel.text.association: '_MaterialText'
      @UI.textArrangement: #TEXT_FIRST
      @UI.lineItem: [{position: 10}]
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      cast(BOMItems.BillOfMaterialComponent as matnr preserving type )                                     as BillOfMaterialComponent,
      @UI.selectionField: [{position: 40 }]
      @UI.lineItem: [{position: 40}]
      @EndUserText.label: 'Serial Number Mgmt Rqt'
      @EndUserText.quickInfo: 'Serial Number Requirement Indicator'
      MatlPlntCompAssembleControl.SerialNumberIsRqdForAssembly,
      @UI.selectionField: [{position: 30 }]
      @UI.lineItem: [{position: 30}]
      MatlPlntCompAssembleControl.IsBatchManagementRequired,
      @UI.hidden: true
      @Semantics.booleanIndicator: true
      cast(case
              when DigitalMockUp.DgtlMockUpUUID is not null
                then 'X'
              else
                ''
           end  as mpe_instce_assembly_rqd preserving type )                                               as MatlCompInstceAssyIsRequired,
      @UI.hidden: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_NONCF_COMP_SADL_EXIT'
      cast( hextobin('00000000000000000000000000000000') as mpe_mrs_leaf_assignment_uuid preserving type ) as MfgRefStrucBOMLeafAssgmtUUID,
      @UI.selectionField: [{position: 20 }]
      @UI.lineItem: [{position: 20}]
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MPE_NONCF_COMP_SADL_EXIT'
      cast('' as mpe_mrs_designator_name)                                                                  as MfgRefStrucItmRefDsgntrName,
      @UI.hidden: true
      cast('' as rsnum)                                                                                    as Reservation,
      @UI.hidden: true
      cast('' as rspos)                                                                                    as ReservationItem,
      @UI.hidden: true
      cast('' as rsart preserving type)                                                                    as RecordType,
      @UI.hidden: true
      MaterialBOMLink.BillOfMaterialVariantUsage,
      @UI.hidden: true
      MaterialBOMLink.Plant                                                                                as BOMOrBOMAltvCrtedInPlnt,
      @UI.hidden: true
      @Semantics.booleanIndicator: true
      cast(' ' as mpe_rtg_assigned_to_oa preserving type)                                                  as CompIsAssignedToOpActy,
      OpActyInstanceReferenceComp._MfgOrder,
      OpActyInstanceReferenceComp._OpActyNtwkInstance,
      OpActyInstanceReferenceComp._OpActyNtwkInstanceBasic,
      OpActyInstanceReferenceComp._OperationActivity,
      OpActyInstanceReferenceComp._OperationActivityInternalId,
      OpActyInstanceReferenceComp._OrderInternalID,
      _MaterialText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DIGITALMOCKUP",
"I_MATERIALBOMLINK",
"I_MATLPLNTCOMPASSEMBLECONTROL",
"I_OPACTYINSTANCEREFERENCECOMP",
"P_BOMITEMS"
],
"ASSOCIATED":
[
"I_MATERIALTEXT",
"I_MFGORDER",
"I_OPACTYNTWKINSTANCE",
"I_OPACTYNTWKINSTANCEBASIC",
"I_OPERATIONACTIVITY",
"I_OPERATIONACTIVITYINTERNALID",
"I_ORDINTERNALBILLOFOPERATIONS"
],
"BASE":
[
"I_OPACTYINSTANCEREFERENCECOMP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/