C_InsurClmBPQuickView

@AbapCatalog.sqlViewName: 'CICLBPQUICKVIEW'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Geschäftspartner für Fallauskunft'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@Metadata.allowExtensions: true
@ObjectModel.usageType: {
    dataClass: #MIXED,
    sizeCategory: #L,
    serviceQuality: #D
}
@ObjectModel.representativeKey: 'BusinessPartner'

define view C_InsurClmBPQuickView
  as select from I_BusinessPartner as _IBP
  association [0..*] to I_BPGenderValueHelpText as _BPGenderText on $projection.GenderCodeName = _BPGenderText.GenderCodeName
  association [0..*] to I_InsurClmClaimOverview as _Claim        on $projection.BusinessPartner = _Claim.InsurancePolicyholder
{
      @UI.facet: [
      {
        purpose:    #QUICK_VIEW,
        type:       #FIELDGROUP_REFERENCE,
        targetQualifier: 'QuickView'
      }]
      @Consumption.filter.hidden: true
  key BusinessPartner,
      @Consumption.filter.hidden: true
      BusinessPartnerCategory,
      @Consumption.filter.hidden: true
      BusinessPartnerName,
      @Consumption.filter.hidden: true
      LastName,
      @Consumption.filter.hidden: true
      FirstName,

      @UI.fieldGroup: [{ label: 'Geburtsdatum' ,position: 10 , qualifier: 'QuickView', importance: #HIGH }]
      // label: 'Date of Birth'

      @Consumption.filter.hidden: true
      @Semantics.contact.birthDate: true
      BirthDate,

      @Consumption.filter.hidden: true
      @Semantics.telephone : {type: [#CELL]}
      @UI.fieldGroup: [{ label: 'Telefonnummer' , position: 40 , importance: #HIGH,qualifier: 'QuickView'}]
      //  label: 'Phone Number'

      _CurrentDefaultAddress._Address._DefaultPhoneNumber.PhoneNumber,

      //       concat_with_space(_CurrentDefaultAddress._Address._DefaultPhoneNumber.PhoneNumber, PersonNumber, 1) as PhoneNumber,

      //      @Semantics.telephone : {type: [#HOME]}

      //      @UI.fieldGroup: [{label: 'Phone Number' , position: 60 , importance: #HIGH,qualifier: 'QuickView'}]

      //      PersonNumber,

      @UI.fieldGroup: [{ label: 'E-Mail', position: 30 , importance: #HIGH,qualifier: 'QuickView'}]
      //   label: 'Email'

      @Consumption.filter.hidden: true
      @Semantics.eMail.address: true
      @Semantics.eMail.type: [#PREF]
      _CurrentDefaultAddress._Address._DefaultEmailAddress.EmailAddress,
      @Consumption.filter.hidden: true
      IsFemale,
      @Consumption.filter.hidden: true
      IsMale,
      @Consumption.filter.hidden: true
      IsSexUnknown,

      @UI.fieldGroup: [{ label: 'Geschlecht'  , position: 20 , importance: #HIGH,qualifier: 'QuickView'}]
      @Consumption.filter.hidden: true
      //  label: 'Gender'

      //@ObjectModel.foreignKey.association: '_GenderValueHelp'

      //@ObjectModel.text.association: '_BPGenderText'

      _BPGenderText[Language = $session.system_language].GenderCodeNameText,
      @Consumption.filter.hidden: true
      _IBP.GenderCodeName,

      @UI.fieldGroup: [{ label: 'Adresse' , position: 50 , importance: #HIGH,qualifier: 'QuickView'}]
      @Consumption.filter.hidden: true
      //  label: 'Address'

      concat_with_space(
        concat_with_space(
          concat( concat_with_space( _CurrentDefaultAddress._Address.StreetName , _CurrentDefaultAddress._Address.HouseNumber, 1), ','),
          concat( concat_with_space(_CurrentDefaultAddress._Address.PostalCode,  _CurrentDefaultAddress._Address.CityName, 1), ','),
          1
        ),
        _CurrentDefaultAddress._Address.Country,
        1
      ) as InsurClmLocationText,
       @Consumption.filter.hidden: true
          case
          when BusinessPartnerCategory = '1'
              then concat(substring (FirstName,1,1), substring (LastName,1,1))
          when BusinessPartnerCategory = '2'
               then concat(substring (OrganizationBPName1,1,1), substring (OrganizationBPName2,1,1))
          when BusinessPartnerCategory = '3'
               then concat(substring (GroupBusinessPartnerName1,1,1), substring (GroupBusinessPartnerName1,1,1))
           else ''
        end                                                                                  as BusinessPartnerInitialsName,
   
      _BPGenderText,
      _DefaultAddress,
      _Claim
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_ADDRESSEMAILADDRESS",
"I_ADDRESSPHONENUMBER",
"I_BPCURRENTDEFAULTADDRESS",
"I_BPGENDERVALUEHELPTEXT",
"I_BUSINESSPARTNER"
],
"ASSOCIATED":
[
"I_BPGENDERVALUEHELPTEXT",
"I_BUSINESSPARTNERDEFAULTADDR",
"I_INSURCLMCLAIMOVERVIEW"
],
"BASE":
[
"I_BUSINESSPARTNER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/