C_MaintOrderConfirmationTP

@AbapCatalog.sqlViewName: 'CMAINTORDCONFTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Order Confirmation'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #CONSUMPTION

@ObjectModel: {
  semanticKey: ['MaintOrderConf', 'MaintOrderConfCntrValue'],
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,
  transactionalProcessingDelegated: true,
  compositionRoot:true,
  draftEnabled: true
}

define view C_MaintOrderConfirmationTP
  as select from I_MaintenanceOrderConfTP
  association [0..1] to C_MaintOrderOperationTP as _MaintOrderOperationTP        on  _MaintOrderOperationTP.MaintenanceOrder          = $projection.MaintenanceOrder
                                                                                 and _MaintOrderOperationTP.MaintenanceOrderOperation = $projection.MaintenanceOrderOperation
  association [0..1] to I_PMTimeUnitVH          as _ActualWorkUnit               on  _ActualWorkUnit.UnitOfMeasure = $projection.ActualWorkQuantityUnit
  association [0..1] to I_PMTimeUnitVH          as _ActualWorkExtQuantityUnit    on  _ActualWorkExtQuantityUnit.UnitOfMeasure = $projection.ActualWorkExternalQuantityUnit
  association [0..1] to I_PMTimeUnitVH          as _RemainingWorkExtQuantityUnit on  _RemainingWorkExtQuantityUnit.UnitOfMeasure = $projection.RemainingWorkExtQuantityUnit
{
  key I_MaintenanceOrderConfTP.MaintOrderConf,
  key I_MaintenanceOrderConfTP.MaintOrderConfCntrValue,
      I_MaintenanceOrderConfTP.MaintOrderConfForEdit,
      I_MaintenanceOrderConfTP.MaintOrderConfCntrValueForEdit,

      I_MaintenanceOrderConfTP.MaintenanceOrder,
      I_MaintenanceOrderConfTP.MaintenanceOrderOperation,
      cast( I_MaintenanceOrderConfTP.MaintenanceOrderSubOperation as maintenanceordersuboperation preserving type ) as MaintenanceOrderSubOperation,

      @Semantics.quantity.unitOfMeasure: 'ActualWorkQuantityUnit'
      I_MaintenanceOrderConfTP.ActualWorkQuantity,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_ActualWorkUnit'
      I_MaintenanceOrderConfTP.ActualWorkQuantityUnit,
      I_MaintenanceOrderConfTP.ActualWorkQtyInExternalUnit,
      @Consumption.valueHelp: '_ActualWorkExtQuantityUnit'
      I_MaintenanceOrderConfTP.ActualWorkExternalQuantityUnit,
      I_MaintenanceOrderConfTP.PostingDate,
      @EndUserText.label: 'Final Confirmation'
      I_MaintenanceOrderConfTP.IsFinalConfirmation,
      I_MaintenanceOrderConfTP.RemainingWorkQuantity,
      I_MaintenanceOrderConfTP.RemainingWorkQuantityUnit,
      I_MaintenanceOrderConfTP.RemainingWorkQtyInExternalUnit,
      @Consumption.valueHelp: '_RemainingWorkExtQuantityUnit'
      I_MaintenanceOrderConfTP.RemainingWorkExtQuantityUnit,
      I_MaintenanceOrderConfTP.Plant,

      @Consumption.valueHelpDefinition: [
          { entity:  { name:    'I_PersWrkAgrmtSrchHelp',
                       element: 'PersonWorkAgreement' }
          }]
      @EndUserText.label: 'Performed By'
      I_MaintenanceOrderConfTP.PersonnelNumber,
      _MaintOrderOperationTP,
      _ActualWorkUnit,
      _ActualWorkExtQuantityUnit,
      _RemainingWorkExtQuantityUnit,

      _MaintenanceOrder,
      _PersonnelName
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTENANCEORDERCONFTP"
],
"ASSOCIATED":
[
"C_MAINTORDEROPERATIONTP",
"I_MAINTENANCEORDER",
"I_PMTIMEUNITVH",
"I_WORKFORCEPERSON"
],
"BASE":
[
"I_MAINTENANCEORDERCONFTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/