C_InvcExcdGRPurgDocItm

@AbapCatalog.sqlViewName: 'CGRCINVEXGRPDI'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Overpaid GR in Purchasing Document Item'
@VDM.viewType: #CONSUMPTION
@OData.publish: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata: { ignorePropagatedAnnotations: true,
             allowExtensions: true }
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
define view C_InvcExcdGRPurgDocItm 
  as select from I_PurchasingDocumentItem
  association [1..1] to P_GRAmtPerPurgDocumentItem as _GRAmtPerPurgDocumentItem on  $projection.PurchasingDocument     = _GRAmtPerPurgDocumentItem.PurchasingDocument
                                                                                and $projection.PurchasingDocumentItem = _GRAmtPerPurgDocumentItem.PurchasingDocumentItem

  association [1..1] to P_InvcAmtPerPurgDocItem as _InvcAmtPerPurgDocItem on  $projection.PurchasingDocument     = _InvcAmtPerPurgDocItem.PurchasingDocument
                                                                          and $projection.PurchasingDocumentItem = _InvcAmtPerPurgDocItem.PurchasingDocumentItem
{

  key PurchasingDocument,
  key PurchasingDocumentItem,
  
        PurchasingDocumentCategory,
        _PurchasingDocument.PurchasingDocumentType,
        @ObjectModel.foreignKey.association: '_CompanyCode'
        CompanyCode,
        
        _PurchasingDocument.PurchasingOrganization,
         @Semantics.amount.currencyCode: 'DocumentCurrency'
        _InvcAmtPerPurgDocItem.InvoicedAmount - _GRAmtPerPurgDocumentItem.GoodsReceiptAmount as CalculatedDiffAmount,
        _PurchasingDocument.CreationDate                                                      as PurchasingDocumentCreationDate,
        _PurchasingDocument.CreatedByUser,
        _PurchasingDocument.DocumentCurrency,

        @Semantics: { amount : {currencyCode:'DocumentCurrency'} }
        GrossAmount,
        _PurchasingDocument.PurchasingGroup,
        
        @Consumption.filter: { selectionType: #SINGLE, multipleSelections: true, mandatory: false }

        _PurchasingDocument.LastChangeDateTime,

        _PurchasingDocument.Supplier,

        @Consumption.filter: { selectionType: #SINGLE, multipleSelections: true, mandatory: false }
        @Semantics.text: true
        _PurchasingDocument._Supplier.SupplierFullName                                        as SupplierFullName,

        @Consumption.filter: { selectionType: #SINGLE, multipleSelections: true, mandatory: false }
        _PurchasingDocument._Supplier.SupplierAccountGroup                                    as SupplierAccountGroup,


        
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      _GRAmtPerPurgDocumentItem.GoodsReceiptAmount,
        
      @Semantics.amount.currencyCode: 'DocumentCurrency'  
      _InvcAmtPerPurgDocItem.InvoicedAmount,
 
  
      Plant,

        _PurchasingDocument,
        _CompanyCode

}

where
     _InvcAmtPerPurgDocItem.InvoicedAmount > _GRAmtPerPurgDocumentItem.GoodsReceiptAmount
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASINGDOCUMENT",
"I_PURCHASINGDOCUMENTITEM",
"I_SUPPLIER",
"P_GRAMTPERPURGDOCUMENTITEM",
"P_INVCAMTPERPURGDOCITEM"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_PURCHASINGDOCUMENT",
"P_GRAMTPERPURGDOCUMENTITEM",
"P_INVCAMTPERPURGDOCITEM"
],
"BASE":
[
"I_PURCHASINGDOCUMENTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/