C_LU_TaxReturnBoxCube

@AbapCatalog.sqlViewName: 'CLUTAXRETURNBOXC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Tax Items for Luxembourg Cube'
@VDM.viewType: #CONSUMPTION
@Analytics: { dataCategory: #CUBE }
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@Metadata.allowExtensions: true
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED



define view C_LU_TaxReturnBoxCube
  with parameters
    P_StatryRptgEntity      : srf_reporting_entity,
    P_StatryRptCategory     : srf_rep_cat_id,
    P_StatryRptRunID        : srf_report_run_id,
    P_ReportingCountry      : land1
    
as select from I_StRpTaxReturnBoxCube(
                                                                                  P_TaxIsDeferredRelevant: 'N',    
                                                                                  P_TaxIsMossRelevant   :  'N',     
                                                                                  P_StatryRptgEntity     : $parameters.P_StatryRptgEntity , 
                                                                                  P_StatryRptCategory    : $parameters.P_StatryRptCategory,
                                                                                  P_StatryRptRunID       : $parameters.P_StatryRptRunID,
                                                                                  P_ReportingCountry     : $parameters.P_ReportingCountry,
                                                                                  P_TaxBoxConfiguration  : '1'                                               
                                                                                  )   
      
 left outer to many join P_LU_TimeDependentVersAssgmt on 
     P_LU_TimeDependentVersAssgmt.Country   = 'LU' and
     P_LU_TimeDependentVersAssgmt.TaxItemGroupingVersion = I_StRpTaxReturnBoxCube.TaxItemGroupingVersion     
     
 left outer to one join   P_T007B_GLO as TransactionType on I_StRpTaxReturnBoxCube.TransactionTypeDetermination = TransactionType.ktosl        
                                                                  
{                                                              
  key CompanyCode,
  key AccountingDocument,
  key FiscalYear,
  key TaxItem,
  key TransactionTypeDetermination,
  key TaxBox,
  key  AccountingDocumentType,
  key  SupplierAccountGroup,      
  key  DebitCreditCode,  
  key TaxDeclnAmountType,  
  key cast( coalesce (P_LU_TimeDependentVersAssgmt.TaxGroupingVersionFromDate, TaxBoxStrucValidityStartDate) as fot_atr_tbs_valid_from ) as TaxBoxStrucValidityStartDate ,
  key
    cast( case
     when UnifiedTaxBoxStructureType = ''
     then 'TVA_P'                              // Periodic VAT Return

     else
       case 
          when P_LU_TimeDependentVersAssgmt.TaxGroupingVersionFromDate is null 
         
         then UnifiedTaxBoxStructureType
         else 'TVA_A'                        // Annual VAT Return 

       end
   end as figen_unified_tbox_struct_type )                        as UnifiedTaxBoxStructureType,         
  key TaxGroup,
  key TaxItemGrpgDebitCreditCode,
  key TaxItemGrpgAcctgDocumentType,
  key TaxItemGrpgSupplierAcctGroup,
  key TaxItemGrpgSpecialGLCode,
  key StatryRptgEntity,
  key StatryRptCategory,
  key StatryRptRunID,
      TaxCode,
      I_StRpTaxReturnBoxCube.Country,        
       cast( coalesce (P_LU_TimeDependentVersAssgmt.TaxGroupingVersionToDate, TaxBoxStrucValidityEndDate) as fot_atr_tbs_valid_to ) as TaxBoxStrucValidityEndDate,     
      TaxBoxName,
      I_StRpTaxReturnBoxCube.TaxItemGroupingVersion,
      TaxBoxStructureType,
      TaxBoxStructure,
      TaxBoxStructureName,
      TaxBoxCondition,
      TaxCountry,
      TaxCalculationProcedure,
      @DefaultAggregation:#MIN
      TaxRate,
      TaxRateValidityStartDate,
      GLAccount,
      TaxItemGroup,
      ReferenceDocumentType,
      PostingDate,
      DocumentDate,
      TaxReportingDate,
      ReportingDate,
      TaxType,
      FiscalPeriod,     
      CompanyCodeCountry,
      ReportingCountry,
      TaxReturnCountry,
      TaxTypeName,     
      @Semantics.currencyCode:true
      CompanyCodeCurrency,
      @Semantics.currencyCode:true
      DocumentCurrency,
      @Semantics.currencyCode:true
      ReportingCurrency,
      @Semantics.currencyCode:true
      AdditionalCurrency1,
      @Semantics.currencyCode:true
      AdditionalCurrency2,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      AmountInReportingCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      AmountInTransactionCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      TaxBaseAmountInRptgCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      TaxAmountInRptgCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TaxBaseAmountInCoCodeCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TaxAmountInCoCodeCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      TaxBaseAmountInTransCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      TaxAmount,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      NonDeductibleInputTaxAmount,
      TargetTaxCode,
      CAReconciliationKey,
      TaxIsNotDeductible,    
      TransactionType.stgrp                                        as TransactionTaxType,  
       _TaxTypeText
               
}
      
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_STRPTAXRETURNBOXCUBE",
"P_LU_TIMEDEPENDENTVERSASSGMT",
"P_T007B_GLO"
],
"ASSOCIATED":
[
"I_TAXTYPETEXT"
],
"BASE":
[
"I_STRPTAXRETURNBOXCUBE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/