@AbapCatalog.sqlViewName: 'CMDCHGPROCSTEP'
@EndUserText.label: 'Master Data Change Process Step'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@VDM.viewType: #CONSUMPTION
@ObjectModel: {
// compositionRoot: true,
// transactionalProcessingDelegated:true,
createEnabled:true,
updateEnabled:true,
deleteEnabled:true,
draftEnabled:false,
usageType.serviceQuality: #C,
usageType.sizeCategory : #L,
usageType.dataClass: #MIXED,
entityChangeStateId: 'MDChgProcessUpdateToken' }
@AccessControl.authorizationCheck: #CHECK
@Search.searchable: true
@Metadata.allowExtensions: true
define view C_MasterDataChangeProcessStep
as select from I_MDChgProcessStepTP as Step
association [1..1] to C_MasterDataChangeProcess as _Root on _Root.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
association [1..1] to I_MasterDataChangeProcess as _RootUpdateToken on _RootUpdateToken.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
association [0..*] to I_MDChgProcModifdObjects as _ModifiedObjects on _ModifiedObjects.MasterDataChangeProcess = Step.MasterDataChangeProcess
and _ModifiedObjects.MDChgProcessStep = Step.MDChgProcessStep
association [1..1] to C_MDChangeProcessLogHeader as _MDChangeProcessLogHeader on _MDChangeProcessLogHeader.MDChgProcessStepUUID = $projection.MDChgProcessStepUUID
{
@UI.hidden: true
key MDChgProcessStepUUID,
MasterDataChangeProcessUUID,
@ObjectModel.readOnly: true
_RootUpdateToken.MDChgProcessUpdateToken,
@Search.defaultSearchElement: true
// cast( Step.MasterDataChangeProcess as mdc_process_id_alpha_out ) as
@UI.lineItem: [{ position : 10 }]
MasterDataChangeProcess,
@UI.lineItem: [{ position : 20 }]
MDChgProcessStep,
MDChgProcessStepType,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
MDChgProcessStepDescription,
MDChgProcessStepStatus,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
cast ( ' ' as abap_boolean preserving type ) as MDChangeProcessStepHasError,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
cast ( 0 as abap.int4 ) as MDChgProcStepNumberOfWarnings,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
cast ( 0 as abap.int4 ) as MDChgProcessStepNumberOfErrors,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
cast ( 0 as abap.int4 ) as MDChgProcStpNumberOfExceptions,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
sum ( _ModifiedObjects.MDChgProcModifdObjectsCount ) as MDChgProcModifdObjectsCount,
// @ObjectModel.readOnly: true
// @ObjectModel.virtualElement: true
// @ObjectModel.virtualElementCalculatedBy: 'ABAP:cl_mdc_process_step_calc_exit'
// cast ( ' ' as abap_boolean preserving type ) as MDChgProcStpHasMappingAdapter,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
@Semantics.quantity.unitOfMeasure: 'MDChangeProcStepProgressUnit'
cast( 0 as abap.int1 ) as MDChgProcStpProgressRatioInPct,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
cast( '%' as msehi ) as MDChangeProcStepProgressUnit,
MDChgProcessStepAdapter,
MDChgProcessStepAdapterConfign,
MDChgProcessStepChkPointIsActv,
MDChgProcessStepOriglNumber,
MDChgProcessStepOriglSqncNmbr,
MDChgProcessStepStartIsReqd,
MDChgProcessSrceObjectTypeCode,
MDChgProcessStepFilterChain,
MDChgProcessStepStartDateTime,
MDChgProcessStepFinishDateTime,
MDChgProcessStepConfign,
MDChgProcessStpOwnConfignIsRqd,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
cast ( ' ' as abap_boolean preserving type ) as MDChangeProcessStepIsTransient,
MDChgProcIsAdhocStep,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
cast ( ' ' as abap_boolean preserving type ) as MDChgProcStepScheduleIsRecmdd,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
cast( '' as mdc_business_system ) as MDChgProcessSrceSystem, //for cross app navigation to SOM
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
cast( '' as mdc_source_id ) as MDChgProcessSrceObject, //for cross app navigation to SOM
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
cast ( '' as boole_d ) as MDChgProcStepIsRollbackAllowed,
MDChgProcessStepWrkflwDefID,
MDChgProcessStepWrkflwHandle,
MDChgProcessStepWrkflwSts,
MDChgProcessStepWrkflwOvrlDcsn,
// count( distinct MDChgProcessStepUUID ) as MDChgProcessStepsCount,
/* Associations */
//I_MDChgProcessStepTP
@ObjectModel.association.type: [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
_Root,
// @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
// @ObjectModel.readOnly: true
_MDChangeProcessLogHeader,
_ModifiedObjects
}
group by
MDChgProcessStepUUID,
MasterDataChangeProcessUUID,
_RootUpdateToken.MDChgProcessUpdateToken,
MasterDataChangeProcess,
MDChgProcessStep,
MDChgProcessStepType,
MDChgProcessStepDescription,
MDChgProcessStepStatus,
MDChgProcessStepAdapter,
MDChgProcessStepAdapterConfign,
MDChgProcessStepChkPointIsActv,
MDChgProcessStepOriglNumber,
MDChgProcessStepOriglSqncNmbr,
MDChgProcessStepStartIsReqd,
MDChgProcessSrceObjectTypeCode,
MDChgProcessStepFilterChain,
MDChgProcessStepStartDateTime,
MDChgProcessStepFinishDateTime,
MDChgProcessStepConfign,
MDChgProcessStpOwnConfignIsRqd,
MDChgProcIsAdhocStep,
MDChgProcessStepWrkflwDefID,
MDChgProcessStepWrkflwHandle,
MDChgProcessStepWrkflwSts,
MDChgProcessStepWrkflwOvrlDcsn
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MASTERDATACHANGEPROCESS",
"I_MDCHGPROCESSSTEPTP",
"I_MDCHGPROCMODIFDOBJECTS"
],
"ASSOCIATED":
[
"C_MASTERDATACHANGEPROCESS",
"C_MDCHANGEPROCESSLOGHEADER",
"I_MASTERDATACHANGEPROCESS",
"I_MDCHGPROCMODIFDOBJECTS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/