C_MaintOrderOpPhaseControl

@EndUserText.label: 'Maintenance Order Op Phase Control'
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.semanticKey:  [ 'MaintenanceOrder', 'MaintenanceOrderOperation', 'MaintenanceOrderSubOperation', 'MaintenancePhaseControl' ]

@VDM.viewType: #CONSUMPTION
@AccessControl.personalData.blocking: #('TRANSACTIONAL')
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}

define view entity C_MaintOrderOpPhaseControl
  as select from           I_MaintOrderOpPhaseControl     as MaintOrderOpPhaseControl

    left outer to one join I_EAMOverallStatusPhaseMapping as EAMOverallStatusPhaseMapping on  MaintOrderOpPhaseControl.EAMOverallStatusProfile  = EAMOverallStatusPhaseMapping.EAMOverallStatusProfile
                                                                                          and MaintOrderOpPhaseControl.EAMBlockerCodeEntityType = EAMOverallStatusPhaseMapping.EAMOverallStatusEntity
                                                                                          and MaintOrderOpPhaseControl.EAMProcessPhaseCode      = EAMOverallStatusPhaseMapping.EAMProcessPhaseCode
                                                                                          and MaintOrderOpPhaseControl.EAMProcessSubPhaseCode   = EAMOverallStatusPhaseMapping.EAMProcessSubPhaseCode

    left outer to one join I_EAMOverallStatus             as EAMOverallStatus             on  MaintOrderOpPhaseControl.EAMOverallStatusProfile  = EAMOverallStatus.EAMOverallStatusProfile
                                                                                          and MaintOrderOpPhaseControl.EAMBlockerCodeEntityType = EAMOverallStatus.EAMOverallStatusEntity
                                                                                          and EAMOverallStatusPhaseMapping.EAMOverallStatus     = EAMOverallStatus.EAMOverallStatus

    left outer to one join I_EAMOverallStatusPhaseMapping as EAMOverallStatusPhMapOrdOp   on  MaintOrderOpPhaseControl.EAMOverallStatusProfile       = EAMOverallStatusPhMapOrdOp.EAMOverallStatusProfile
                                                                                          and MaintOrderOpPhaseControl.EAMBlockerCodeEntityType      = EAMOverallStatusPhMapOrdOp.EAMOverallStatusEntity
                                                                                          and MaintOrderOpPhaseControl.MaintOrdOpProcessPhaseCode    = EAMOverallStatusPhMapOrdOp.EAMProcessPhaseCode
                                                                                          and MaintOrderOpPhaseControl.MaintOrdOpProcessSubPhaseCode = EAMOverallStatusPhMapOrdOp.EAMProcessSubPhaseCode

    left outer to one join I_EAMOverallStatus             as EAMOverallStatusOrdOp        on  MaintOrderOpPhaseControl.EAMOverallStatusProfile  = EAMOverallStatusOrdOp.EAMOverallStatusProfile
                                                                                          and MaintOrderOpPhaseControl.EAMBlockerCodeEntityType = EAMOverallStatusOrdOp.EAMOverallStatusEntity
                                                                                          and EAMOverallStatusPhMapOrdOp.EAMOverallStatus       = EAMOverallStatusOrdOp.EAMOverallStatus

  association [0..*] to I_EAMProcessPhaseText          as _EAMProcessPhaseText          on _EAMProcessPhaseText.EAMProcessPhaseCode = $projection.EAMProcessPhaseCode
  association [0..*] to I_EAMProcessSubPhaseText       as _EAMProcessSubPhaseText       on _EAMProcessSubPhaseText.EAMProcessSubPhaseCode = $projection.EAMProcessSubPhaseCode
  association [0..*] to I_MaintObjPhaseControlStateTxt as _MaintObjPhaseControlStateTxt on _MaintObjPhaseControlStateTxt.MaintObjPhaseControlStateCode = $projection.MaintObjPhaseControlStateCode
{

  key MaintOrderOpPhaseControl.MaintenanceOrder,
  key MaintOrderOpPhaseControl.MaintenanceOrderOperation,
  key MaintOrderOpPhaseControl.MaintenanceOrderSubOperation,
      @ObjectModel.text.element: ['MaintenancePhaseControlName']
  key MaintOrderOpPhaseControl.MaintenancePhaseControl,
      MaintOrderOpPhaseControl.MaintenancePhaseControlName,
      MaintOrderOpPhaseControl.MaintenancePhaseControlText,
      MaintOrderOpPhaseControl.MaintPhseCtrlIsSetAutomly,
      MaintOrderOpPhaseControl.MaintPhaseControlAuthorityCode,
      @ObjectModel.text.element: ['MaintProcgPhseCtrlActvtnDesc']
      MaintOrderOpPhaseControl.MaintProcgPhseCtrlActvtnCode,
      @ObjectModel.text.element: ['EAMProcessPhaseCodeDesc']
      MaintOrderOpPhaseControl.EAMProcessPhaseCode,
      @ObjectModel.text.element: ['EAMProcessSubPhaseCodeDesc']
      MaintOrderOpPhaseControl.EAMProcessSubPhaseCode,
      @Semantics.booleanIndicator:true
      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      MaintOrderOpPhaseControl.MaintObjPhseCtrlStatusIsActive,

      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      MaintOrderOpPhaseControl.StatusObject,
      MaintOrderOpPhaseControl.MaintenanceUserStatusCode,
      MaintOrderOpPhaseControl.EAMOverallStatusProfile,
      MaintOrderOpPhaseControl.MaintUserStatusProfileCode,

      MaintOrderOpPhaseControl.MaintenanceOrderType,
      MaintOrderOpPhaseControl.MaintenancePlanningPlant,
      MaintOrderOpPhaseControl.EAMBlockerCodeEntityType,

      @ObjectModel.text.element: ['MaintObjPhaseControlStateDesc']
      MaintOrderOpPhaseControl.MaintObjPhaseControlStateCode,

      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      @Semantics.booleanIndicator: true
      case
        when EAMOverallStatusOrdOp.EAMOverallStatusSequence is null then ' '
        when EAMOverallStatus.EAMOverallStatusSequence is null then 'X'
        when EAMOverallStatus.EAMOverallStatusSequence > EAMOverallStatusOrdOp.EAMOverallStatusSequence then 'X'
        else ' '
      end as MaintPhaseControlIsRelevant,

      @Semantics.text: true
      MaintOrderOpPhaseControl._MaintPhseCtrlActivationCode._MaintPhseCtrlActvtnCodeTxt[1:Language = $session.system_language ].MaintProcgPhseCtrlActvtnDesc,
      @Semantics.text: true
      _EAMProcessPhaseText[1:Language = $session.system_language ].EAMProcessPhaseCodeDesc,
      @Semantics.text: true
      _EAMProcessSubPhaseText[1:Language = $session.system_language ].EAMProcessSubPhaseCodeDesc,
      @Semantics.text: true
      _MaintObjPhaseControlStateTxt[1:Language = $session.system_language ].MaintObjPhaseControlStateDesc,

      MaintOrderOpPhaseControl._MaintenanceOrderOperation.MaintOrdOpProcessPhaseCode,
      MaintOrderOpPhaseControl._MaintenanceOrderOperation.MaintOrdOpProcessSubPhaseCode,

      MaintOrderOpPhaseControl._MaintObjPhseCtrlCodeChgSet,
      MaintOrderOpPhaseControl._MaintObjPhseCtrlCodeChgReset,
      MaintOrderOpPhaseControl._MaintenanceOrder,
      MaintOrderOpPhaseControl._MaintenanceOrderOperation
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EAMOVERALLSTATUS",
"I_EAMOVERALLSTATUSPHASEMAPPING",
"I_EAMPROCESSPHASETEXT",
"I_EAMPROCESSSUBPHASETEXT",
"I_MAINTOBJPHASECONTROLSTATETXT",
"I_MAINTORDEROPERANDSUBOPER",
"I_MAINTORDEROPPHASECONTROL",
"I_MAINTPHSECTRLACTIVATIONCODE",
"I_MAINTPHSECTRLACTVTNCODETXT"
],
"ASSOCIATED":
[
"I_MAINTENANCEORDER",
"I_MAINTORDEROPERANDSUBOPER",
"I_MAINTORDEROPPHSECTRLCHGHIST"
],
"BASE":
[
"I_MAINTORDEROPPHASECONTROL"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/