C_JournalEntryCustomerCard

@AbapCatalog: {
    sqlViewName: 'CDOCCUSCNTCT',
    compiler.compareFilter: true
}
@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #REQUIRED
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Journal Entry Customer Contact Card'

@ObjectModel.usageType: {
    dataClass: #MIXED,
    serviceQuality: #C,
    sizeCategory: #L
}
@VDM: {
    viewType: #CONSUMPTION,
    private: false
}
@Search.searchable: true
@Consumption.ranked: true
define view C_JournalEntryCustomerCard
  as select from I_Customer as Customer
{
      @Semantics.contact.type: #ORGANIZATION
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.85
      }
      @ObjectModel.text.element:  [ 'FullName' ]
      @Search.ranking: #HIGH      
  key Customer.Customer                                               as ContactCardID,

      @Semantics.name.fullName: true
      @Search.ranking: #HIGH
      Customer.CustomerFullName                                       as FullName,
      
      @UI.hidden: true
      Customer.AuthorizationGroup,

      -- ADDRESS

      @Semantics.address.type:  [ #WORK ]
      @Semantics.address.street: true
      @Search.ranking: #LOW
      Customer.StreetName,

      @Semantics.address.type:  [ #WORK ]
      @Semantics.address.streetNoNumber: true
      @Search.ranking: #LOW
      Customer._StandardAddress.HouseNumber,

      @Semantics.address.type:  [ #WORK ]
      @Semantics.address.city: true
      @Search.ranking: #LOW
      Customer.CityName,

      @Semantics.address.type:  [ #WORK ]
      @Semantics.address.zipCode: true
      @Search.ranking: #LOW
      Customer.PostalCode,

      @Semantics.address.type:  [ #WORK ]
      @Semantics.address.streetNoNumber: true
      @Search.ranking: #LOW
      cast( Customer.Country as farp_inspect_item_country_name preserving type) as Country,

      -- END ADDRESS


      @Semantics.telephone.type:  [ #WORK ]
      @Consumption.filter.hidden: true
      @Search.ranking: #LOW
      Customer._StandardAddress._DefaultPhoneNumber.PhoneNumber       as PhoneNumber,

      @Semantics.telephone.type:  [ #CELL ]
      @Consumption.filter.hidden: true
      @Search.ranking: #LOW
      cast( Customer._StandardAddress._DefaultMobilePhoneNumber.PhoneNumber as farp_mobile preserving type ) as MobilePhoneNumber,

      @EndUserText.label: 'Email'
      @Semantics.eMail.type:  [ #WORK ]
      @Semantics.eMail.address: true
      @Consumption.filter.hidden: true
      @Search.ranking: #LOW
      Customer._StandardAddress._DefaultEmailAddress.EmailAddress     as EmailAddress,
      
      // Fields added For Data Controller in DCL .... NOT TO BE CONSUMED.

      @UI.hidden: true
      @Consumption.filter.hidden: true
      Customer.DataControllerSet,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      Customer.DataController1,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      Customer.DataController2,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      Customer.DataController3,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      Customer.DataController4,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      Customer.DataController5,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      Customer.DataController6,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      Customer.DataController7,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      Customer.DataController8,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      Customer.DataController9,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      Customer.DataController10,
    
      @UI.hidden: true
      @Consumption.filter.hidden: true      
      Customer.IsBusinessPurposeCompleted
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_ADDRESSEMAILADDRESS",
"I_ADDRESSPHONENUMBER",
"I_CUSTOMER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/