C_MaintenanceOrderPhaseControl

@EndUserText.label: 'Maintenance Order Phase Control'
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.semanticKey: [ 'MaintenanceOrder', 'MaintenancePhaseControl' ]

@VDM.viewType: #CONSUMPTION
@AccessControl.personalData.blocking: #('TRANSACTIONAL')
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}

define view entity C_MaintenanceOrderPhaseControl
  as select from           I_MaintenanceOrderPhaseControl as MaintOrderPhaseControl

    left outer to one join I_EAMOverallStatusPhaseMapping as EAMOverallStatusPhaseMapping on  MaintOrderPhaseControl.EAMOverallStatusProfile  = EAMOverallStatusPhaseMapping.EAMOverallStatusProfile
                                                                                          and MaintOrderPhaseControl.EAMBlockerCodeEntityType = EAMOverallStatusPhaseMapping.EAMOverallStatusEntity
                                                                                          and MaintOrderPhaseControl.EAMProcessPhaseCode      = EAMOverallStatusPhaseMapping.EAMProcessPhaseCode
                                                                                          and MaintOrderPhaseControl.EAMProcessSubPhaseCode   = EAMOverallStatusPhaseMapping.EAMProcessSubPhaseCode

    left outer to one join I_EAMOverallStatus             as EAMOverallStatus             on  MaintOrderPhaseControl.EAMOverallStatusProfile  = EAMOverallStatus.EAMOverallStatusProfile
                                                                                          and MaintOrderPhaseControl.EAMBlockerCodeEntityType = EAMOverallStatus.EAMOverallStatusEntity
                                                                                          and EAMOverallStatusPhaseMapping.EAMOverallStatus   = EAMOverallStatus.EAMOverallStatus

    left outer to one join I_EAMOverallStatusPhaseMapping as EAMOverallStatusPhaseMapOrd  on  MaintOrderPhaseControl.EAMOverallStatusProfile     = EAMOverallStatusPhaseMapOrd.EAMOverallStatusProfile
                                                                                          and MaintOrderPhaseControl.EAMBlockerCodeEntityType    = EAMOverallStatusPhaseMapOrd.EAMOverallStatusEntity
                                                                                          and MaintOrderPhaseControl.MaintOrdProcessPhaseCode    = EAMOverallStatusPhaseMapOrd.EAMProcessPhaseCode
                                                                                          and MaintOrderPhaseControl.MaintOrdProcessSubPhaseCode = EAMOverallStatusPhaseMapOrd.EAMProcessSubPhaseCode

    left outer to one join I_EAMOverallStatus             as EAMOverallStatusOrd          on  MaintOrderPhaseControl.EAMOverallStatusProfile  = EAMOverallStatusOrd.EAMOverallStatusProfile
                                                                                          and MaintOrderPhaseControl.EAMBlockerCodeEntityType = EAMOverallStatusOrd.EAMOverallStatusEntity
                                                                                          and EAMOverallStatusPhaseMapOrd.EAMOverallStatus    = EAMOverallStatusOrd.EAMOverallStatus

  association [0..*] to I_EAMProcessPhaseText          as _EAMProcessPhaseText          on _EAMProcessPhaseText.EAMProcessPhaseCode = $projection.EAMProcessPhaseCode
  association [0..*] to I_EAMProcessSubPhaseText       as _EAMProcessSubPhaseText       on _EAMProcessSubPhaseText.EAMProcessSubPhaseCode = $projection.EAMProcessSubPhaseCode
  association [0..*] to I_MaintObjPhaseControlStateTxt as _MaintObjPhaseControlStateTxt on _MaintObjPhaseControlStateTxt.MaintObjPhaseControlStateCode = $projection.MaintObjPhaseControlStateCode

