C_InquiryRelatedDocsFFS

DDL: C_INQUIRYRELATEDDOCSFFS SQL: CINQYRLTDOCS Type: view CONSUMPTION

Related Documents for Inquiry Factsheet

C_InquiryRelatedDocsFFS is a Consumption CDS View that provides data about "Related Documents for Inquiry Factsheet" in SAP S/4HANA. It reads from 1 data source (I_SDDocumentProcessFlow) and exposes 15 fields with key fields SubsequentDocument, PrecedingDocument, DocRelationshipUUID. It has 1 association to related views.

1 data source(s) 15 fields

Data Sources (1)

SourceAliasJoin Type
I_SDDocumentProcessFlow SO from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_SalesDocument _RelatedSalesDoc $projection.SubsequentDocument = _RelatedSalesDoc.SalesDocument

Annotations (14)

NameValueLevelField
AbapCatalog.sqlViewName CINQYRLTDOCS view
ClientHandling.algorithm #SESSION_VARIABLE view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Related Documents for Inquiry Factsheet view
VDM.viewType #CONSUMPTION view
Search.searchable true view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
UI.headerInfo.typeName Related Sales Document view
UI.headerInfo.typeNamePlural Related Sales Documents view
UI.headerInfo.title.type #STANDARD view
UI.headerInfo.title.value SalesDocument view

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY SubsequentDocument I_SDDocumentProcessFlow SubsequentDocument
KEY PrecedingDocument I_SDDocumentProcessFlow PrecedingDocument
KEY DocRelationshipUUID I_SDDocumentProcessFlow DocRelationshipUUID
SalesDocument I_SDDocumentProcessFlow SubsequentDocument
SDDocumentCategory _RelatedSalesDoc SDDocumentCategory
SalesDocumentType _RelatedSalesDoc SalesDocumentType
SalesDocumentDate _RelatedSalesDoc SalesDocumentDate
Status
TotalNetAmount _RelatedSalesDoc TotalNetAmount
TransactionCurrency _RelatedSalesDoc TransactionCurrency
_SDDocumentCategory _RelatedSalesDoc _SDDocumentCategory
_SalesDocumentType _RelatedSalesDoc _SalesDocumentType
DistributionChannel _RelatedSalesDoc DistributionChannel
SalesOrganization _RelatedSalesDoc SalesOrganization
OrganizationDivision _RelatedSalesDoc OrganizationDivision 
@AbapCatalog.sqlViewName: 'CINQYRLTDOCS'
@ClientHandling.algorithm:#SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Related Documents for Inquiry Factsheet'
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@ObjectModel: {
   semanticKey: ['SalesDocument'],
   usageType.dataClass: #MIXED,
   usageType.serviceQuality: #C,
   usageType.sizeCategory: #XL
}

@UI.headerInfo: {
  typeName:       'Related Sales Document',
  typeNamePlural: 'Related Sales Documents',
  title:          { type: #STANDARD, value: 'SalesDocument' }
}

define view C_InquiryRelatedDocsFFS

  as select from I_SDDocumentProcessFlow as SO

  association [0..1] to I_SalesDocument as _RelatedSalesDoc on $projection.SubsequentDocument = _RelatedSalesDoc.SalesDocument
  
{

      @UI.hidden: true
  key SO.SubsequentDocument,
      @UI.hidden: true
  key SO.PrecedingDocument,
      @UI.hidden: true
  key SO.DocRelationshipUUID,
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @UI: {
      lineItem: [{position: 10, importance: #HIGH, type: #STANDARD, label:'Sales Document'}]
          }
     @Consumption.semanticObject: 'SalesOrder'
     SO.SubsequentDocument as SalesDocument,
     
      /*@UI: {
        lineItem: [{position:20, importance: #HIGH, type: #STANDARD, label: 'Sales Document Category'}]
      }*/
      @ObjectModel.foreignKey.association: '_SDDocumentCategory'
      _RelatedSalesDoc.SDDocumentCategory,
      
      @UI: {
        lineItem: [{position:30, importance: #HIGH, type: #STANDARD}]
      }
      @ObjectModel.foreignKey.association: '_SalesDocumentType'
      _RelatedSalesDoc.SalesDocumentType,
      
      @UI: {
      lineItem: [{position: 40, importance: #HIGH, type: #STANDARD}]
          }
      _RelatedSalesDoc.SalesDocumentDate,

      @UI: {
      lineItem: [{position: 50, importance: #HIGH, type: #STANDARD, label:'Status'}]
          }
      _RelatedSalesDoc._OverallSDProcessStatus._Text[1: Language=$session.system_language ].OverallSDProcessStatusDesc as Status,

      @DefaultAggregation: #NONE
      @UI: {
      lineItem: [{position: 60, importance: #HIGH, type: #STANDARD}]
          }
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      _RelatedSalesDoc.TotalNetAmount,
      @Semantics.currencyCode: true
      _RelatedSalesDoc.TransactionCurrency,
      
     // Associations

     _RelatedSalesDoc._SDDocumentCategory,
     _RelatedSalesDoc._SalesDocumentType,
     
     //For Access Control

     @Consumption.hidden: true
     @UI.hidden: true
     _RelatedSalesDoc.DistributionChannel,
     
     @Consumption.hidden: true
     @UI.hidden: true
     _RelatedSalesDoc.SalesOrganization,
     
     @Consumption.hidden: true
     @UI.hidden: true
     _RelatedSalesDoc.OrganizationDivision
     
}
where
      SO.PrecedingDocumentCategory = 'A'
  and SO.SubsequentDocumentItem    = '000000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_OVERALLSDPROCESSSTATUS",
"I_OVERALLSDPROCESSSTATUSTEXT",
"I_SALESDOCUMENT",
"I_SDDOCUMENTPROCESSFLOW"
],
"ASSOCIATED":
[
"I_SALESDOCUMENT",
"I_SALESDOCUMENTTYPE",
"I_SDDOCUMENTCATEGORY"
],
"BASE":
[
"I_SALESDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More