C_LegalEntitySubstVolByProduct

@AbapCatalog.sqlViewName: 'CSVTBYPRDCTMNT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Legal Entity Separated by Product'
@VDM.viewType: #CONSUMPTION

@ObjectModel: {
    usageType:{
        dataClass: #MIXED,
        serviceQuality: #D,
        sizeCategory: #L
      }
}

@Metadata.allowExtensions: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.semanticKey: ['ChmlCmplncInfoCombinedName']
define view C_LegalEntitySubstVolByProduct
  as select from I_SVTAggrgnLglEntityByProduct as SVTByProduct
  association [0..*] to C_MatlDocsByMonthAndBusProcess as _MatlDocsByMonthAndBusProcess on  $projection.SVTAggregationItemUUID = _MatlDocsByMonthAndBusProcess.SVTAggregationItemUUID
                                                                                        and $projection.ChmlCmplncInfoUUID     = _MatlDocsByMonthAndBusProcess.ChmlCmplncInfoUUID

  association [1..1] to C_ChmlCmplncPrimMatl  as _ChmlCmplncPrimMatl                    on  $projection.ChmlCmplncInfoUUID     = _ChmlCmplncPrimMatl.ChmlCmplncInfoUUID
  association [1..1] to C_LegalEntitySVTStatusMonitor  as _LegalEntitySVTStatusMonitor  on  $projection.SVTAggregationItemUUID = _LegalEntitySVTStatusMonitor.SVTAggregationItemUUID
  
{
  key SVTAggregationItemUUID,
  key ChmlCmplncInfoUUID,
      _ChmlCmplncPrimMatl.ChmlCmplncInfoCombinedName,
      _ChmlCmplncPrimMatl.Material,
      PlannedSubstanceVolume,
      PlannedSubstanceVolumeUnit,
      
      ConfirmedSubstanceVolume,
      ConfirmedSubstanceVolumeUnit, 

      @Semantics.quantity.unitOfMeasure: 'SubstanceVolumeThresholdUnit'
      PlannedSubstanceVolume + ConfirmedSubstanceVolume as LglEntityProductTotalSubstVol,
      
      // For Header information

      _LegalEntitySVTStatusMonitor.CASNumber,
      _LegalEntitySVTStatusMonitor.SubstanceName,
      _LegalEntitySVTStatusMonitor.LegalEntity,
      _LegalEntitySVTStatusMonitor.TotalSubstanceVolume,
      _LegalEntitySVTStatusMonitor.TotalSubstanceVolumeUnit,
      _LegalEntitySVTStatusMonitor.CmplRqVersTrackingPeriodText,
      _LegalEntitySVTStatusMonitor.TrackingPeriodStartDate,
      _LegalEntitySVTStatusMonitor.TrackingPeriodEndDate,
      _LegalEntitySVTStatusMonitor.SubstanceVolumeThresholdQty,
      _LegalEntitySVTStatusMonitor.SubstanceListName,
      @Semantics.unitOfMeasure: true
      _LegalEntitySVTStatusMonitor.SubstanceVolumeThresholdUnit,
      _LegalEntitySVTStatusMonitor.LglEntitySubstVolThldReachUnit,
      _LegalEntitySVTStatusMonitor.LglEntitySubstVolThldReachPct,
      _LegalEntitySVTStatusMonitor.CmplRqSVTStatusCriticality,
      _LegalEntitySVTStatusMonitor.ProdAllocPercentUnit,
      
      @Semantics.quantity.unitOfMeasure: 'ProdAllocPercentUnit'
      cast( round( 
                cast ( 
                    cast( PlannedSubstanceVolume + ConfirmedSubstanceVolume as abap.decfloat16 ) /
                    cast( _LegalEntitySVTStatusMonitor.TotalSubstanceVolume as abap.decfloat16 ) * 100 
                  as abap.dec( 10, 5 ) ) , 2 )
              as ehpma_svt_prod_pct_of_sbst_vol ) as LglEntitySubstVolProductPct,
      
      
      //For DCL need

      SVTAggregationHeaderUUID,

      //Associations

      _SVTAggregationItem,
      _SVTAggregationHeader,
      _LegalEntitySVTStatusMonitor,
      _MatlDocsByMonthAndBusProcess
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_CHMLCMPLNCPRIMMATL",
"C_LEGALENTITYSVTSTATUSMONITOR",
"I_SVTAGGRGNLGLENTITYBYPRODUCT"
],
"ASSOCIATED":
[
"C_CHMLCMPLNCPRIMMATL",
"C_LEGALENTITYSVTSTATUSMONITOR",
"C_MATLDOCSBYMONTHANDBUSPROCESS",
"I_SVTAGGREGATIONHEADER",
"I_SVTAGGREGATIONITEM"
],
"BASE":
[
"I_SVTAGGRGNLGLENTITYBYPRODUCT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/