C_JrnlEntrLdgrCoCodeCrcyRole

DDL: C_JRNLENTRLDGRCOCODECRCYROLE Type: view_entity CONSUMPTION

Ledger Company Code Currency Role

C_JrnlEntrLdgrCoCodeCrcyRole is a Consumption CDS View that provides data about "Ledger Company Code Currency Role" in SAP S/4HANA. It reads from 1 data source (R_JrnlEntrLdgrCoCodeCrcyRole) and exposes 14 fields with key fields Ledger, CompanyCode, CurrencyRole, CurrencyField. It has 2 associations to related views.

1 data source(s) 14 fields

Data Sources (1)

SourceAliasJoin Type
R_JrnlEntrLdgrCoCodeCrcyRole R_JrnlEntrLdgrCoCodeCrcyRole from

Associations (2)

CardinalityTargetAliasCondition
[0..1] I_Companycodecurrencyrole _CurrencyRole $projection.CurrencyRole = _CurrencyRole.CurrencyRole and $projection.CompanyCode = _CurrencyRole.CompanyCode
[0..*] I_CurrencyRoleText _Text $projection.CurrencyRole = _Text.CurrencyRole

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Ledger Company Code Currency Role view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #CONSUMPTION view
ObjectModel.query.implementedBy ABAP:CL_MJE_LDGRCOCODECURRENCYROLE view

Fields (14)

KeyFieldSource TableSource FieldDescription
KEY Ledger Ledger
KEY CompanyCode CompanyCode
KEY CurrencyRole
KEY CurrencyField CurrencyField
CurrencyFieldName CurrencyFieldName
AmountFieldName AmountFieldName
TaxBaseAmountFieldName TaxBaseAmountFieldName
CurrencyRoleName
Currency _CurrencyRole Currency
Decimals
FiscalYear
AccountingDocument
CurrencyWithCurrencyRoleText
CurrencyIsRelevant 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Ledger Company Code Currency Role'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #L,
  dataClass: #MIXED
}
@VDM.viewType: #CONSUMPTION

@ObjectModel.query.implementedBy: 'ABAP:CL_MJE_LDGRCOCODECURRENCYROLE'

define view entity C_JrnlEntrLdgrCoCodeCrcyRole
  as select from R_JrnlEntrLdgrCoCodeCrcyRole  
  association [0..1] to I_Companycodecurrencyrole as _CurrencyRole on  $projection.CurrencyRole = _CurrencyRole.CurrencyRole
                                                                   and $projection.CompanyCode  = _CurrencyRole.CompanyCode
  association [0..*] to I_CurrencyRoleText        as _Text         on  $projection.CurrencyRole = _Text.CurrencyRole

{

  key Ledger,      
  key CompanyCode,
      @ObjectModel.text.element: ['CurrencyRoleName']
  key cast(CurrencyRole as fins_curtp preserving type ) as CurrencyRole,
      
  key CurrencyField,
      CurrencyFieldName,
      AmountFieldName,
      TaxBaseAmountFieldName,
      
      @Semantics.text: true
      cast( _Text[1: Language = $session.system_language].CurrencyRoleName as fac_crcyrole_txt ) as CurrencyRoleName,

      _CurrencyRole.Currency,
      _CurrencyRole._Currency.Decimals,
      // To get Trans. Currency we need following fields (see impl. class)

      cast( '0000' as gjahr) as FiscalYear,
      cast( '' as belnr_d) as  AccountingDocument,
      // Text shown on FE

      cast( '' as abap.char( 255 )) as CurrencyWithCurrencyRoleText,
      @Semantics.booleanIndicator
      cast( '' as abap.char( 1 )) as CurrencyIsRelevant
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODECURRENCYROLE",
"I_CURRENCY",
"I_CURRENCYROLETEXT",
"R_JRNLENTRLDGRCOCODECRCYROLE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More