C_MaintWrkReqDamageCodeGroupVH

@AbapCatalog.sqlViewName: 'CMWRKRQCDGRP'
@VDM.viewType: #CONSUMPTION

@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_InspectionCodeGroupText']
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
  usageType: {
    serviceQuality: #B,
    sizeCategory: #M,
    dataClass: #CUSTOMIZING }
}
@Search.searchable: true
@Consumption.ranked: true
@ObjectModel.dataCategory: #VALUE_HELP
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
define view C_MaintWrkReqDamageCodeGroupVH
  as select from I_InspectionCodeGroup
  //inner join I_PMNotificationType as _PMNotificationType on  _PMNotificationType.MaintNotifCodgCatalogTypeCode   = I_InspectionCodeGroup.InspectionCatalog


  association [0..*] to I_Inspectioncodegrouptext as _InspectionCodeGroupText on  _InspectionCodeGroupText.InspectionCatalog   = $projection.InspectionCatalog
                                                                              and _InspectionCodeGroupText.InspectionCodeGroup = $projection.InspectionCodeGroup
{

      @Search: { defaultSearchElement: true , ranking: #HIGH, fuzzinessThreshold: 0.7}
      @Consumption.filter.defaultValue: 'D'
  key I_InspectionCodeGroup.InspectionCatalog,
      @Search: { defaultSearchElement: true , ranking: #HIGH, fuzzinessThreshold: 0.7 }
          //--[ GENERATED:012:GFBfhxvv7jY4hYOuhNduX0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_InspectionCodeGroupStdVH',
                     element: 'InspectionCodeGroup' },
          additionalBinding: [{ localElement: 'InspectionCatalog',
                                element: 'InspectionCatalog' }]
        }]
      // ]--GENERATED

      @ObjectModel.text.element: ['InspSpecAddlCodeGroupText']
      @EndUserText.label: 'Failure Mode Group'
  key I_InspectionCodeGroup.InspectionCodeGroup,

      @UI.hidden: true
      I_InspectionCodeGroup.CodeGroupStatus,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      @ObjectModel.filter.transformedBy: 'ABAP:CL_EAM_MALF_CODE_VH_EXIT'
      cast ('' as rbnr) as CatalogProfile,
      @Search: { defaultSearchElement: true, ranking: #LOW,  fuzzinessThreshold: 0.7}
      @EndUserText.label: 'Failure Mode Group Text'
      _InspectionCodeGroupText[1: Language = $session.system_language ].InspSpecAddlCodeGroupText,
      _InspectionCodeGroupText

}
where
      I_InspectionCodeGroup.CodeGroupStatus     = '2' // Released

  and I_InspectionCodeGroup.CodeGroupIsInactive = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSPECTIONCODEGROUP",
"I_INSPECTIONCODEGROUPTEXT"
],
"ASSOCIATED":
[
"I_INSPECTIONCODEGROUPTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/