C_MaintTaskListQuickVw

@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CMAINTTASKLISTQW'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Task list long text quickview'

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.representativeKey: 'TaskList'

@UI.headerInfo : {
  typeName: 'Task List',
  typeNamePlural: 'Task Lists',
   typeImageUrl: 'sap-icon://Fiori2/F0247'

}
define view C_MaintTaskListQuickVw
  as select from I_MaintenanceTaskList
{
@UI.facet: [{
           purpose: #QUICK_VIEW,
           type: #FIELDGROUP_REFERENCE,
           targetQualifier: 'TaskListQuickView'
         }]
  @EndUserText.label: 'Task List Type'
  @UI:{
        fieldGroup: {
          importance: #HIGH,
          qualifier: 'TaskListQuickView',
          position: 20
        }
      }
      @ObjectModel.text.element:  [ 'BillOfOperationsTypeName' ]
      @UI.textArrangement: #TEXT_FIRST
  key TaskListType,
  key TaskListGroup,
  key TaskListGroupCounter,
  
  key case ltrim( TaskListGroup, '0')
               when '' then case ltrim( TaskListGroupCounter, '0')
                               when '' then concat( TaskListType, '/0/0' )
                               else concat( concat( TaskListType, '/0/' ), ltrim( TaskListGroupCounter, '0') )
                            end
               else case ltrim( TaskListGroupCounter, '0')
                       when '' then concat( concat( concat( TaskListType, '/' ), ltrim( TaskListGroup, '0') ), '/0' )
                       else concat( concat( concat( concat( TaskListType, '/' ), ltrim( TaskListGroup, '0') ), '/' ), ltrim( TaskListGroupCounter, '0') )
                    end
             end                                                                                                          as  TaskList,
   TaskListDesc,
   @EndUserText.label: 'Task List type Name'
    _TaskListType._Text[1:Language = $session.system_language].BillOfOperationsTypeName,
   @EndUserText.label: 'Planning Plant'
  @UI:{
        fieldGroup: {
          importance: #HIGH,
          qualifier: 'TaskListQuickView',
          position: 60
        }
      }
       @ObjectModel.text.element:  [ 'PlantName' ]
      @UI.textArrangement: #TEXT_FIRST
      Plant,
   //MaintenancePlanningPlant,

   @EndUserText.label: 'Planning Plant Name'
   _Plant.PlantName,
   @EndUserText.label: 'System Status'
  @UI:{
        fieldGroup: {
          importance: #HIGH,
          qualifier: 'TaskListQuickView',
          position: 90
        }
      }
       @ObjectModel.text.element:  [ 'TaskListStatusDesc' ]
      @UI.textArrangement: #TEXT_FIRST
   TaskListStatus,
   _TaskListStatus._Text[1:Language = $session.system_language].BillOfOperationsStatusDesc  as  TaskListStatusDesc,
   @EndUserText.label: 'Work Center'
  @UI:{
        fieldGroup: {
          importance: #HIGH,
          qualifier: 'TaskListQuickView',
          position: 70
        }
      }
       @ObjectModel.text.element:  [ 'WorkCenterText' ]
      @UI.textArrangement: #TEXT_FIRST
   WorkCenterInternalID,
    @EndUserText.label: 'Work Center Text'
   _WorkCenter._Text[1:Language = $session.system_language].WorkCenterText,
    @EndUserText.label: 'Valid From'
  @UI:{
        fieldGroup: {
          importance: #HIGH,
          qualifier: 'TaskListQuickView',
          position: 40
        }
      }
   ValidityStartDate as KeyDate,
    @EndUserText.label: 'Maintenance Strategy'
  @UI:{
        fieldGroup: {
          importance: #HIGH,
          qualifier: 'TaskListQuickView',
          position: 30
        }
      }
       @ObjectModel.text.element:  [ 'MaintenanceStrategyDesc' ]
      @UI.textArrangement: #TEXT_FIRST
   MaintenanceStrategy,
    @EndUserText.label: 'Maintenance Strategy Text'
   _MaintenanceStrategy._MaintenanceStrategyText[1:Language = $session.system_language].MaintenanceStrategyDesc,
   @EndUserText.label: 'Long Text'
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_TASKLIST_LTXT_EXIT'
      @Semantics.text: true
      @UI:{
        fieldGroup: {
          importance: #HIGH,
          qualifier: 'TaskListQuickView',
          position: 10
        }
      }
      cast (' ' as abap.sstring( 1333 ))                                                                            as  LongText,
       @EndUserText.label: 'Work Center Plant'
  @UI:{
        fieldGroup: {
          importance: #HIGH,
          qualifier: 'TaskListQuickView',
          position: 80
        }
      }
      @ObjectModel.text.element:  [ 'WorkCenterPlantName' ]
      @UI.textArrangement: #TEXT_FIRST
      _WorkCenter.Plant                                                                        as  WorkCenterPlant,
      @EndUserText.label: 'Work Center Plant Name'
      _WorkCenter._Plant.PlantName                                                             as  WorkCenterPlantName,
       @EndUserText.label: 'Planner Group'
  @UI:{
        fieldGroup: {
          importance: #HIGH,
          qualifier: 'TaskListQuickView',
          position: 50
        }
      }
      @ObjectModel.text.element:  [ 'ResponsiblePlannerGroupName' ]
      @UI.textArrangement: #TEXT_FIRST
      ResponsiblePlannerGroup,
        @EndUserText.label: 'Responsible Planner Group Text'
      _ResponsiblePlannerGroup.ResponsiblePlannerGroupName
      
  
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONSSTATUS",
"I_BILLOFOPERATIONSSTATUSTEXT",
"I_BILLOFOPERATIONSTYPETEXT",
"I_MAINTENANCESTRATEGY",
"I_MAINTENANCESTRATEGYT",
"I_MAINTENANCETASKLIST",
"I_MAINTENANCETASKLISTTYPE",
"I_PLANT",
"I_RESPONSIBLEPLANNERGROUP",
"I_WORKCENTER",
"I_WORKCENTERTEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/