C_MaintNotificationQuickVw

@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CNOTIFQV'
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@EndUserText.label: 'Quick View for Maintenance Notification'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.representativeKey: 'MaintenanceNotification'

@UI.headerInfo : { typeName: 'Maintenance Notification',
                   typeNamePlural: 'Maintenance Notifications',
                   typeImageUrl: 'sap-icon://request',

                   imageUrl: 'MaintNotificationThumbnailURL'}

define view C_MaintNotificationQuickVw
  as select from I_MaintNotificationTechObj

{

      @UI.facet: [{ purpose: #QUICK_VIEW, type: #FIELDGROUP_REFERENCE, targetQualifier: 'MaintNotificationQuickVw' }]

      // Maintenance Notification ID (Key)

      @UI: { fieldGroup:     [{ qualifier:'MaintNotificationQuickVw', position: 10 }]}
      @UI.hidden: true
      @EndUserText.label: 'Maintenance Notification'
  key MaintenanceNotification,

      // Maintenance Notification Image

      @Semantics.imageUrl: true
      @EndUserText.label: 'Image'
      @Consumption.filter.hidden: true
      //      'sap-icon://request'                                               as MaintNotificationThumbnailURL,

      cast( 'sap-icon://request' as string128 )                          as MaintNotificationThumbnailURL,

      // Maintenance Notification Internal ID ( Status Object Mapping)

      @UI.hidden: true
      MaintNotifInternalID,

      // Maintenance Notification Description

      @UI: { fieldGroup:     [{ qualifier:'MaintNotificationQuickVw', position: 20}] }
      @EndUserText.label: 'Description'
      @UI.hidden: true
      NotificationText,

      // Maintenance Notification Long Text

      @Semantics.text: true
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_NTF_LTXT_EXIT'
      @UI.fieldGroup: [{ qualifier: 'MaintNotificationQuickVw', position: 30 }]
      @UI.multiLineText: true
      @EndUserText.label: 'Long Text'
      cast( '' as eams_ltext )                                           as MaintNotificationLongText,

      // Maintenance Notification Type

      @UI: { fieldGroup:     [{ qualifier:'MaintNotificationQuickVw', position: 40 }]}
      @ObjectModel.text.element:  [ 'NotificationTypeName' ]
      @EndUserText.label: 'Notification Type'
      @UI.textArrangement: #TEXT_FIRST
      NotificationType,

      @EndUserText.label: 'Notification Type Name'
      _PMNotificationType._Text[1:Language=$session.system_language].NotificationTypeName,


      // Maintenance Notification Priority

      @UI: { fieldGroup:     [{ qualifier:'MaintNotificationQuickVw', position: 50}] }
      @ObjectModel.text.element: 'MaintPriorityDesc'
      @EndUserText.label: 'Priority'
      @UI.textArrangement: #TEXT_FIRST
      MaintPriority,
      @EndUserText.label: 'Priority Text'
      _PMNotificationPriority._Text[1:Language=$session.system_language].MaintPriorityDesc,

      // Maintenance Notification IsBreakdown?

      @UI: { fieldGroup:     [{ qualifier:'MaintNotificationQuickVw', position:  70 }] }
      @EndUserText.label: 'Breakdown'
      MaintenanceObjectIsDown,

      // Maintenance Notification Creation Date

      @UI: { fieldGroup:     [{ qualifier:'MaintNotificationQuickVw', position: 80}] }
      @EndUserText.label: 'Notification Date'
      NotificationCreationDate,

      // Maintenance Notification Person Responsible

      @UI: { fieldGroup:     [{ qualifier:'MaintNotificationQuickVw', position: 90}] }
      @EndUserText.label: 'Person Responsible'
      @ObjectModel.text.element:  [ 'PersonResponsibleName' ]
      @UI.textArrangement: #TEXT_FIRST
      PersonResponsible,

      // Maintenance Notification Person Responsible Name

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_OBJPG_MNTNTF_PART_EXIT'
      @EndUserText.label: 'Person Responsible Name'
      cast('' as eams_person_responsible_name)                           as PersonResponsibleName,

      // Maintenance Notification Parnter Function (Person Responsible)

      @UI.hidden: true
      cast(_PMNotificationType.MaintNotifRespPartnerFunction  as  char2) as MaintNotifRespPartnerFunction,

      // Maintanence Notification System Status

      @UI: { fieldGroup:     [{ qualifier:'MaintNotificationQuickVw', position: 100}] }
      @EndUserText.label: 'System Status'
      @ObjectModel: { virtualElement: true, virtualElementCalculatedBy: 'ABAP:CL_EAM_MNTNTF_STS_EXIT' }
      cast ('' as vdm_j_system_status_concat_t)                          as ConcatenatedActiveSystStsName,

      // Maintanence Notification User Status

      @UI: { fieldGroup:     [{ qualifier:'MaintNotificationQuickVw', position: 110}] }
      @EndUserText.label: 'User Status'
      @ObjectModel: { virtualElement: true, virtualElementCalculatedBy: 'ABAP:CL_EAM_MNTNTF_STS_EXIT' }
      cast ('' as vdm_j_user_status_concat_t)                            as ConcatenatedActiveUserStsName,

      //    // IME: 2002 LACD

      @UI: { fieldGroup:     [{ qualifier:'MaintNotificationQuickVw', position: 60}] }
      LatestAcceptableCompletionDate
      //    // IME: 2002 LACD



}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTNOTIFICATIONTECHOBJ",
"I_PMNOTIFICATIONPRIORITY",
"I_PMNOTIFICATIONPRIORITYTEXT",
"I_PMNOTIFICATIONTYPE",
"I_PMNOTIFICATIONTYPETEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/