C_NO_TaxReturnBoxCube

@AbapCatalog.sqlViewName: 'CNOTAXRETURNBOXC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'ATR enabled Tax Items for Norway - Cube'
@VDM.viewType: #CONSUMPTION
@Analytics: { dataCategory: #CUBE }
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@Metadata.allowExtensions: true
@AccessControl.personalData.blocking:  #BLOCKED_DATA_INCLUDED

define view C_NO_TaxReturnBoxCube
  with parameters
    P_StatryRptgEntity  : srf_reporting_entity,
    P_StatryRptCategory : srf_rep_cat_id,
    P_StatryRptRunID    : srf_report_run_id,
    P_ReportingCountry  : land1,
    P_KeyDate           : vdm_v_key_date

  as select from           I_StRpTaxReturnBoxCube(
                                     P_TaxIsDeferredRelevant : 'N',
                                     P_TaxIsMossRelevant     : 'N',
                                     P_StatryRptgEntity      : $parameters.P_StatryRptgEntity ,
                                     P_StatryRptCategory     : $parameters.P_StatryRptCategory,
                                     P_StatryRptRunID        : $parameters.P_StatryRptRunID,
                                     P_ReportingCountry      : $parameters.P_ReportingCountry,
                                     P_TaxBoxConfiguration   : '1'
                                                                                              )

    left outer to one join P_T007B_GLO                                            as TransactionType on I_StRpTaxReturnBoxCube.TransactionTypeDetermination = TransactionType.ktosl
    left outer to one join P_NO_VATAdjReasons(P_KeyDate : $parameters.P_KeyDate ) as VAT_Adj_Reason  on  I_StRpTaxReturnBoxCube.TaxCode                      = VAT_Adj_Reason.TaxCode
                                                                                                     and I_StRpTaxReturnBoxCube.TransactionTypeDetermination = VAT_Adj_Reason.TransactionTypeDetermination
                                                                                                     and I_StRpTaxReturnBoxCube.TaxCalculationProcedure      = VAT_Adj_Reason.TaxCalculationProcedure
{

  key  CompanyCode,
  key  AccountingDocument,
  key  FiscalYear,
  key  TaxItem,
  key  I_StRpTaxReturnBoxCube.TransactionTypeDetermination,
  key  DebitCreditCode,
  key  AccountingDocumentType,
  key  SupplierAccountGroup,
  key  TaxBox,
  key  TaxDeclnAmountType,
  key  TaxBoxStrucValidityStartDate,
  key  UnifiedTaxBoxStructureType,
  key  TaxGroup,
  key  TaxItemGrpgDebitCreditCode,
  key  TaxItemGrpgAcctgDocumentType,
  key  TaxItemGrpgSupplierAcctGroup,
  key  TaxItemGrpgSpecialGLCode,
  key  StatryRptgEntity,
  key  StatryRptCategory,
  key  StatryRptRunID,
       I_StRpTaxReturnBoxCube.TaxCode,
       I_StRpTaxReturnBoxCube.Country,
       TaxBoxStrucValidityEndDate,
       TaxBoxName,
       I_StRpTaxReturnBoxCube.TaxItemGroupingVersion,
       TaxBoxStructureType,
       TaxBoxStructure,
       TaxBoxStructureName,
       TaxBoxCondition,
       TaxCountry,
       I_StRpTaxReturnBoxCube.TaxCalculationProcedure,
       TaxRate,
       cast(right(cast( I_StRpTaxReturnBoxCube.TaxRate as char20 ), 10 ) as figen_taxrateinpercentastext ) as TaxRateInPercentAsText,
       TaxRateValidityStartDate,
       GLAccount,
       TaxItemGroup,
       ReferenceDocumentType,
       PostingDate,
       DocumentDate,
       TaxReportingDate,
       ReportingDate,
       TaxType,
       FiscalPeriod,
       CompanyCodeCountry,
       ReportingCountry,
       TaxReturnCountry,
       TaxTypeName,

       @Semantics.currencyCode:true
       CompanyCodeCurrency,
       @Semantics.currencyCode:true
       DocumentCurrency,
       @Semantics.currencyCode:true
       ReportingCurrency,

       @DefaultAggregation:#SUM
       @Semantics.amount.currencyCode: 'ReportingCurrency'
       AmountInReportingCurrency,
       @DefaultAggregation:#SUM
       @Semantics.amount.currencyCode: 'ReportingCurrency'
       TaxBaseAmountInRptgCrcy,
       @DefaultAggregation:#SUM
       @Semantics.amount.currencyCode: 'ReportingCurrency'
       TaxAmountInRptgCrcy,
       @DefaultAggregation:#SUM
       @Semantics.amount.currencyCode: 'ReportingCurrency'
       NonDeductibleInputTaxAmount,
       @DefaultAggregation:#SUM
       @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
       TaxBaseAmountInCoCodeCrcy,
       @DefaultAggregation:#SUM
       @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
       TaxAmountInCoCodeCrcy,
       @DefaultAggregation:#SUM
       @Semantics.amount.currencyCode: 'DocumentCurrency'
       TaxBaseAmountInTransCrcy,
       @DefaultAggregation:#SUM
       @Semantics.amount.currencyCode: 'DocumentCurrency'
       TaxAmount,
       TargetTaxCode,
       CAReconciliationKey,
       TaxIsNotDeductible,
       TransactionType.stgrp                                                                               as TransactionTaxType,
       _ReportingCurrency,
       _TaxTypeText,
       _TaxCodeText,
       VAT_Adj_Reason.NO_VATAdjustmentReason                                                               as NO_VATAdjustmentReason
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_STRPTAXRETURNBOXCUBE",
"P_NO_VATADJREASONS",
"P_T007B_GLO"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_TAXCODETEXT",
"I_TAXTYPETEXT"
],
"BASE":
[
"I_STRPTAXRETURNBOXCUBE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/