C_MaterialStockTimeSeries

DDL: C_MATERIALSTOCKTIMESERIES Type: view CONSUMPTION

Material stock for periods by type

C_MaterialStockTimeSeries is a Consumption CDS View that provides data about "Material stock for periods by type" in SAP S/4HANA. It reads from 1 data source (I_MaterialStockTimeSeries) and exposes 26 fields.

1 data source(s) 26 fields

Data Sources (1)

SourceAliasJoin Type
I_MaterialStockTimeSeries I_MaterialStockTimeSeries from

Parameters (4)

NameTypeDefault
P_Language sylangu
P_StartDate vdm_v_start_date
P_EndDate vdm_v_end_date
P_PeriodType nsdm_period_type

Annotations (13)

NameValueLevelField
AbapCatalog.sqlViewName CMATSTOCKTIMESER view
AbapCatalog.preserveKey true view
AbapCatalog.compiler.compareFilter true view
EndUserText.label Material stock for periods by type view
AccessControl.authorizationCheck #PRIVILEGED_ONLY view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.sizeCategory #XXL view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.modelingPattern #ANALYTICAL_QUERY view
VDM.viewType #CONSUMPTION view
Analytics.query true view
Metadata.allowExtensions true view

Fields (26)

KeyFieldSource TableSource FieldDescription
PeriodType PeriodType
EndDate EndDate
YearPeriod YearPeriod
Material Material
Plant Plant
StorageLocation StorageLocation
Batch Batch
Supplier Supplier
SDDocument SDDocument
SDDocumentItem SDDocumentItem
WBSElementInternalID WBSElementInternalID
Customer Customer
InventoryStockType InventoryStockType
InventorySpecialStockType InventorySpecialStockType
CompanyCode CompanyCode
FiscalYearVariant FiscalYearVariant
MaterialBaseUnit MaterialBaseUnit
MatlWrhsStkQtyInMatlBaseUnit MatlWrhsStkQtyInMatlBaseUnit
MaterialName
CompanyCodeName _CompanyCode CompanyCodeName
PlantName _Plant PlantName
StorageLocationName _StorageLocation StorageLocationName
SupplierName _Supplier SupplierName
CustomerName _Customer CustomerName
InventoryStockTypeName
InventorySpecialStockTypeName 
@AbapCatalog: {
                sqlViewName: 'CMATSTOCKTIMESER',
                preserveKey: true,
                compiler.compareFilter: true
              }
@EndUserText.label: 'Material stock for periods by type'
@AccessControl.authorizationCheck:#PRIVILEGED_ONLY
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
                usageType: {
                             sizeCategory: #XXL,
                             serviceQuality: #D,
                             dataClass:#TRANSACTIONAL
                           },
                modelingPattern: #ANALYTICAL_QUERY,
                supportedCapabilities: [#ANALYTICAL_QUERY]
              }
@VDM.viewType: #CONSUMPTION
@Analytics.query : true
@Metadata.allowExtensions: true
define view C_MaterialStockTimeSeries
  with parameters
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_LANGUAGE
    P_Language   : sylangu,
    P_StartDate  : vdm_v_start_date,
    P_EndDate    : vdm_v_end_date,
    P_PeriodType : nsdm_period_type

  as select from I_MaterialStockTimeSeries(P_StartDate:  :P_StartDate,
                                           P_EndDate:    :P_EndDate,
                                           P_PeriodType: :P_PeriodType)
{
  // Period

  PeriodType,
  EndDate,
  YearPeriod,

  // Stock Identifier

  @AnalyticsDetails.query.axis: #ROWS
  @ObjectModel.text.element: ['MaterialName']
  Material,
  @ObjectModel.text.element: ['PlantName']
  Plant,
  @ObjectModel.text.element: ['StorageLocationName']
  StorageLocation,
  Batch,
  @ObjectModel.text.element: ['SupplierName']
  Supplier,
  SDDocument,
  SDDocumentItem,
  WBSElementInternalID,
  @ObjectModel.text.element: ['CustomerName']
  Customer,
  @ObjectModel.text.element: ['InventoryStockTypeName']
  InventoryStockType,
  @ObjectModel.text.element: ['InventorySpecialStockTypeName']
  InventorySpecialStockType,

  // Stock Groups

  CompanyCode,
  @Semantics.fiscal.yearVariant: true
  FiscalYearVariant,

  // Units

  @Semantics.unitOfMeasure
  MaterialBaseUnit,

  // Quantity

  @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
  @AnalyticsDetails.query.axis: #COLUMNS
  MatlWrhsStkQtyInMatlBaseUnit,

  // Names and descriptions

  _Material._Text[1: Language=$parameters.P_Language].MaterialName,
  _CompanyCode.CompanyCodeName,
  _Plant.PlantName,
  _StorageLocation.StorageLocationName,
  _Supplier.SupplierName,
  _Customer.CustomerName,
  _InventoryStockType._Text[1: Language=$parameters.P_Language].InventoryStockTypeName,
  _InventorySpecialStockType._Text[1: Language=$parameters.P_Language].InventorySpecialStockTypeName
}                               
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_CUSTOMER",
"I_INVENTORYSPECIALSTOCKTYPE",
"I_INVENTORYSPECIALSTOCKTYPET",
"I_INVENTORYSTOCKTYPE",
"I_INVENTORYSTOCKTYPET",
"I_MATERIAL",
"I_MATERIALSTOCKTIMESERIES",
"I_MATERIALTEXT",
"I_PLANT",
"I_STORAGELOCATION",
"I_SUPPLIER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More