C_JP_MachineLearningOpenItem

@AbapCatalog.sqlViewName: 'CJPMLOPNITM'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D
@VDM.viewType:#CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.buffering.status: #NOT_ALLOWED
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Machine Learning Open Receivable Items'
define view C_JP_MachineLearningOpenItem
  as select from I_JournalEntry as _AccDocHdr
    inner join I_OperationalAcctgDocItem as _AccDocItm
        on _AccDocHdr.CompanyCode = _AccDocItm.CompanyCode
       and _AccDocHdr.AccountingDocument = _AccDocItm.AccountingDocument
       and _AccDocHdr.FiscalYear = _AccDocItm.FiscalYear
    association [0..1] to I_Customer as _Customer
        on _AccDocItm.Customer = _Customer.Customer
    association [0..1] to I_Supplier as _Supplier
        on _AccDocItm.Supplier = _Supplier.Supplier
    association [0..1] to I_CompanyCode as _CompanyCode
        on _AccDocHdr.CompanyCode = _CompanyCode.CompanyCode
    association [0..1] to I_CustomerCompany as _CustCompany
        on _AccDocItm.Customer = _CustCompany.Customer
       and _AccDocItm.CompanyCode = _CustCompany.CompanyCode
    association [1..1] to I_JP_InvcSummaryMchnLrngItem as _InvcSmmryItem
        on _AccDocItm.AccountingDocument = _InvcSmmryItem.AccountingDocument
       and _AccDocItm.AccountingDocumentItem = _InvcSmmryItem.AccountingDocumentItem
       and _AccDocItm.CompanyCode  = _InvcSmmryItem.CompanyCode
       and _AccDocItm.FiscalYear = _InvcSmmryItem.FiscalYear
{
    key _AccDocHdr.CompanyCode,
    key _AccDocHdr.FiscalYear,
    key _AccDocHdr.AccountingDocument,
    key _AccDocItm.AccountingDocumentItem,
    _CompanyCode.Country,
    _AccDocHdr.AccountingDocumentType,
    _AccDocHdr.PostingDate,
    _AccDocHdr.DocumentReferenceID,  
    @Semantics.currencyCode: true
    _AccDocHdr.CompanyCodeCurrency,
    @Semantics.currencyCode: true
    _AccDocHdr.TransactionCurrency,
    _AccDocHdr.AccountingDocumentHeaderText,
    _AccDocItm.AssignmentReference,
    _AccDocItm.PaymentReference,
    _AccDocItm.BillingDocument,
    @API.element.releaseState: #DEPRECATED
    @API.element.successor:    'ClearingJournalEntryFiscalYear'
    @VDM.lifecycle.status:    #DEPRECATED
    @VDM.lifecycle.successor: 'ClearingJournalEntryFiscalYear'
    _AccDocItm.ClearingDocFiscalYear,
    _AccDocItm.ClearingJournalEntryFiscalYear,
    @API.element.releaseState: #DEPRECATED
    @API.element.successor:    'ClearingJournalEntry'
    @VDM.lifecycle.status:    #DEPRECATED
    @VDM.lifecycle.successor: 'ClearingJournalEntry'  
    _AccDocItm.ClearingAccountingDocument,
    _AccDocItm.ClearingJournalEntry,
    _AccDocItm.ClearingDate,
    @Semantics.amount.currencyCode:'CompanyCodeCurrency'
    _AccDocItm.AmountInCompanyCodeCurrency,
    @Semantics.amount.currencyCode:'TransactionCurrency'
    _AccDocItm.AmountInTransactionCurrency,
    @Semantics.amount.currencyCode:'CompanyCodeCurrency'
    _AccDocItm.TaxAmountInCoCodeCrcy,
    @Semantics.amount.currencyCode:'TransactionCurrency'    
    _AccDocItm.TaxAmount,
    @Semantics.amount.currencyCode:'CompanyCodeCurrency'
    _AccDocItm.CashDiscountAmtInCoCodeCrcy,
    @Semantics.amount.currencyCode:'TransactionCurrency'
    _AccDocItm.CashDiscountAmount,
    _AccDocItm.DebitCreditCode,
    _AccDocItm.DocumentItemText,
    _AccDocItm.FinancialAccountType,
    _AccDocItm.InvoiceReference,
    _AccDocItm.InvoiceReferenceFiscalYear,
    _AccDocItm.InvoiceItemReference,
    _AccDocItm.FollowOnDocumentType,
    case when _AccDocItm.FinancialAccountType='K' 
        then _AccDocItm.Supplier 
        else _AccDocItm.Customer end as Debtor,
    case when _AccDocItm.FinancialAccountType='K'
        then _Supplier.OrganizationBPName1
        else _Customer.OrganizationBPName1 end as OrganizationBPName1,
    case when _AccDocItm.FinancialAccountType='K' 
        then _Supplier.OrganizationBPName2
        else _Customer.OrganizationBPName2 end as OrganizationBPName2,
    case when _AccDocItm.FinancialAccountType='K' 
        then _Supplier.CityName 
        else _Customer.CityName end as CityName,
    case when _AccDocItm.FinancialAccountType='K' 
        then _Supplier.Country 
        else _Customer.Country end as BusinessPartnerCountry,
    _AccDocItm.PartnerCompany,
    _AccDocItm.NetDueDate,
    _AccDocItm.CashDiscount1Percent,
    _AccDocItm.CashDiscount1DueDate,
    _AccDocItm.CashDiscount2Percent,
    _AccDocItm.CashDiscount2DueDate,
    _AccDocItm.DueCalculationBaseDate              as DueCalculationBaseDate,
    _AccDocItm.PaymentMethod                       as PaymentMethod,
    _AccDocItm.GLAccount                           as GLAccount,
    _Customer.AlternativePayerAccount              as AlternativePayerAccount,
    _CustCompany.AlternativePayerAccount           as CoCodeAlternativePayerAccount,
    _InvcSmmryItem.InvcSmmryPayer,
    _InvcSmmryItem.InvcSmmryPayerName,
    _InvcSmmryItem.InvcSmmryRecipient,
    _InvcSmmryItem.InvcSmmryRecipientName,
    _InvcSmmryItem.AlternativePayerName1,
    _InvcSmmryItem.AlternativePayerName2,
    _InvcSmmryItem.AlternativePayerName3,
    _InvcSmmryItem.AlternativePayerName4,
    _InvcSmmryItem.AlternativeBankName1,
    _InvcSmmryItem.AlternativeBankName2,
    _InvcSmmryItem.AlternativeBankName3,
    _InvcSmmryItem.AlternativeBankName4,
    _InvcSmmryItem.AlternativeBankBranchName1,
    _InvcSmmryItem.AlternativeBankBranchName2,
    _InvcSmmryItem.AlternativeBankBranchName3,
    _InvcSmmryItem.AlternativeBankBranchName4,
    _InvcSmmryItem.InvcSmmryVirtualAcctNo,  
    _InvcSmmryItem.Bank,
    _InvcSmmryItem.BankCountry,
    _InvcSmmryItem.InvcSmmryMonthlyInvc,
    _InvcSmmryItem.InvcSmmryPayerInvc
    //cast('' as abap.sstring( 64)) as MachineLearningArUUID

}
where _AccDocItm.ClearingJournalEntry is null
   or _AccDocItm.ClearingJournalEntry = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_CUSTOMER",
"I_CUSTOMERCOMPANY",
"I_JOURNALENTRY",
"I_JP_INVCSUMMARYMCHNLRNGITEM",
"I_OPERATIONALACCTGDOCITEM",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CUSTOMER",
"I_CUSTOMERCOMPANY",
"I_JP_INVCSUMMARYMCHNLRNGITEM",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/