C_MblApplPushNotification

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Mobile Application Push Notification'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
    serviceQuality: #X,
    sizeCategory: #S,
    dataClass: #MIXED
}

@Search.searchable: true
@Metadata.allowExtensions: true
@VDM.viewType: #CONSUMPTION

define root view entity C_MblApplPushNotification
  as select from I_MblApplPushNotification as PushNotification
  composition [1..*] of C_MblApplPushRecipients  as _PushRecipients
  association [1..*] to C_MblApplPushRecipients  as _PushUsers    on $projection.MobileApplicationPushInternal = _PushUsers.MobileApplicationPushInternal
  association [1..1] to C_MblApplPushScenarioDef as _PushScenario on $projection.MblApplPushScenarioInternal = _PushScenario.MblApplPushScenarioInternal
{
  key MobileApplicationPushInternal,
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_MobileApplicationVH', element: 'MobileUserApplication'}}]
      MobileUserApplication,
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
      //@EndUserText.label: 'Scenario'

      MblApplPushScenarioInternal,
      MobileUserRecordInternal,
      MblUsrApplPushSourceType,
      MobileUserApplPushSourceObj,
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
      MobileUserApplPushObjKey,
      MobileUserApplPushObjKeyRef,
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
      @ObjectModel.text.association: '_PushStatusText'
      MobileUserApplicationPushSts,
      //Status icon and Semantic colors

      case MobileUserApplicationPushSts
          when 'NEW' then 0
          when 'ENQUEUE' then 2
          when 'PROCESS' then 0
          when 'SRV_COMP' then 3
          when 'COMPLETED' then 3
          when 'CANCEL' then 1
         else 0
      end  as MblApplPushStatusCriticality,
      MblUsrApplNmbrOfPushRecipients,
      MblUsrApplPushEmlNotifIsEnbld,
      MobileUserApplPushExprtnDteTme,
      MblUsrApplPushProcdDteTme,
      MblUsrApplPushCancelDteTme,
      MobileUserApplPushCmpltDteTme,
      MblApplPushServerCmpltdDteTme,
      MblUsrApplPushEnqueueDteTme,
      MblUsrApplPushEventInternal,
      MobileUserApplPushEvtParam,
      MobileUserApplPushQueuedRFC,
      MobileUserApplPushScenarioPrio,
      MobileUserApplPushHistIsEnbld,
      MblUsrApplPushOutbTrggrIsEnbld,
      MobileUserApplPushRetryIsAllwd,
      MblUsrApplFetchCallbackIsAllwd,
      MobileUserApplPushCreatedBy,
      MblUsrApplPushCreatedDteTme,
      MobileUserApplPushChangedBy,
      MblUsrApplPushChangedDteTme,
      @ObjectModel.virtualElement: true
      @ObjectModel.filter.transformedBy: 'ABAP:CL_EAM_MBL_FILTER_USERNAME'
      @EndUserText.label: 'User Name'
      @UI.selectionField: [{ position: 20 }]
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_MobileApplicationUserVH', element: 'MobileUser'}}]
      cast( '   ' as uname )  as MobileApplicationPushRecipient,
      concat_with_space(MobileUserApplPushObjKey, concat_with_space('-', MobileUserApplication,1), 1) as MobileApplPushNotifTitle,

      /* Associations */
      _PushScenario,
      _PushRecipients,
      _PushUsers,
      _PushStatusText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MBLAPPLPUSHNOTIFICATION"
],
"ASSOCIATED":
[
"C_MBLAPPLPUSHRECIPIENTS",
"C_MBLAPPLPUSHSCENARIODEF",
"I_MBLUSRAPPLPUSHSTATUSTEXT"
],
"BASE":
[
"I_MBLAPPLPUSHNOTIFICATION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/