@AbapCatalog.sqlViewName: 'CMFGBPRESPY'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Manufacturing User Responsibilities'
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
define view C_MfgBPResponsibility
as select from I_RespyMgmtTeamMbrFunc as TeamFunc
inner join I_RespyMgmtTeamHeaderDetail as TeamHeader on TeamHeader.RespyMgmtTeamID = TeamFunc.RespyMgmtTeamID
inner join I_RespyMgmtTeamTypeBasic as RespyMgmtTeamType on RespyMgmtTeamType.RespyMgmtTeamType = TeamHeader.RespyMgmtTeamType
left outer join I_RespyMgmtTeamCatFuncBfrExcl as RespyMgmtTeamCatFuncBfrExcl on RespyMgmtTeamCatFuncBfrExcl.RespyMgmtFunction = TeamFunc.RespyMgmtFunction
and RespyMgmtTeamCatFuncBfrExcl.RespyMgmtTeamCategory = 'EPO'
association [1..1] to C_MfgOperatorDetail as _Detail on _Detail.MfgBusinessPartner = $projection.RespyMgmtBusinessPartner
{
@UI.hidden: true
key TeamFunc.RespyMgmtTeamID,
@UI.lineItem: [{position: 30 }]
key TeamFunc.RespyMgmtFunction as RespyMgmtFunction,
@UI.hidden: true
key TeamFunc.RespyMgmtBusinessPartner,
@UI.hidden: true
RespyMgmtTeamType.RespyMgmtTeamCategory,
@UI.lineItem: [{position: 10}]
@EndUserText.label: 'Team Name'
TeamHeader.TeamName as RespyMgmtTeamName,
@UI.hidden: true
TeamHeader.RespyMgmtTeamType as RespyMgmtTeamType,
@UI.lineItem: [{position: 20 }]
@EndUserText.label: 'Description'
TeamHeader._TeamDescription.TeamDescription as RespyMgmtTeamDescription,
@UI.lineItem: [{position: 40 }]
RespyMgmtTeamCatFuncBfrExcl.RespyMgmtFunctionDescription,
@ObjectModel.association.type: [#TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT]
_Detail
}
where
RespyMgmtTeamType.RespyMgmtTeamCategory = 'EPO'
and TeamHeader.TeamStatus = '01'
union
select from I_RespyMgmtTeamMbrFunc as TeamFunc
inner join I_RespyMgmtDirectSuperTeam as SuperTeam on TeamFunc.RespyMgmtTeamID = SuperTeam.RespyMgmtSuperTeamID
inner join I_RespyMgmtTeamHeaderDetail as TeamHeader on TeamHeader.RespyMgmtTeamID = SuperTeam.RespyMgmtTeamID
inner join I_RespyMgmtTeamTypeBasic as RespyMgmtTeamType on RespyMgmtTeamType.RespyMgmtTeamType = TeamHeader.RespyMgmtTeamType
left outer join I_RespyMgmtTeamCatFuncBfrExcl as RespyMgmtTeamCatFuncBfrExcl on RespyMgmtTeamCatFuncBfrExcl.RespyMgmtFunction = TeamFunc.RespyMgmtFunction
and RespyMgmtTeamCatFuncBfrExcl.RespyMgmtTeamCategory = 'EPO'
association [1..1] to C_MfgOperatorDetail as _Detail on _Detail.MfgBusinessPartner = $projection.RespyMgmtBusinessPartner
{
@UI.hidden: true
key TeamHeader.RespyMgmtTeamID as RespyMgmtTeamID,
@UI.lineItem: [{position: 30 }]
key TeamFunc.RespyMgmtFunction as RespyMgmtFunction,
key TeamFunc.RespyMgmtBusinessPartner,
@UI.hidden: true
RespyMgmtTeamType.RespyMgmtTeamCategory,
@UI.lineItem: [{position: 10 }]
@EndUserText.label: 'Team Name'
@UI.textArrangement: #TEXT_FIRST
TeamHeader.TeamName as RespyMgmtTeamName,
@UI.hidden: true
TeamHeader.RespyMgmtTeamType as RespyMgmtTeamType,
@UI.lineItem: [{position: 20 }]
@EndUserText.label: 'Description'
TeamHeader._TeamDescription.TeamDescription as RespyMgmtTeamDescription,
@UI.lineItem: [{position: 40 }]
RespyMgmtTeamCatFuncBfrExcl.RespyMgmtFunctionDescription,
@ObjectModel.association.type: [#TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT]
_Detail
}
where
RespyMgmtTeamType.RespyMgmtTeamCategory = 'EPO'
and TeamHeader.TeamStatus = '01'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RESPYMGMTDIRECTSUPERTEAM",
"I_RESPYMGMTTEAMCATFUNCBFREXCL",
"I_RESPYMGMTTEAMDESCRIPTION",
"I_RESPYMGMTTEAMHEADERDETAIL",
"I_RESPYMGMTTEAMMBRFUNC",
"I_RESPYMGMTTEAMTYPEBASIC"
],
"ASSOCIATED":
[
"C_MFGOPERATORDETAIL"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/