C_MfgOrderOperationMissingComp

@AbapCatalog.sqlViewName: 'CMPEOPMISSC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true -- otherwise despiting the key below all the fields are treated as key fields -> BOPF does not work
@Metadata.allowExtensions: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #CONSUMPTION
@UI.presentationVariant.sortOrder: {by: 'MaterialName', direction: #ASC}
@EndUserText.label: 'Mfg Order Operation Missing Component'
define view C_MfgOrderOperationMissingComp as select from I_MfgOrderOperationComponent
{
      @ObjectModel.foreignKey.association: '_Reservation'
      @UI.hidden: true
  key Reservation,
  
      @UI.hidden: true
  key ReservationItem,
      
      @ObjectModel.foreignKey.association: '_MfgOrderOperationBySemanKey'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrdOpBySemanticKeyStdVH', element: 'ManufacturingOrderOperation' } } ]
      @UI.hidden: true
      ManufacturingOrderOperation,
      
      @ObjectModel.foreignKey.association: '_MfgOrderSequence'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderSequenceStdVH', element: 'ManufacturingOrderSequence' } } ]
      @UI.hidden: true
      ManufacturingOrderSequence,
      
      @ObjectModel.foreignKey.association: '_MfgOrder'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderStdVH', element: 'ManufacturingOrder' } } ]
      @UI.hidden: true
      ManufacturingOrder,
      
      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      @UI.hidden: true
      ManufacturingOrderCategory,

      @ObjectModel.foreignKey.association: '_MfgOrderType'
      @UI.hidden: true
      ManufacturingOrderType,

      @ObjectModel.foreignKey.association: '_ProductionPlant'
      @UI.hidden: true
      ProductionPlant,

      @UI.identification.position: 30 
      @UI.statusInfo.position: 30
      @UI.fieldGroup.position: 30
      @UI.lineItem.position: 30
      @ObjectModel.text.element: 'MaterialName'  
      @ObjectModel.foreignKey.association: '_Material'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      Material,
      
      @UI.hidden: true
      _Material._Text[1: Language=$session.system_language].MaterialName as MaterialName,      
      
      _Reservation,
      _MfgOrderOperationBySemanKey,
      _MfgOrderSequence,
      _MfgOrder,
      _Material,
      _MfgOrderCategory,
      _MfgOrderType,
      _ProductionPlant
}
where
  MaterialComponentIsMissing = 'X' and ReservationIsFinallyIssued = 'X';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIAL",
"I_MATERIALTEXT",
"I_MFGORDEROPERATIONCOMPONENT"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_MFGORDER",
"I_MFGORDERCATEGORY",
"I_MFGORDEROPERATIONBYSEMANKEY",
"I_MFGORDERSEQUENCE",
"I_MFGORDERTYPE",
"I_PLANT",
"I_RESERVATIONDOCUMENTHEADER"
],
"BASE":
[
"I_MFGORDEROPERATIONCOMPONENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/