C_MyEHSLocationExpanded

@EndUserText.label: 'My EHS Location and Sublocations'

@OData.publish: true
@VDM.viewType: #CONSUMPTION


@AccessControl.authorizationCheck: #CHECK

@AbapCatalog.sqlViewName: 'CMYLOCEXPANDED'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MASTER}

define view C_MyEHSLocationExpanded
  as select from I_MyEHSLocationExpanded
{
      // To be able to resolve the association to the location name it is necessary to have the field

      // _EHSLocationRevision.EHSLocationUUID in this view, even though this is the same UUID as

      // the EHSLocationUUID from view I_MyEHSLocationExpanded. To avoid having two fields with the

      // same value here we use _EHSLocationRevision.EHSLocationUUID as key field instead of

      // I_MyEHSLocationExpanded.EHSLocationUUID


      @UI.hidden: true

  key _EHSLocationRevision.EHSLocationUUID          as EHSLocationUUID,
      MyEHSLocationUUID,

      // Only needed for technical reasons

      @Consumption.hidden: true
      _EHSLocationRevision.RevisionStartDate,

      // Only needed for technical reasons

      @Consumption.hidden: true
      _EHSLocationRevision.RevisionEndDate,
      
      EHSLocationHierarchyLevel,

      @ObjectModel.text.association: '_Name'
      _EHSLocationRevision._EHSLocationRoot.EHSLocationID,
      _EHSLocationRevision.EHSLocationRevisionUUID,

      _EHSLocationRevision.EHSLocationType,
      _EHSLocationRevision.EHSLocationStatus,
      _EHSLocationRevision.EHSLocationAuthorizationGroup,
      _EHSLocationRevision.Plant,
      _EHSLocationRevision.CostCenter,
      _EHSLocationRevision.CompanyCode,
      _EHSLocationRevision.BusinessArea,

      _EHSLocationRevision._EHSLocationRevisionName as _Name
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EHSLOCATION",
"I_EHSLOCATIONROOT",
"I_MYEHSLOCATIONEXPANDED"
],
"ASSOCIATED":
[
"I_EHSLOCATIONREVISIONNAMET"
],
"BASE":
[
"I_EHSLOCATION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/