@AbapCatalog.sqlViewName: 'CFIJEPOSTWEEKND'
@EndUserText.label: 'Journal Entry Item Postings on Weekends'
@VDM.viewType: #CONSUMPTION
@OData.publish: true
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: [ '_UserContactCard']
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata: { ignorePropagatedAnnotations: true,
allowExtensions: true }
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
define view C_JrnlEntrItmWeekendPostg
with parameters
@Consumption.valueHelpDefinition: [{ entity:{ name: 'C_FactoryCalWeekendPostingVH', element:'FactoryCalendar' } }]
P_FactoryCalendar : wfcid
as select from I_GLAccountLineItemRawData
association [0..1] to I_UserContactCard as _UserContactCard on $projection.AccountingDocCreatedByUser = _UserContactCard.ContactCardID
association [1..1] to I_CalendarDate as _CalendarDate on $projection.CreationDate = _CalendarDate.CalendarDate
association [0..1] to I_FactoryCalendar as _FactoryCalendar on $projection.FiscalYear between _FactoryCalendar.ValidityStartYear and _FactoryCalendar.ValidityEndYear
and _FactoryCalendar.FactoryCalendar = $parameters.P_FactoryCalendar
{
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_CompanyCodeVH', element:'CompanyCode' } }]
@ObjectModel.foreignKey.association: '_CompanyCode'
key CompanyCode,
@ObjectModel.foreignKey.association: '_FiscalYear'
key FiscalYear,
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_JournalEntryStdVH', element: 'AccountingDocument' },
additionalBinding: [{ localElement: 'CompanyCode', element: 'CompanyCode' },
{ localElement: 'FiscalYear', element: 'FiscalYear' }]
}]
@ObjectModel.foreignKey.association: '_JournalEntry'
key AccountingDocument as JournalEntry,
key LedgerGLLineItem,
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_LedgerStdVH', element: 'Ledger' } }]
@ObjectModel.foreignKey.association: '_Ledger'
key cast(SourceLedger as rldnr preserving type ) as Ledger,
@Semantics.amount.currencyCode: 'TransactionCurrency'
AmountInTransactionCurrency,
@ObjectModel.foreignKey.association: '_CalendarDate'
@Semantics.systemDate.createdAt: true
CreationDate,
_CalendarDate.WeekDay,
@ObjectModel.foreignKey.association: '_UserContactCard'
@Consumption.semanticObject: 'User'
@Semantics.user.id: true
AccountingDocCreatedByUser,
@Semantics.name.fullName: true
_UserContactCard.FullName as FullName,
@ObjectModel.foreignKey.association: '_LedgerFiscalYearForVariant'
@Semantics.fiscal.year: true
LedgerFiscalYear,
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_ChartOfAccountsStdVH', element: 'ChartOfAccounts' } }]
@ObjectModel.foreignKey.association: '_ChartOfAccounts'
ChartOfAccounts,
_CompanyCode.CompanyCodeName as CompanyCodeName,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_GLAccountInCompanyCodeStdVH', element: 'GLAccount' },
additionalBinding: [{ localElement: 'CompanyCode', element: 'CompanyCode' }]
}]
@ObjectModel.foreignKey.association: '_GLAccountInCompanyCode'
GLAccount,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_ControllingAreaStdVH', element: 'ControllingArea' } }]
@ObjectModel.text.element: ['ControllingAreaName']
@ObjectModel.foreignKey.association: '_ControllingArea'
ControllingArea,
@Semantics.text: true
_ControllingArea.ControllingAreaName,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProfitCenterVH', element: 'ProfitCenter' },
additionalBinding: [{ localElement: 'ControllingArea', element: 'ControllingArea' }] }]
@ObjectModel.foreignKey.association: '_ProfitCenter'
ProfitCenter,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CostCenterStdVH', element: 'CostCenter' },
additionalBinding: [{ localElement: 'ControllingArea', element: 'ControllingArea' }] }]
@ObjectModel.foreignKey.association: '_CostCenter'
CostCenter,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_BusTransTypeStdVH', element: 'BusinessTransactionType' } }]
@ObjectModel.foreignKey.association: '_BusinessTransactionType'
BusinessTransactionType,
@ObjectModel.foreignKey.association: '_FiscalYearVariant'
@Semantics.fiscal.yearVariant: true
FiscalYearVariant,
@Semantics.fiscal.period: true
FiscalPeriod,
@Semantics.fiscal.yearPeriod: true
FiscalYearPeriod,
PostingDate,
DocumentDate,
@Semantics.systemDate.lastChangedAt: true
LastChangeDateTime,
@ObjectModel.foreignKey.association: '_BalanceTransactionCurrency'
@Semantics.currencyCode: true
BalanceTransactionCurrency,
@Semantics.amount.currencyCode: 'BalanceTransactionCurrency'
AmountInBalanceTransacCrcy,
@ObjectModel.foreignKey.association: '_TransactionCurrency'
@Semantics.currencyCode: true
TransactionCurrency,
@ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
@Semantics.currencyCode: true
CompanyCodeCurrency,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
AmountInCompanyCodeCurrency,
@ObjectModel.foreignKey.association: '_GlobalCurrency'
@Semantics.currencyCode: true
GlobalCurrency,
@Semantics.amount.currencyCode: 'GlobalCurrency'
AmountInGlobalCurrency,
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
case DebitCreditCode when 'S' then cast( AmountInCompanyCodeCurrency as fis_dr_hsl preserving type )
else cast( cast( 0 as abap.curr( 23,2) ) as fis_dr_hsl preserving type )
end as DebitAmountInCoCodeCrcy,
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
case DebitCreditCode when 'H' then cast( AmountInCompanyCodeCurrency as fis_cr_hsl preserving type )
else cast( cast( 0 as abap.curr( 23,2) ) as fis_cr_hsl preserving type )
end as CreditAmountInCoCodeCrcy,
@ObjectModel.foreignKey.association: '_DebitCreditCode'
DebitCreditCode,
@ObjectModel.foreignKey.association: '_AccountingDocumentType'
AccountingDocumentType,
@ObjectModel.foreignKey.association: '_FinancialAccountType'
FinancialAccountType,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }]
@ObjectModel.foreignKey.association: '_Supplier'
Supplier,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_Customer_VH', element: 'Customer' } }]
@ObjectModel.foreignKey.association: '_Customer'
Customer,
_JournalEntry.AccountingDocumentHeaderText,
_JournalEntry.TransactionCode,
_CompanyCode,
_FiscalYear,
_JournalEntry,
_Ledger,
_ChartOfAccounts,
_GLAccountInCompanyCode,
_ControllingArea,
@Consumption.filter.businessDate.at: true
_ProfitCenter,
@Consumption.filter.businessDate.at: true
_CostCenter,
_BusinessTransactionType,
_FiscalYearVariant,
_BalanceTransactionCurrency,
_TransactionCurrency,
_CompanyCodeCurrency,
_GlobalCurrency,
_DebitCreditCode,
_AccountingDocumentType,
_FinancialAccountType,
_UserContactCard,
_CalendarDate,
_FiscalYearPeriodForVariant,
_LedgerFiscalYearForVariant,
_Supplier,
_Customer
}
where
(
( _CalendarDate.WeekDay = '1' and _FactoryCalendar.MondayIsWorkingDay = '0' )
or
( _CalendarDate.WeekDay = '2' and _FactoryCalendar.TuesdayIsWorkingDay = '0' )
or
( _CalendarDate.WeekDay = '3' and _FactoryCalendar.WednesdayIsWorkingDay = '0' )
or
( _CalendarDate.WeekDay = '4' and _FactoryCalendar.ThursdayIsWorkingDay = '0' )
or
( _CalendarDate.WeekDay = '5' and _FactoryCalendar.FridayIsWorkingDay = '0' )
or
( _CalendarDate.WeekDay = '6' and _FactoryCalendar.SaturdayIsWorkingDay = '0' )
or
( _CalendarDate.WeekDay = '7' and _FactoryCalendar.SundayIsWorkingDay = '0' )
)
and IsReversal = ''
and IsReversed = ''
and _JournalEntry.IntercompanyTransaction = ''
and PartnerCompany = ''
and _JournalEntry._User.IsTechnicalUser = ''
and AmountInTransactionCurrency <> 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CALENDARDATE",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_FACTORYCALENDAR",
"I_GLACCOUNTLINEITEMRAWDATA",
"I_JOURNALENTRY",
"I_USER",
"I_USERCONTACTCARD"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENTTYPE",
"I_BUSINESSTRANSACTIONTYPE",
"I_CALENDARDATE",
"I_CHARTOFACCOUNTS",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_CURRENCY",
"I_CUSTOMER",
"I_DEBITCREDITCODE",
"I_FACTORYCALENDAR",
"I_FINANCIALACCOUNTTYPE",
"I_FISCALYEARFORCOMPANYCODE",
"I_FISCALYEARFORVARIANT",
"I_FISCALYEARPERIODFORVARIANT",
"I_FISCALYEARVARIANT",
"I_GLACCOUNTINCOMPANYCODE",
"I_JOURNALENTRY",
"I_LEDGER",
"I_PROFITCENTER",
"I_SUPPLIER",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_GLACCOUNTLINEITEMRAWDATA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/