C_LegalEntitySubstVolByMonth

@AbapCatalog.sqlViewName: 'CSVTBYMONTHMNT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Legal Entity Separated by Month'
@VDM.viewType: #CONSUMPTION

@ObjectModel: {
    usageType:{
        dataClass: #MIXED,
        serviceQuality: #D,
        sizeCategory: #L
      }
}

@Metadata.allowExtensions: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.semanticKey: ['PeriodMonthYearName','SVTBusinessProcess', 'CmplRqSVTScenario']
define view C_LegalEntitySubstVolByMonth
  as select from I_SVTAggrgnLegalEntityByMonth as SVTByMonth
  association [1..1] to I_CalendarMonth                as _CalendarMonth                on  $projection.CalendarMonth = _CalendarMonth.CalendarMonth

  association [0..1] to I_SVTBusinessProcess           as _SVTBusinessProcess           on  $projection.SVTBusinessProcess = _SVTBusinessProcess.SVTBusinessProcess

  association [0..1] to I_CmplRqSVTScenario            as _CmplRqSVTScenario            on  $projection.CmplRqSVTScenario = _CmplRqSVTScenario.CmplRqSVTScenario

  association [0..*] to C_MatlDocsByMonthAndBusProcess as _MatlDocsByMonthAndBusProcess on  $projection.SVTAggregationItemUUID = _MatlDocsByMonthAndBusProcess.SVTAggregationItemUUID
                                                                                        and $projection.CalendarMonth          = _MatlDocsByMonthAndBusProcess.CalendarMonth
                                                                                        and $projection.SVTBusinessProcess     = _MatlDocsByMonthAndBusProcess.SVTBusinessProcess
                                                                                        and $projection.CmplRqSVTScenario      = _MatlDocsByMonthAndBusProcess.CmplRqSVTScenario

  association [1..1] to C_LegalEntitySVTStatusMonitor  as _LegalEntitySVTStatusMonitor  on  $projection.SVTAggregationItemUUID = _LegalEntitySVTStatusMonitor.SVTAggregationItemUUID


{
      //SVTByMonth

  key SVTAggregationItemUUID,
      @ObjectModel:
      {
        readOnly: true,
        text.element:  [ 'CalendarMonthName' ]
      }
  key CalendarMonth,
  key CalendarYear,
      @ObjectModel:
      {
        readOnly: true,
        text.element:  [ 'SVTBusinessProcessText' ]
      }
  key SVTBusinessProcess,
      @ObjectModel:
      {
        readOnly: true,
        text.element:  [ 'CmplRqSVTScenarioText' ]
      }
  key CmplRqSVTScenario,

      _CalendarMonth._Text[1: Language = $session.system_language].CalendarMonthName,

      _SVTBusinessProcess._Text[1: Language = $session.system_language].SVTBusinessProcessText,

      _CmplRqSVTScenario._Text[1: Language = $session.system_language].CmplRqSVTScenarioText,

      PlannedSubstanceVolume,
      PlannedSubstanceVolumeUnit,

      concat_with_space(_CalendarMonth._Text[1: Language = $session.system_language].CalendarMonthName, CalendarYear, 2) as PeriodMonthYearName,

      ConfirmedSubstanceVolume,
      ConfirmedSubstanceVolumeUnit, 

      @Semantics.quantity.unitOfMeasure: 'SubstanceVolumeThresholdUnit'
      PlannedSubstanceVolume + ConfirmedSubstanceVolume as LglEntityTotalSubstVol,
      
      // For Header information

      _LegalEntitySVTStatusMonitor.CASNumber,
      _LegalEntitySVTStatusMonitor.SubstanceName,
      _LegalEntitySVTStatusMonitor.LegalEntity,
      _LegalEntitySVTStatusMonitor.TotalSubstanceVolume,
      _LegalEntitySVTStatusMonitor.TotalSubstanceVolumeUnit,
      _LegalEntitySVTStatusMonitor.CmplRqVersTrackingPeriodText,
      _LegalEntitySVTStatusMonitor.TrackingPeriodStartDate,
      _LegalEntitySVTStatusMonitor.TrackingPeriodEndDate,
      _LegalEntitySVTStatusMonitor.SubstanceVolumeThresholdQty,
      _LegalEntitySVTStatusMonitor.SubstanceListName,
      @Semantics.unitOfMeasure: true
      _LegalEntitySVTStatusMonitor.SubstanceVolumeThresholdUnit,
      _LegalEntitySVTStatusMonitor.LglEntitySubstVolThldReachUnit,
      _LegalEntitySVTStatusMonitor.LglEntitySubstVolThldReachPct,
      _LegalEntitySVTStatusMonitor.CmplRqSVTStatusCriticality,
      _LegalEntitySVTStatusMonitor.ProdAllocPercentUnit,

      //For DCL need

      SVTAggregationHeaderUUID,

      //Associations

      _SVTAggregationItem,
      _SVTAggregationHeader,
      _MatlDocsByMonthAndBusProcess,
      _CalendarMonth,
      _CalendarYear,
      _LegalEntitySVTStatusMonitor,
      _LegalEntitySVTStatusMonitor._UnitOfMeasureMass
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_LEGALENTITYSVTSTATUSMONITOR",
"I_CALENDARMONTH",
"I_CALENDARMONTHTEXT",
"I_CMPLRQSVTSCENARIO",
"I_CMPLRQSVTSCENARIOTEXT",
"I_SVTAGGRGNLEGALENTITYBYMONTH",
"I_SVTBUSINESSPROCESS",
"I_SVTBUSINESSPROCESSTEXT"
],
"ASSOCIATED":
[
"C_LEGALENTITYSVTSTATUSMONITOR",
"C_MATLDOCSBYMONTHANDBUSPROCESS",
"I_CALENDARMONTH",
"I_CALENDARYEAR",
"I_CMPLRQSVTSCENARIO",
"I_SVTAGGREGATIONHEADER",
"I_SVTAGGREGATIONITEM",
"I_SVTBUSINESSPROCESS",
"I_UNITOFMEASURE"
],
"BASE":
[
"C_LEGALENTITYSVTSTATUSMONITOR",
"I_SVTAGGRGNLEGALENTITYBYMONTH"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/