C_InternalContacts

@AbapCatalog.sqlViewName: 'CINTCNTCS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Internal Contacts'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking:#NOT_REQUIRED

define view C_InternalContacts 
as select distinct from I_SDDocumentPartner          as Partner
left outer to one join I_PersonWorkAgreement_1       as Employment                  on Partner.Personnel = Employment.PersonWorkAgreement
  association[0..1] to I_WorkforcePerson             as _Employee                   on $projection.Person = _Employee.Person
  association[0..1] to I_WorkforcePersonImageURL     as _ImageURL                   on $projection.Person =_ImageURL.Person
  association[0..*] to I_PersonWorkAgrmtOrglDetails  as _PersonWorkAgrmtOrglDetails on $projection.Personnel = _PersonWorkAgrmtOrglDetails.PersonWorkAgreement
                                                                                    and _PersonWorkAgrmtOrglDetails.StartDate <= $session.system_date
                                                                                    and _PersonWorkAgrmtOrglDetails.EndDate >= $session.system_date
{
    key SDDocument,
    
    @ObjectModel.foreignKey.association: '_PartnerFunction'
    key Partner.PartnerFunction as PartnerFunction,
     
     Personnel,
     
     @Consumption.hidden: true
     @UI.hidden: true
     Employment.Person,
    
     _Employee._BusinessUser.AcademicTitle,
     _Employee.PersonFullName as EmployeeFullName,
     
     _PersonWorkAgrmtOrglDetails._PersonWorkAgrmtJobText[1: Language=$session.system_language].JobName,
     _PersonWorkAgrmtOrglDetails._CompanyCode.CompanyCodeName,

      _ImageURL.WorkforcePersonImageURL as EmployeeImageURL,
      
      _Employee._WorkplaceAddress.DefaultEmailAddress,
      _Employee._WorkplaceAddress.NormalizedPhoneNumber,
      _Employee._WorkplaceAddress.MblNormalizedPhoneNumber,

      // For Access control

      @Consumption.hidden: true
      @UI.hidden: true
       _Employee.AuthorizationGroup,
      
      @Consumption.hidden: true
      @UI.hidden: true
       _Employee.IsBusinessPurposeCompleted,
      
      //Association

      _PartnerFunction
}
where _PartnerFunction.SDDocumentPartnerType='PE'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSUSER",
"I_COMPANYCODE",
"I_PARTNERFUNCTION",
"I_PERSONWORKAGREEMENT_1",
"I_PERSONWORKAGRMTJOBTEXT",
"I_PERSONWORKAGRMTORGLDETAILS",
"I_SDDOCUMENTPARTNER",
"I_WORKFORCEPERSON",
"I_WORKFORCEPERSONIMAGEURL",
"I_WORKPLACEADDRESS"
],
"ASSOCIATED":
[
"I_PARTNERFUNCTION",
"I_PERSONWORKAGRMTORGLDETAILS",
"I_WORKFORCEPERSON",
"I_WORKFORCEPERSONIMAGEURL"
],
"BASE":
[
"I_SDDOCUMENTPARTNER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/