C_LegalTransactionDocStamp

@AbapCatalog.sqlViewName: 'CLCMLTDOCSTMP'
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [ '_StampContactCard' ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION

@ObjectModel: { semanticKey: 'LglCntntMDocumentStampUUID',
                representativeKey: 'LglCntntMDocumentStampUUID',

                usageType.dataClass: #MIXED,
                usageType.serviceQuality:  #C,
                usageType.sizeCategory: #L  }


@UI.headerInfo:{
  typeName: 'Stamp',
  typeNamePlural: 'Stamps',
  title: { value: 'LglCntntMDocumentStampName' }
}

@Search.searchable: true
@EndUserText.label: 'Document Stamps in Legal Transaction'

define view C_LegalTransactionDocStamp
  as select from I_LglCntntMDocumentStamp
  //  Value Helps

  association [0..1] to C_LglCntntMDocStampNameVH as _LglCntntMDocStampNameVH    on  $projection.LglCntntMDocumentStamp = _LglCntntMDocStampNameVH.LglCntntMDocumentStamp

  // For Stamp Text

  association [1..1] to C_LglCntntMDocStamp       as _LglCntntMDocStamp          on  $projection.LglCntntMDocumentStamp = _LglCntntMDocStamp.LglCntntMDocumentStamp

  //Contact Card

  association [0..1] to I_LCMUserContactCard      as _StampContactCard           on  _StampContactCard.ContactCardType = 'User'
                                                                                 and _StampContactCard.ContactCardID   = $projection.LglCntntMCreatedByUser
                                                                                 and _StampContactCard.ContactCardRole = 'Creator'

  //Extension

  association [1..1] to E_LglCntntMDocumentStamp  as _LglCntntMDocumentStampExtn on  $projection.LglCntntMDocumentStampUUID = _LglCntntMDocumentStampExtn.LglCntntMDocumentStampUUID
{
      @UI.hidden: true
  key LglCntntMDocumentStampUUID                          as LglCntntMDocumentStampUUID,

      @UI: {
            identification: {position: 10, importance: #HIGH },
            lineItem: {position: 10, importance: #HIGH },
            textArrangement: #TEXT_ONLY
          }
      @ObjectModel: {
          mandatory: true,
          text.element: 'LglCntntMDocumentStampName'
          }
      @Consumption.valueHelp: '_LglCntntMDocStampNameVH'
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
      @EndUserText.label: 'Stamp Name'
      LglCntntMDocumentStamp                              as LglCntntMDocumentStamp,

      @UI.hidden: true
      @Consumption.filter.hidden: true
      @ObjectModel.readOnly: true
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
      _LglCntntMDocStampNameVH.LglCntntMDocumentStampName as LglCntntMDocumentStampName,

      @UI: {
          identification: {position: 20, importance: #HIGH },
          lineItem: {position: 20, importance: #HIGH}
          }
      @EndUserText.label: 'Date, Time'
      LglCntntMCreatedUTCDateTime                         as LglCntntMCreatedUTCDateTime,

      @UI.hidden: true
      @Consumption.filter.hidden: true
      LglCntntMCreatedByUser                              as LglCntntMCreatedByUser,

      @UI: {
          lineItem: { position: 30, label: 'Added By', value: '_StampContactCard', type: #AS_CONTACT, importance: #HIGH },
          fieldGroup: { qualifier: 'AddedBy', position: 30, value: '_StampContactCard', type: #AS_CONTACT }
          }
      @EndUserText.label: 'Added By'
      _StampContactCard,

      @ObjectModel.readOnly: true
      @UI: {
          lineItem: { position: 40, label: 'Added By', importance: #HIGH }
          }
      _StampContactCard.FullName,

      @UI.hidden : true
      LglCntntMDocumentUUID                               as LglCntntMDocumentUUID,

      //      Value Help / Contact Card

      _LglCntntMDocStampNameVH,
      _LglCntntMDocStamp,


      //Authorization

      @UI.hidden: true
      _DocumentAuth
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_LGLCNTNTMDOCSTAMPNAMEVH",
"I_LCMUSERCONTACTCARD",
"I_LGLCNTNTMDOCUMENTSTAMP"
],
"ASSOCIATED":
[
"C_LGLCNTNTMDOCSTAMP",
"C_LGLCNTNTMDOCSTAMPNAMEVH",
"E_LGLCNTNTMDOCUMENTSTAMP",
"I_LCMDOCUMENT",
"I_LCMUSERCONTACTCARD"
],
"BASE":
[
"I_LGLCNTNTMDOCUMENTSTAMP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/