C_InvtryTurnoverAnlysDets

@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'CINVTOANLYSDETS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE

@UI.headerInfo:{
  typeName: 'Inventory Turnover Analysis',
  typeNamePlural: 'Inventory Turnover Analysis',
  title: { label: 'Inventory Turnover Analysis',
           value: 'Material' },
  description: { label: 'Plant',
                 value: 'Plant' }
}
@Consumption.semanticObject: 'Material'

@EndUserText.label: 'Inventory Turnover Analysis Details'
@VDM.private: false
@VDM.viewType: #CONSUMPTION
@Metadata.ignorePropagatedAnnotations: true
define view C_InvtryTurnoverAnlysDets

 with parameters
    @Consumption.derivation: { lookupEntity: 'C_SglGregorianCalDateFunction',  
    resultElement: 'DateFunctionStartDate', binding: [ {
         targetParameter: 'P_DateFunction', type: #CONSTANT, value : 'PREVIOUS365DAYS' },
       { targetParameter : 'P_Language' , type : #SYSTEM_FIELD, value : '#SYSTEM_LANGUAGE'  } ] 
    } 
    @Consumption.hidden: true
    P_StartDate: bedat

  as select from I_MaterialPlant as _MaterialPlant
    join         I_Plant               on _MaterialPlant.Plant = I_Plant.Plant //t001w

    join         I_Purreqvaluationarea on I_Plant.ValuationArea = I_Purreqvaluationarea.ValuationArea //t001k

    join         I_CompanyCode         on I_CompanyCode.CompanyCode = I_Purreqvaluationarea.CompanyCode //t001


  association [0..1] to I_ProductPlant                as _ProductPlant                on  $projection.Plant    = _ProductPlant.Plant
                                                                                      and $projection.Material = _ProductPlant.Product

  association [0..1] to C_InvtryTurnoverPrfrdSupplier as _InvtryTurnoverPrfrdSupplier on  $projection.Plant    = _InvtryTurnoverPrfrdSupplier.Plant
                                                                                      and $projection.Material = _InvtryTurnoverPrfrdSupplier.Material

  association [0..*] to C_InvtryTurnoverSupplier      as _InvtryTurnoverSupplier      on  $projection.Plant    = _InvtryTurnoverSupplier.Plant
                                                                                      and $projection.Material = _InvtryTurnoverSupplier.Material

  association [0..1] to I_UnitOfMeasure               as _BaseUnit                    on  $projection.MaterialBaseUnit = _BaseUnit.UnitOfMeasure
{
      @Consumption.filter.hidden: true
  key _MaterialPlant.Material,
      @Consumption.filter.hidden: true
  key _MaterialPlant.Plant,

      @Consumption.groupWithElement: 'Material'
      @Consumption.filter.hidden: true
      @Semantics.text: true
      _MaterialPlant._Material._Text[1: Language=$session.system_language].MaterialName,

      @Consumption.groupWithElement: 'Plant'
      @Consumption.filter.hidden: true
      @Semantics.text: true
      I_Plant.PlantName,

      //Material Data

      @Semantics.unitOfMeasure: true
      @Consumption.filter.hidden: true
      @ObjectModel.foreignKey.association: '_BaseUnit'
      _MaterialPlant._Material.MaterialBaseUnit as MaterialBaseUnit,

      @Consumption.filter.hidden: true
      @Semantics.currencyCode: true
      I_CompanyCode.Currency,

      @Consumption.filter.hidden: true
      I_CompanyCode.CompanyCode,

      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @Consumption.filter.hidden: true
      _MaterialPlant.MaterialSafetyStockQty,

      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @Consumption.filter.hidden: true
      _ProductPlant.MinimumLotSizeQuantity,

      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @Consumption.filter.hidden: true
      _ProductPlant.MaximumLotSizeQuantity,

      @Consumption.filter.hidden: true
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      _ProductPlant.FixedLotSizeQuantity,

      // Preferred Supplier

      _InvtryTurnoverPrfrdSupplier,
      // All Suppliers

      _InvtryTurnoverSupplier,

      _BaseUnit
}

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_MATERIAL",
"I_MATERIALPLANT",
"I_MATERIALTEXT",
"I_PLANT",
"I_PRODUCTPLANT",
"I_PURREQVALUATIONAREA"
],
"ASSOCIATED":
[
"C_INVTRYTURNOVERPRFRDSUPPLIER",
"C_INVTRYTURNOVERSUPPLIER",
"I_PRODUCTPLANT",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/