C_LegalTransLinkedObjCube

@AbapCatalog.sqlViewName: 'CLGLTRLKOBJCUBE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck:#CHECK
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics.dataCategory: #CUBE
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations:true
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@EndUserText.label: 'Legal Transaction Linked Obj - Cube'
@ObjectModel.supportedCapabilities: [ #ANALYTICAL_PROVIDER  ]
@ObjectModel.modelingPattern: #ANALYTICAL_CUBE
@Analytics.internalName:#LOCAL

define view C_LegalTransLinkedObjCube
  as select from           I_LegalTransaction       as LegalTransaction
    left outer to one join I_LegalTrLinkedObjectsTP as _LegalTrLinkedObjectsTP on LegalTransaction.LegalTransactionUUID = _LegalTrLinkedObjectsTP.LegalTransactionUUID
  association [1..1] to I_LegalTransaction        as _LegalTransaction     on  _LegalTrLinkedObjectsTP.LegalTransactionUUID = _LegalTransaction.LegalTransactionUUID
                                                                           and _LegalTransaction.IsEndOfPurposeBlocked      = ''
  association [0..1] to I_LCMLinkedObjectTypeText as _LinkedObjectTypeText on  $projection.LglCntntMLinkdObjType = _LinkedObjectTypeText.LglCntntMLinkdObjType
                                                                           and _LinkedObjectTypeText.Language    = $session.system_language
{
  key LegalTransaction.LegalTransactionUUID                                                                                      as LegalTransactionUUID,
  key _LegalTrLinkedObjectsTP.LegalTransactionLinkdObjUUID                                                                       as LegalTransactionLinkdObjUUID,
      _LegalTrLinkedObjectsTP.LglCntntMLinkdObjType,
      _LinkedObjectTypeText.LglCntntMLinkdObjTypeName,
      _LegalTrLinkedObjectsTP.LglCntntMLinkdObj,
      _LegalTransaction.LegalTransactionUUID                                                                                     as LegalTransactionTopUUID,
      _LegalTrLinkedObjectsTP.LegalTransactionIsTriggerObj,

      case when  _LegalTrLinkedObjectsTP.LegalTransactionIsTriggerObj = 'X' then
              cast ( 'X' as lcm_lgltranstriggerobjnametext  )
           else
              cast( ' ' as lcm_lgltranstriggerobjnametext ) end                                                                  as LglTransTriggerObjNameText,

      _LegalTrLinkedObjectsTP._LegalTransactionTP._LegalTransactionHealthText.LegalTransactionHealthName                         as LegalTransactionHealthName,
      _LegalTrLinkedObjectsTP._LegalTransaction._MainLegalTransactionEntity.LglCntntMEntity                                      as LglCntntMEntity,
      _LegalTrLinkedObjectsTP._LegalTransaction._MainLegalTransactionEntity.LglCntntMEntityTypeName                              as LglCntntMEntityTypeName,
      _LegalTrLinkedObjectsTP._LegalTransaction._LglCntntMGovLawText[1: Language = $session.system_language].LglCntntMGovLawText as LglCntntMGovLawText,
      _LegalTransaction.LegalTransactionHealth                                                                                   as LegalTransactionHealth,

      LegalTransaction._LglCntntMMainOrgTypeText.LglCntntMMainOrgTypeName                                                        as LglCntntMMainOrgTypeName,

      case
      when LegalTransaction.LglCntntMMainOrgType = '04' then
           LegalTransaction._SalesOrganizationText.SalesOrganizationName
      when LegalTransaction.LglCntntMMainOrgType = '05' then
           LegalTransaction._PurchasingOrganization.PurchasingOrganizationName
        else
           LegalTransaction._CompanyCode.CompanyCodeName
        end                                                                                                                      as LglCntntMMainOrgName,

      @Aggregation.referenceElement: ['LegalTransactionUUID']
      @Aggregation.default: #COUNT_DISTINCT
      cast( 1 as  lcm_totallt )                                                                                                  as TotalNumberOfLegalTransactions,

      @EndUserText.label: 'Legal Transactions with linked object'
      @Aggregation.referenceElement: ['LegalTransactionTopUUID']
      @Aggregation.default: #COUNT_DISTINCT
      cast (1 as abap.int4(10) )                                                                                                 as TotNrOfLegalTransWithLinkedObj
}
where
  LegalTransaction.IsEndOfPurposeBlocked = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_LCMLINKEDOBJECTTYPETEXT",
"I_LEGALTRANSACTION",
"I_LEGALTRANSACTIONENTITY",
"I_LEGALTRANSACTIONHEALTHTEXT",
"I_LEGALTRANSACTIONTP",
"I_LEGALTRLINKEDOBJECTSTP",
"I_LGLCNTNTMGOVLAWTEXT",
"I_LGLCNTNTMMAINORGTYPETEXT",
"I_PURCHASINGORGANIZATION",
"I_SALESORGANIZATIONTEXT"
],
"ASSOCIATED":
[
"I_LCMLINKEDOBJECTTYPETEXT",
"I_LEGALTRANSACTION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/