C_InspLotStatus

@AbapCatalog.sqlViewName: 'CINSPLOTSTATUS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Status of Inspection Lot Object Page'
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: {
    dataClass: #MIXED,
    sizeCategory: #L, //expected number of rows < 10.000.000

    serviceQuality: #D 
}
@Metadata.ignorePropagatedAnnotations: true
define view C_InspLotStatus 
as select distinct from I_StatusObjectActiveStatus as _statusObject
    //Retrieve inspection lot number

    inner join I_InspectionLot as _InspLot 
       on _InspLot.StatusObject = _statusObject.StatusObject
    //Retrieve system status short name and description      

    left outer join  I_StatusCodeText as _StatusCodeText 
        on  _statusObject.StatusCode = _StatusCodeText.StatusCode
        and _statusObject.StatusProfile= _StatusCodeText.StatusProfile
        and _StatusCodeText.Language = $session.system_language
    //Retrieve user status short name and description   

    left outer join I_UserStatusText as _UserStatusText
        on  _statusObject.StatusProfile = _UserStatusText.StatusProfile
        and _statusObject.StatusCode    = _UserStatusText.UserStatus
        and _UserStatusText.Language    = $session.system_language
{
    key _InspLot.InspectionLot,
    key _statusObject.StatusCode,
    _statusObject._StatusCode._StatusCodeText[1:Language=$session.system_language].IsUserStatus,
    case _statusObject._StatusCode._StatusCodeText[1:Language=$session.system_language].IsUserStatus
      when 'X' then _UserStatusText.UserStatusShortName 
      else  _StatusCodeText.StatusShortName
      end as StatusShortName,
    case _statusObject._StatusCode._StatusCodeText[1:Language=$session.system_language].IsUserStatus
      when 'X' then _UserStatusText.UserStatusName 
      else _StatusCodeText.StatusName
      end as StatusName,
    @Consumption.hidden: true     //for DCL

    _InspLot.Plant,
    @Consumption.hidden: true     //for DCL

    _InspLot.InspectionLotType,
    @Consumption.hidden: true     //for DCL

    _InspLot.MatlQualityAuthorizationGroup     
     
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSPECTIONLOT",
"I_STATUSCODE",
"I_STATUSCODETEXT",
"I_STATUSOBJECTACTIVESTATUS",
"I_USERSTATUSTEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/