@AbapCatalog.sqlViewName: 'CLEGALTRREQ'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: { createEnabled,
updateEnabled,
deleteEnabled,
usageType.dataClass: #MIXED,
usageType.serviceQuality: #C,
usageType.sizeCategory: #M
}
//@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #CONSUMPTION
//TODO
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: [ '_OwnerContactCard' ]
@EndUserText.label: 'Legal Content Request'
define view C_LegalContentRequest
as select from I_LegalTransaction as LegalTr
association [0..1] to I_LcmContext as _LglCntntMContext on $projection.LglCntntMContextUUID = _LglCntntMContext.LglCntntMContextUUID
//Parties
association [0..*] to C_LegalTransactionEntity as _LegalTransactionEntity on $projection.LegalTransactionUUID = _LegalTransactionEntity.LegalTransactionUUID
association [0..*] to C_LegalTransactionIntContact as _LegalTransactionIntContact on $projection.LegalTransactionUUID = _LegalTransactionIntContact.LegalTransactionUUID
association [0..*] to C_LegalTransactionExtContact as _LegalTransactionExtContact on $projection.LegalTransactionUUID = _LegalTransactionExtContact.LegalTransactionUUID
//Reference objects
association [0..*] to C_LegalTrRelationShip as _LegalTrRelationShip on $projection.LegalTransactionUUID = _LegalTrRelationShip.LegalTransactionUUID
association [0..*] to C_LegalTrLinkedObjects as _LegalTrLinkedObjects on $projection.LegalTransactionUUID = _LegalTrLinkedObjects.LegalTransactionUUID
association [0..1] to I_LCMUserContactCard as _OwnerContactCard on _OwnerContactCard.ContactCardType = 'User'
and _OwnerContactCard.ContactCardID = $projection.lglcntntmcontextowner
and _OwnerContactCard.ContactCardRole = 'Creator'
//Dates
association [0..*] to C_LegalTransactionDate as _LegalTransactionDate on $projection.LegalTransactionUUID = _LegalTransactionDate.LegalTransactionUUID
//Documnets
association [0..*] to C_LglTransReqLglCntntDoc as _LglTransReqLglCntntDoc on $projection.LegalTransactionUUID = _LglTransReqLglCntntDoc.LegalTransactionUUID
//Category groups
association [0..*] to C_LglTransCategoryGroup as _LglTransCategoryGroup on $projection.LegalTransactionUUID = _LglTransCategoryGroup.LegalTransactionUUID
//Value Help
association [0..1] to C_LegalContentRequestCntxtIDVH as _ContextIdValueHelp on $projection.LglCntntMContext = _ContextIdValueHelp.LglCntntMContext
association [0..1] to I_Language as _LanguageValueHelp on $projection.LglCntntMLanguage = _LanguageValueHelp.Language
association [0..1] to C_LglCntntMGovLawVH as _LCMGovLawVH on $projection.LglCntntMGovLaw = _LCMGovLawVH.LglCntntMGovLaw
association [0..1] to C_LglTransMainOrgCoCodeCrteVH as _LglTransMainOrgCoCodeCrteVH on $projection.LglCntntMMainOrgCoCode = _LglTransMainOrgCoCodeCrteVH.CompanyCode
association [0..1] to C_LglTransMainOrgPurOrgCrteVH as _LglTransMainOrgPurOrgCrteVH on $projection.LglCntntMMainOrgPurOrg = _LglTransMainOrgPurOrgCrteVH.PurchasingOrganization
association [0..1] to C_LglTransMainOrgSlsOrgCrteVH as _LglTransMainOrgSlsOrgCrteVH on $projection.LglCntntMMainOrgSalesOrg = _LglTransMainOrgSlsOrgCrteVH.SalesOrganization
association [0..1] to C_LglTransMainOrgTypeCrteVH as _LglTransMainOrgTypeCrteVH on $projection.LglCntntMMainOrgType = _LglTransMainOrgTypeCrteVH.LglCntntMMainOrgType
association [0..1] to C_LglTransAccLvlEditValHelp as _LglTransAccLvlEditValHelp on $projection.LglTransAccessLvl = _LglTransAccLvlEditValHelp.LglCntntMAccessLvl
and $projection.LglCntntMProfile = _LglTransAccLvlEditValHelp.LglCntntMProfile
//Text associations
/* association [0..1] to I_LglCntntMProfileText as _LglCntntMProfileText on $projection.LglCntntMProfile = _LglCntntMProfileText.LglCntntMProfile
and Language = $session.system_language */
association [0..1] to I_LglCntntMAccessLvlText as _AccessLvlText on $projection.LglTransAccessLvl = _AccessLvlText.LglCntntMAccessLvl
and Language = $session.system_language
association [0..1] to I_LanguageText as _LanguageText on $projection.LglCntntMLanguage = _LanguageText.LanguageCode
and Language = $session.system_language
/* association [0..1] to I_LegalTransactionHealthText as _LegalTransactionHealthText on $projection.legaltransactionhealth = _LegalTransactionHealthText.LegalTransactionHealth
and Language = $session.system_language */
association [0..1] to I_SalesOrganizationText as _SalesOrganizationText on $projection.LglCntntMMainOrgSalesOrg = _SalesOrganizationText.SalesOrganization
and Language = $session.system_language
association [0..1] to I_LglCntntMMainOrgTypeText as _LglCntntMMainOrgTypeText on $projection.LglCntntMMainOrgType = _LglCntntMMainOrgTypeText.LglCntntMMainOrgType
and Language = $session.system_language
association [0..1] to I_PurchasingOrganization as _PurchasingOrganization on $projection.LglCntntMMainOrgPurOrg = _PurchasingOrganization.PurchasingOrganization
{
key LegalTransactionUUID,
@Consumption.semanticObject: 'LegalTransaction'
LegalTransaction,
@Semantics.text: true
@ObjectModel: { mandatory: true }
LegalTransactionTitle,
LglCntntMContextUUID,
LglTransWrkFlwModInstce,
LglCntntMProfile,
@UI.hidden: true
@ObjectModel.readOnly: true
@EndUserText.label: 'Access Level'
@ObjectModel.text.association: '_AccessLvlText'
@Consumption: {
valueHelp: '_LglTransAccLvlEditValHelp'
}
@UI.textArrangement: #TEXT_ONLY
LglTransAccessLvl,
@ObjectModel.text.association: '_LglCntntMMainOrgTypeText'
//@ObjectModel.text.element: 'LglCntntMMainOrgTypeName'
// @ObjectModel.readOnly: true
@UI.textArrangement: #TEXT_ONLY
@Consumption: {
valueHelp: '_LglTransMainOrgTypeCrteVH'
}
@EndUserText.label: 'Main Organization Type'
LglCntntMMainOrgType,
/* @UI.hidden: true
@ObjectModel.readOnly: true
@Semantics.text: true
_LglTransMainOrgTypeCrteVH.LglCntntMMainOrgTypeName, */
@ObjectModel.text.element: 'CompanyCodeName'
@UI.textArrangement: #TEXT_FIRST
@Consumption: {
valueHelp: '_LglTransMainOrgCoCodeCrteVH'
}
@EndUserText.label: 'Main Organization'
LglCntntMMainOrgCoCode,
@UI.hidden: true
// @ObjectModel.readOnly: true
@Semantics.text: true
_LglTransMainOrgCoCodeCrteVH.CompanyCodeName,
@ObjectModel.text.association: '_SalesOrganizationText'
//@ObjectModel.text.element: 'SalesOrganizationName'
@UI.textArrangement: #TEXT_FIRST
@Consumption: {
valueHelp: '_LglTransMainOrgSlsOrgCrteVH'
}
@EndUserText.label: 'Main Organization'
LglCntntMMainOrgSalesOrg,
/* @UI.hidden: true
@ObjectModel.readOnly: true
@Semantics.text: true
_LglTransMainOrgSlsOrgCrteVH._Text[1: Language = $session.system_language ].SalesOrganizationName, */
//@ObjectModel.text.element: 'PurchasingOrganizationName'
@ObjectModel.text.association: '_PurchasingOrganization'
@UI.textArrangement: #TEXT_FIRST
@Consumption: {
valueHelp: '_LglTransMainOrgPurOrgCrteVH'
}
@EndUserText.label: 'Main Organization'
LglCntntMMainOrgPurOrg,
/* @UI.hidden: true
@ObjectModel.readOnly: true
@Semantics.text: true
_LglTransMainOrgPurOrgCrteVH.PurchasingOrganizationName,*/
@EndUserText.label: 'Description'
@UI.multiLineText: true
@Semantics.text: true
LglCntntMLongText,
@UI.hidden: true
@ObjectModel.readOnly: true
IsEndOfPurposeBlocked,
@ObjectModel.text.element: 'LglCntntMContextTitle'
@Consumption.valueHelp: '_ContextIdValueHelp'
@UI.textArrangement: #TEXT_FIRST
@EndUserText.label: 'Context'
@ObjectModel: { mandatory: true }
_LglCntntMContext.LglCntntMContext as LglCntntMContext,
_LglCntntMContext.LglCntntMContextTitle,
//On the UI it will be hended separately
@ObjectModel.text.element: 'FullName'
@EndUserText.label: 'Owner'
_LglCntntMContext.LglCntntMContextOwner,
//On the UI it will be hended separately
@ObjectModel.readOnly: true
@Semantics.text: true
@UI.hidden: true
cast( '' as ad_namtext) as FullName,
@EndUserText.label: 'Language'
//@ObjectModel.text.element: 'LanguageName'
@ObjectModel.text.association: '_LanguageText'
@Consumption.valueHelp: '_LanguageValueHelp'
@Semantics.text: true
LglCntntMLanguage,
/* @EndUserText.label: 'Language'
@ObjectModel.readOnly: true
@Semantics.text: true
@Consumption.filter.hidden: true
_LanguageValueHelp._Text[1: Language = $session.system_language].LanguageName as LanguageName,*/
@EndUserText.label: 'Governing Law'
@ObjectModel.text.element: 'LglCntntMGovLawText'
@Consumption.valueHelp: '_LCMGovLawVH'
@Semantics.text: true
@UI.textArrangement: #TEXT_FIRST
LglCntntMGovLaw,
@ObjectModel.readOnly: true
@Semantics.text: true
@Consumption.filter.hidden: true
_LCMGovLawVH.LglCntntMGovLawText as LglCntntMGovLawText,
_LglCntntMContext,
_OwnerContactCard,
_LegalTransactionEntity,
_LegalTransactionIntContact,
_LegalTransactionExtContact,
_LegalTrLinkedObjects,
_LegalTrRelationShip,
_LglTransReqLglCntntDoc,
_ContextIdValueHelp,
_LegalTransactionDate,
_LglTransCategoryGroup,
@Consumption.filter.hidden: true
_LCMGovLawVH,
@Consumption.filter.hidden: true
_LanguageValueHelp,
_LglTransMainOrgCoCodeCrteVH,
_LglTransMainOrgSlsOrgCrteVH,
_LglTransMainOrgPurOrgCrteVH,
_LglTransMainOrgTypeCrteVH,
_LglTransAccLvlEditValHelp,
//Text associations
_LanguageText,
_LglCntntMMainOrgTypeText,
_AccessLvlText,
_SalesOrganizationText,
_PurchasingOrganization
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_LGLCNTNTMGOVLAWVH",
"C_LGLTRANSMAINORGCOCODECRTEVH",
"I_LCMCONTEXT",
"I_LEGALTRANSACTION"
],
"ASSOCIATED":
[
"C_LEGALCONTENTREQUESTCNTXTIDVH",
"C_LEGALTRANSACTIONDATE",
"C_LEGALTRANSACTIONENTITY",
"C_LEGALTRANSACTIONEXTCONTACT",
"C_LEGALTRANSACTIONINTCONTACT",
"C_LEGALTRLINKEDOBJECTS",
"C_LEGALTRRELATIONSHIP",
"C_LGLCNTNTMGOVLAWVH",
"C_LGLTRANSACCLVLEDITVALHELP",
"C_LGLTRANSCATEGORYGROUP",
"C_LGLTRANSMAINORGCOCODECRTEVH",
"C_LGLTRANSMAINORGPURORGCRTEVH",
"C_LGLTRANSMAINORGSLSORGCRTEVH",
"C_LGLTRANSMAINORGTYPECRTEVH",
"C_LGLTRANSREQLGLCNTNTDOC",
"I_LANGUAGE",
"I_LANGUAGETEXT",
"I_LCMCONTEXT",
"I_LCMUSERCONTACTCARD",
"I_LGLCNTNTMACCESSLVLTEXT",
"I_LGLCNTNTMMAINORGTYPETEXT",
"I_PURCHASINGORGANIZATION",
"I_SALESORGANIZATIONTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/