@AbapCatalog.sqlViewName: 'CFIJEPREVPERIOD'
@EndUserText.label: 'Jrnl Entr Item Postd Prior Fiscal Period'
@VDM.viewType: #CONSUMPTION
@OData.publish: true
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: [ '_UserContactCard',
'_DebitCreditCodeText',
'_AccountingDocumentTypeText']
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata: { ignorePropagatedAnnotations: true,
allowExtensions: true }
@ObjectModel.representativeKey: 'LedgerGLLineItem'
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
define view C_JrnlEntrItmPriorFsclPerd
as select from I_JournalEntryItem
association [1..1] to I_FiscalYearPeriodForVariant as _FiscalYearPeriodForVariant on $projection.FiscalYearVariant = _FiscalYearPeriodForVariant.FiscalYearVariant
and $projection.FiscalYearPeriod = _FiscalYearPeriodForVariant.FiscalYearPeriod
association [0..1] to I_UserContactCard as _UserContactCard on $projection.AccountingDocCreatedByUser = _UserContactCard.ContactCardID
{
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_CompanyCodeVH', element:'CompanyCode' } }]
@ObjectModel.foreignKey.association: '_CompanyCode'
key CompanyCode,
@ObjectModel.foreignKey.association: '_FiscalYear'
key FiscalYear,
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_JournalEntryStdVH', element: 'AccountingDocument' },
additionalBinding: [{ localElement: 'CompanyCode', element: 'CompanyCode' },
{ localElement: 'FiscalYear', element: 'FiscalYear' }]
}]
@ObjectModel.foreignKey.association: '_JournalEntry'
key AccountingDocument as JournalEntry,
key LedgerGLLineItem,
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_LedgerStdVH', element: 'Ledger' } }]
@ObjectModel.foreignKey.association: '_Ledger'
key Ledger,
@Semantics.systemDate.createdAt: true
CreationDate,
PostingDate,
_FiscalYearPeriodForVariant.FiscalPeriodEndDate as FiscalPeriodEndDate,
@ObjectModel.foreignKey.association: '_UserContactCard'
@Consumption.semanticObject: 'User'
@Semantics.user.id: true
AccountingDocCreatedByUser,
@Semantics.name.fullName: true
_UserContactCard.FullName as FullName,
@ObjectModel.foreignKey.association: '_LedgerFiscalYear'
@Semantics.fiscal.year: true
LedgerFiscalYear,
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_ChartOfAccountsStdVH', element: 'ChartOfAccounts' } }]
@ObjectModel.text.association: '_ChartOfAccountsText'
@ObjectModel.foreignKey.association: '_ChartOfAccounts'
ChartOfAccounts,
_CompanyCode.CompanyCodeName as CompanyCodeName,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_GLAccountInCompanyCodeStdVH', element: 'GLAccount' },
additionalBinding: [{ localElement: 'CompanyCode', element: 'CompanyCode' }]
}]
@ObjectModel.text.association: '_GLAccountTxt'
@ObjectModel.foreignKey.association: '_GLAccountInCompanyCode'
GLAccount,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_ControllingAreaStdVH', element: 'ControllingArea' } }]
@ObjectModel.text.element: ['ControllingAreaName']
@ObjectModel.foreignKey.association: '_ControllingArea'
ControllingArea,
@Semantics.text: true
_ControllingArea.ControllingAreaName,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProfitCenterVH', element: 'ProfitCenter' },
additionalBinding: [{ localElement: 'ControllingArea', element: 'ControllingArea' }] }]
@ObjectModel.foreignKey.association: '_ProfitCenter'
ProfitCenter,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CostCenterStdVH', element: 'CostCenter' },
additionalBinding: [{ localElement: 'ControllingArea', element: 'ControllingArea' }] }]
@ObjectModel.foreignKey.association: '_CostCenter'
CostCenter,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_BusTransTypeStdVH', element: 'BusinessTransactionType' } }]
@ObjectModel.text.association: '_BusinessTransactionTypeText'
@ObjectModel.foreignKey.association: '_BusinessTransactionType'
BusinessTransactionType,
@ObjectModel.foreignKey.association: '_FiscalYearVariant'
@Semantics.fiscal.yearVariant: true
FiscalYearVariant,
@ObjectModel.foreignKey.association: '_FiscalPeriod'
@Semantics.fiscal.period: true
FiscalPeriod,
@Semantics.fiscal.yearPeriod: true
FiscalYearPeriod,
_FiscalYearPeriodForVariant.FiscalPeriodStartDate as FiscalPeriodStartDate,
_FiscalYearPeriodForVariant.IsSpecialPeriod as IsSpecialPeriod,
DocumentDate,
@Semantics.systemDate.lastChangedAt: true
LastChangeDateTime,
@ObjectModel.foreignKey.association: '_BalanceTransactionCurrency'
@Semantics.currencyCode: true
BalanceTransactionCurrency,
@Semantics.amount.currencyCode: 'BalanceTransactionCurrency'
AmountInBalanceTransacCrcy,
@ObjectModel.foreignKey.association: '_TransactionCurrency'
@Semantics.currencyCode: true
TransactionCurrency,
@Semantics.amount.currencyCode: 'TransactionCurrency'
AmountInTransactionCurrency,
@ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
@Semantics.currencyCode: true
CompanyCodeCurrency,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
AmountInCompanyCodeCurrency,
@ObjectModel.foreignKey.association: '_GlobalCurrency'
@Semantics.currencyCode: true
GlobalCurrency,
@Semantics.amount.currencyCode: 'GlobalCurrency'
AmountInGlobalCurrency,
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
DebitAmountInCoCodeCrcy,
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
CreditAmountInCoCodeCrcy,
@ObjectModel.text.association: '_DebitCreditCodeText'
@ObjectModel.foreignKey.association: '_DebitCreditCode'
DebitCreditCode,
@ObjectModel.text.association: '_AccountingDocumentTypeText'
@ObjectModel.foreignKey.association: '_AccountingDocumentType'
AccountingDocumentType,
@ObjectModel.text.association: '_FinancialAccountTypeText'
@ObjectModel.foreignKey.association: '_FinancialAccountType'
FinancialAccountType,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }]
@ObjectModel.foreignKey.association: '_Supplier'
Supplier,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_Customer_VH', element: 'Customer' } }]
@ObjectModel.foreignKey.association: '_Customer'
Customer,
_JournalEntry.AccountingDocumentHeaderText,
_JournalEntry.TransactionCode,
--_SourceLedger,
_CompanyCode,
_FiscalYear,
_JournalEntry,
_Ledger,
_LedgerFiscalYear,
_ChartOfAccounts,
_ChartOfAccountsText,
_GLAccountInCompanyCode,
_GLAccountTxt,
_ControllingArea,
@Consumption.filter.businessDate.at: true
_ProfitCenter,
@Consumption.filter.businessDate.at: true
_CostCenter,
_BusinessTransactionType,
_BusinessTransactionTypeText,
_FiscalYearVariant,
_FiscalPeriod,
_BalanceTransactionCurrency,
_TransactionCurrency,
_CompanyCodeCurrency,
_GlobalCurrency,
_DebitCreditCode,
_DebitCreditCodeText,
_AccountingDocumentType,
_AccountingDocumentTypeText,
_FinancialAccountType,
_FinancialAccountTypeText,
_UserContactCard,
_FiscalYearPeriodForVariant,
_FiscalYearPeriodForVariant._FiscalPeriodStartDate,
_FiscalPeriodForVariant,
_LedgerFiscalYearForVariant,
_Supplier,
_Customer
}
where
CreationDate > _FiscalYearPeriodForVariant.FiscalPeriodEndDate
and PostingDate < _FiscalYearPeriodForVariant.FiscalPeriodEndDate
and IsReversal = ''
and IsReversed = ''
and SourceLedger = Ledger
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_FISCALYEARPERIODFORVARIANT",
"I_JOURNALENTRY",
"I_JOURNALENTRYITEM",
"I_USERCONTACTCARD"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENTTYPE",
"I_ACCOUNTINGDOCUMENTTYPETEXT",
"I_BUSINESSTRANSACTIONTYPE",
"I_BUSTRANSACTIONTYPETEXT",
"I_CALENDARDATE",
"I_CHARTOFACCOUNTS",
"I_CHARTOFACCOUNTSTEXT",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_CURRENCY",
"I_CUSTOMER",
"I_DEBITCREDITCODE",
"I_DEBITCREDITCODETEXT",
"I_FINANCIALACCOUNTTYPE",
"I_FINANCIALACCOUNTTYPETEXT",
"I_FISCALPERIODFORVARIANT",
"I_FISCALYEARFORCOMPANYCODE",
"I_FISCALYEARFORVARIANT",
"I_FISCALYEARPERIODFORCMPNYCODE",
"I_FISCALYEARPERIODFORVARIANT",
"I_FISCALYEARVARIANT",
"I_GLACCOUNTINCOMPANYCODE",
"I_GLACCOUNTTEXT",
"I_JOURNALENTRY",
"I_LEDGER",
"I_PROFITCENTER",
"I_SUPPLIER",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_FISCALYEARPERIODFORVARIANT",
"I_JOURNALENTRYITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/