{

  key MaintOrderPhaseControl.MaintenanceOrder,
      @ObjectModel.text.element: ['MaintenancePhaseControlName']
  key MaintOrderPhaseControl.MaintenancePhaseControl,
      MaintOrderPhaseControl.MaintenancePhaseControlName,
      MaintOrderPhaseControl.MaintenancePhaseControlText,
      MaintOrderPhaseControl.MaintPhseCtrlIsSetAutomly,
      MaintOrderPhaseControl.MaintPhaseControlAuthorityCode,
      @ObjectModel.text.element: ['MaintProcgPhseCtrlActvtnDesc']
      MaintOrderPhaseControl.MaintProcgPhseCtrlActvtnCode,
      @ObjectModel.text.element: ['EAMProcessPhaseCodeDesc']
      MaintOrderPhaseControl.EAMProcessPhaseCode,
      @ObjectModel.text.element: ['EAMProcessSubPhaseCodeDesc']
      MaintOrderPhaseControl.EAMProcessSubPhaseCode,
      @Semantics.booleanIndicator:true
      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      MaintOrderPhaseControl.MaintObjPhseCtrlStatusIsActive,

      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      MaintOrderPhaseControl.StatusObject,
      MaintOrderPhaseControl.MaintenanceUserStatusCode,
      MaintOrderPhaseControl.EAMOverallStatusProfile,
      MaintOrderPhaseControl.MaintUserStatusProfileCode,

      MaintOrderPhaseControl.MaintenanceOrderType,
      MaintOrderPhaseControl.MaintenancePlanningPlant,
      MaintOrderPhaseControl.EAMBlockerCodeEntityType,

      @ObjectModel.text.element: ['MaintObjPhaseControlStateDesc']
      MaintOrderPhaseControl.MaintObjPhaseControlStateCode,

      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      @Semantics.booleanIndicator: true
      case
        when EAMOverallStatusOrd.EAMOverallStatusSequence is null then ' '
        when EAMOverallStatus.EAMOverallStatusSequence is null then 'X'
        when EAMOverallStatus.EAMOverallStatusSequence > EAMOverallStatusOrd.EAMOverallStatusSequence then 'X'
        else ' '
      end as MaintPhaseControlIsRelevant,

      @Semantics.text: true
      MaintOrderPhaseControl._MaintPhseCtrlActivationCode._MaintPhseCtrlActvtnCodeTxt[1:Language = $session.system_language ].MaintProcgPhseCtrlActvtnDesc,
      @Semantics.text: true
      _EAMProcessPhaseText[1:Language = $session.system_language ].EAMProcessPhaseCodeDesc,
      @Semantics.text: true
      _EAMProcessSubPhaseText[1:Language = $session.system_language ].EAMProcessSubPhaseCodeDesc,
      @Semantics.text: true
      _MaintObjPhaseControlStateTxt[1:Language = $session.system_language ].MaintObjPhaseControlStateDesc,

      MaintOrderPhaseControl._MaintenanceOrder.MaintOrdProcessPhaseCode,
      MaintOrderPhaseControl._MaintenanceOrder.MaintOrdProcessSubPhaseCode,

      MaintOrderPhaseControl._MaintObjPhseCtrlCodeChgSet,
      MaintOrderPhaseControl._MaintObjPhseCtrlCodeChgReset,
      MaintOrderPhaseControl._MaintenanceOrder
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EAMOVERALLSTATUS",
"I_EAMOVERALLSTATUSPHASEMAPPING",
"I_EAMPROCESSPHASETEXT",
"I_EAMPROCESSSUBPHASETEXT",
"I_MAINTENANCEORDER",
"I_MAINTENANCEORDERPHASECONTROL",
"I_MAINTOBJPHASECONTROLSTATETXT",
"I_MAINTPHSECTRLACTIVATIONCODE",
"I_MAINTPHSECTRLACTVTNCODETXT"
],
"ASSOCIATED":
[
"I_MAINTENANCEORDER",
"I_MAINTORDERPHSECTRLCHGHIST"
],
"BASE":
[
"I_MAINTENANCEORDERPHASECONTROL"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/