C_NO_SAFTJournalEntryCube

@AbapCatalog.sqlViewName: 'CNOSAFTJORENTC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataCategory: #CUBE
@Metadata.allowExtensions:true
@Analytics.internalName:#LOCAL
@EndUserText.label: 'SAF-T Norway Journal Entry Cube'
define view C_NO_SAFTJournalEntryCube
  with parameters
    P_Ledger      : fins_ledger,
    P_StartDate   : dats,
    P_EndDate     : dats,
    P_CompanyCode : bukrs

  as select from I_JournalEntryItem as JournalItem
    inner join   I_JournalEntry     as JournalEntry on  JournalEntry.CompanyCode        = JournalItem.CompanyCode
                                                    and JournalEntry.FiscalYear         = JournalItem.FiscalYear
                                                    and JournalEntry.AccountingDocument = JournalItem.AccountingDocument
{

      @ObjectModel.foreignKey.association: '_CompanyCode'
  key JournalEntry.CompanyCode,
      @ObjectModel.foreignKey.association: '_FiscalYear'
  key JournalEntry.FiscalYear,
  key JournalEntry.AccountingDocument,
      @ObjectModel.foreignKey.association: '_Ledger'
  key JournalItem.Ledger,
      JournalItem.SourceLedger                                                                                                  as LedgerGroup,
      JournalEntry.PostingDate,
      cast( 'A' as fis_blart )                                                                                                  as JournalEntryType,
      JournalEntry.CreationTime,

      @ObjectModel.foreignKey.association: '_FiscalPeriod'
      JournalEntry.FiscalPeriod,
      JournalEntry.DocumentDate,
      JournalEntry.DocumentReferenceID,

      @ObjectModel.foreignKey.association: '_AccountingDocumentType'
      JournalEntry.AccountingDocumentType,
      coalesce(JournalEntry._AccountingDocumentTypeText[1: Language = $session.system_language].AccountingDocumentTypeName,' ') as AccountingDocumentTypeName,
      JournalEntry.AccountingDocumentCreationDate,
      JournalEntry.AccountingDocCreatedByUser,
      JournalEntry.AccountingDocumentHeaderText                                                                                 as AccountingDocumentHeaderText,

      case
       when JournalEntry.CompanyCodeCurrency <> JournalEntry.TransactionCurrency
       then JournalEntry.ExchangeRate
       else 0
      end                                                                                                                       as ExchangeRate,

      @Semantics.currencyCode:true
      JournalEntry.CompanyCodeCurrency,
      @Semantics.currencyCode:true
      JournalEntry.TransactionCurrency,

      concat(concat(JournalEntry.CompanyCode, JournalEntry.AccountingDocument), JournalEntry.FiscalYear )                       as DocumentTransaction,

      JournalEntry._CompanyCode,
      JournalEntry._FiscalYear,
      JournalEntry._FiscalPeriod,
      JournalEntry._AccountingDocumentType,
      JournalItem._Ledger
}
where
           JournalItem.Ledger                      = $parameters.P_Ledger
  and      JournalItem.LedgerGLLineItem            =  '000001'
  and      JournalEntry.PostingDate                between $parameters.P_StartDate and $parameters.P_EndDate
  and      JournalEntry.CompanyCode                = $parameters.P_CompanyCode
  and(
           JournalEntry.AccountingDocumentCategory =  ''
    or     JournalEntry.AccountingDocumentCategory =  'C'
    or     JournalEntry.AccountingDocumentCategory =  'J'
    or     JournalEntry.AccountingDocumentCategory =  'U'
    or     JournalEntry.AccountingDocumentCategory =  'L'
  )
  and(
    (
           JournalEntry._CompanyCode.Country       =  'NO'
      and(
           JournalItem.TaxCountry                  =  'NO'
        or JournalItem.TaxCountry                  =  ''
      )
    )
    or(
           JournalEntry._CompanyCode.Country       <> 'NO'
      and  JournalItem.TaxCountry                  =  'NO'
    )
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTINGDOCUMENTTYPETEXT",
"I_COMPANYCODE",
"I_JOURNALENTRY",
"I_JOURNALENTRYITEM"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENTTYPE",
"I_COMPANYCODE",
"I_FISCALYEARFORCOMPANYCODE",
"I_FISCALYEARPERIODFORCMPNYCODE",
"I_LEDGER"
],
"BASE":
[
"I_JOURNALENTRY",
"I_JOURNALENTRYITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/