C_LockboxBatchItemWorklist

@AbapCatalog.sqlViewName: 'CLBBATITMWL'
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA') //Partner's Bank Account - archiving is possible

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED

define view C_LockboxBatchItemWorklist
  with parameters
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_LANGUAGE
    P_Language : spras
  as select from    I_ARLockBoxBatchItem as item
    left outer join I_ARLockBoxBatch     as batch        on  item.LockboxBatchInternalKey = batch.LockboxBatchInternalKey
                                                         and item.LockboxBatch            = batch.LockboxBatch
    left outer join dd07v                as MlStatusName on  MlStatusName.domname    = 'FEB_ML_STATUS'
                                                         and MlStatusName.domvalue_l = item.MachineLrngBankStmntItemStatus
                                                         and MlStatusName.ddlanguage = $parameters.P_Language

{
  key batch.LockboxBatchInternalKey,
  key LockboxBatchItem,
  key batch.LockboxBatch,
      item.Lockbox,
      LockboxBatchOrigin,
      LockboxBatchDestination,
      HouseBank,
      HouseBankAccount,
      case when PaymentAdviceAccountType = 'D' then Customer
                                               else ''
      end                                             as Customer,
      Cheque,
      ValueDate,
      DepositDate,
      @Semantics.currencyCode: true
      item.Currency,
      @Semantics.amount.currencyCode: 'Currency'
      item.AmountInTransactionCurrency,
      PartnerBankCountry,
      PartnerBank,
      PartnerBankAccount,
      @UI.multiLineText: true
      MemoLine,
      //not needed due to new string based persistence

      MemoLine1,
      PaymentAdvice,
      BankLedgerIsPosted,
      SubledgerIsPostedSuccessfully,
      BankLedgerDocument,
      AssignmentReference,
      PaymentExternalTransacType,
      DocumentItemText,
      DocumentReferenceID,
      item.CompanyCode,
      FiscalYear,
      BankLedgerAcctgDocFiscalYear,
      case when BankLedgerIsPosted = 'X' and SubledgerIsPostedSuccessfully = 'X' then
        case when LockboxSubledgerDocument is initial and item.PostingErrorStatus = '3' then 'P' //Partially applied

                                                                                        else 'G' end  //Applied

      else
        case when SubledgerOnAccountDocument is not initial then 'Y' //on account

                                                            else 'R' end //Unprocessed

      end                                             as LockboxItemLifeCycSts,
      LockboxProcessingStatus,
      SubledgerOnAccountDocument,
      SubledgerDocument,
      SubledgerAcctgDocFiscalYear,
      BankPostingDate,
      BankPostingKey,
      BankReference,
      BusinessArea,
      BusinessPartnerName,
      TreasuryContract,
      DaybookEntry,
      DunningBlockingReason,
      ExchangeRate,
      @Semantics.amount.currencyCode: 'Currency'
      FeeAmountInTransactionCrcy,
      @Semantics.amount.currencyCode: 'OriginalCurrency'
      FeeAmountInOriginalCrcy,
      MemoLineIsChanged,
      @Semantics.currencyCode: true
      OriginalCurrency,
      @Semantics.amount.currencyCode: 'OriginalCurrency'
      AmountInOriginalCurrency,
      @Semantics.amount.currencyCode: 'Currency'
      OverdueChargeAmtInTransacCrcy,
      PartnerBankIBAN,
      PartnerBankSWIFTCode,
      PaymentAdviceAccount,
      PaymentAdviceAccountType,
      PaymentAdviceAccountTypeName,
      PaymentReference,
      PostingDate,
      PostingErrorStatus,
      ReferenceDocument,
      ReferenceDocumentType,
      BankStmntItemReprocessReason,
      ReturnReason,
      TreasuryContractType,
      ValueDateTime,
      MachineLrngBankStmntItemStatus,
      ProfitCenter,
      IsCompleted,
      CostCenter,
      BankAccount,
      BankAccountInternalID,
      BankAccountHolderName,
      BankAccountAdditionalName,
      BankAccountType,
      BankName,
      ChartOfAccounts,
      CreatedByUser,
      GLAccount,
      InterestRateInPercent,
      BankAccountReferenceText,
      BankStatementImportDate,
      BankStatementImportTime,
      DebitCreditCode,
      BankStatementItemDraftUUID,
      LockboxSubledgerDocument,
      cast(MlStatusName.ddtext as feb_ml_status_name) as MachineLrngBkStmntItemStatName
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ARLOCKBOXBATCH",
"I_ARLOCKBOXBATCHITEM",
"DD07V"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/