C_ObjPgTechnicalObjectWthDesc

@ClientHandling.algorithm: #SESSION_VARIABLE //Inserted by VDM CDS Suite Plugin

@AbapCatalog.sqlViewName: 'COPTOWTHDESC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Obj Page for Technical Object with Desc'
@VDM.viewType: #CONSUMPTION

@ObjectModel: {
   usageType.serviceQuality: #X,
   usageType.sizeCategory: #XL,
   usageType.dataClass: #MIXED
}
define view C_ObjPgTechnicalObjectWthDesc
  with parameters
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_LANGUAGE
    P_Language : sylangu
  as select from I_TechnicalObject
{
  key TechnicalObject,
  key TechObjIsEquipOrFuncnlLoc,

      @UI: {
        fieldGroup: [ { qualifier:'Description', position:20, importance: #HIGH } ]
      }
      @EndUserText.label: 'Long Text'
      @Semantics.text: true
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_TECHOBJ_LTXT_EXIT'
      cast (' ' as eams_ltext )                                                                             as  TechnicalObjectLongText,

      @UI: {
        fieldGroup: [ { qualifier:'Description', position:10, importance: #HIGH } ]
      }
      @EndUserText.label: 'Description'
      _TechnicalObjectText[1:Language = $session.system_language].TechnicalObjectDescription,
      @ObjectModel.text.element:  [ 'TechnicalObjectClassDesc' ]
      @UI: {
        fieldGroup: [
        {qualifier:'HeaderInf',position:80, importance: #HIGH},
        {qualifier:'General',position:10,importance: #HIGH}
        ]}
      // Based on web-dynpro app

      @EndUserText.label: 'Class'
      cast(' ' as klasse_d)                                                                                          as  ClassNumber,
      @Semantics.text: true
      cast(' ' as klsbez)                                                                                            as  TechnicalObjectClassDesc,

      @UI: {
        fieldGroup: [
            {qualifier:'General',position:20},
            {qualifier:'HeaderInf',position:20, importance: #HIGH}
            ]}
      @Semantics.text: true
      @ObjectModel.text.element:  [ 'TechnicalObjectCategoryDesc' ]
      @EndUserText.label: 'Category'
      TechnicalObjectCategory,
      @Semantics.text: true
      _TechnicalObjectCategory._Text[1: Language = $parameters.P_Language].TechnicalObjectCategoryDesc,

      @UI: {
          fieldGroup: [
              {qualifier:'General',position:30,importance: #HIGH}
          ]
      }
      @EndUserText.label: 'Type'
      @ObjectModel.text.element:  [ 'TechnicalObjectTypeDesc' ]
      TechnicalObjectType,
      @UI: {
        fieldGroup: [
            {qualifier:'HeaderInf',position:30, importance: #HIGH}
        ]
      }
      @EndUserText.label: 'Type'
      @Semantics.text: true
      _TechnicalObjectType._Text[1: Language = $parameters.P_Language].TechnicalObjectTypeDesc,
      @UI: {
        fieldGroup: [
            {qualifier:'General', position:40,importance: #HIGH}
        ]
      }
      AssetManufacturerName,
      @UI: {
          fieldGroup: [
              {qualifier:'General',position:50, importance: #HIGH}
          ]
      }
      ManufacturerPartTypeName,   //Label: Model Number

      @UI: {
          fieldGroup: [
              {qualifier:'General',position:60}
          ]
      }
      @EndUserText.label: 'Manufacturer Part Number'
      ManufacturerPartNmbr,
      @UI: {
          fieldGroup: [
              {qualifier:'General',position:70}
          ]
      }
      @EndUserText.label: 'Manufacturer Serial Number'
      ManufacturerSerialNumber,
      @UI: {
          fieldGroup: [
              {qualifier:'General',position:80}
          ]
      }
      SerialNumber,
      @ObjectModel.text.element:  [ 'MaterialName' ]
      @UI: {
          fieldGroup: [
              {qualifier:'General',position:90}
          ]
      }
      Material,
      @EndUserText.label: 'Material Name'
      _Equipment._Material._Text[1:Language = $session.system_language].MaterialName,
      
      @ObjectModel.text.element:  [ 'MaterialTypeName' ]
      @UI: {
          fieldGroup: [
              {qualifier:'General',position:100}
          ]
      }      
      ConstructionMaterial,
      @EndUserText.label: 'Construction Material Name'
      _ConstructionMaterial._Text[1:Language = $session.system_language].MaterialName as MaterialTypeName,
      
      @UI: {
          fieldGroup: [
              {qualifier:'General',position:110}
          ]
      }
      InventoryNumber,
      @EndUserText.label: 'Authorization Group'
      @UI: {
          fieldGroup: [
              {qualifier:'General',position:120}
          ]
      }
      AuthorizationGroup,
      
      @UI: {
          fieldGroup: [
              {qualifier:'General',position:130}
          ]
      }
      GrossWeight,
      GrossWeightUnit,
      @UI: {
          fieldGroup: [
              {qualifier:'General',position:140}
          ]
      }
      SizeOrDimensionText,
      
      @UI: {
        fieldGroup: [
            {qualifier:'HeaderOverview',position:10, importance: #HIGH}
            ]
      }
      @EndUserText.label: 'Original Files'
      cast ('0' as abap.int2 )                                                                                      as  TechObjNmbrOfAttachedDocuments,
      
      MaintObjectInternalID,     
      
      @UI.hidden: true
      cast(TechnicalObject as char40) as TechObjectWithLeadingZeros,
      
      //DCL fields

      @UI.hidden: true
      _LocationAccountAssignment.CostCenter,
      @UI.hidden: true
      _LocationAccountAssignment.ControllingArea,
      @UI.hidden: true
      MaintenancePlanningPlant,
      @UI.hidden: true
      MaintenancePlannerGroup,
      @UI.hidden: true
      _LocationAccountAssignment._WorkCenter.Plant                                                                   as  MaintenancePlant,
      
      //Association key for DCL

      //_LocationAccountAssignment key

      @UI.hidden: true
      MaintObjectLocAcctAssgmtNmbr,
      _LocationAccountAssignment
}                                                                                
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EQUIPMENT",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MATERIAL",
"I_MATERIALTEXT",
"I_TECHNICALOBJECT",
"I_TECHNICALOBJECTCATEGORY",
"I_TECHNICALOBJECTCATEGORYT",
"I_TECHNICALOBJECTTEXT",
"I_TECHNICALOBJECTTYPE",
"I_TECHNICALOBJECTTYPETEXT",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"I_LOCATIONACCOUNTASSIGNMENT"
],
"BASE":
[
"I_TECHNICALOBJECT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/