C_InhRepairOpenSrvcConf

@EndUserText.label: 'In-House Repair with Open Confirmations'
@VDM: {
  viewType: #CONSUMPTION
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [ '_User' ]
}
@ObjectModel: {
  semanticKey: ['ServiceConfirmation'],
  usageType: {serviceQuality: #C, 
              sizeCategory  : #XL, 
              dataClass     : #MIXED}
}
@Metadata: {
  allowExtensions: true,
  ignorePropagatedAnnotations: true
}
@ClientHandling: {
  algorithm: #SESSION_VARIABLE
}
@AbapCatalog: {
  sqlViewName: 'CINHREPROPNCONF',
  compiler.compareFilter: true,
  preserveKey: true
}

define view C_InhRepairOpenSrvcConf
  as select from I_ServiceDocumentEnhcd
  association [0..1] to I_User as _User on _User.UserID = $projection.ServiceDocumentCreatedByUser
{
  key cast( ServiceDocument as crms4_repa_repair_confmtin_lbl preserving type )  as ServiceConfirmation,
  key ServiceObjectType,
      ReferenceInHouseRepair                                                     as InHouseRepair,
      ReferenceInHouseRepairItem                                                 as InHouseRepairItem,

      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocNetAmount,
      @Semantics.currencyCode:true
      TransactionCurrency,
      @Consumption.hidden: true
      ServiceDocumentCreatedByUser,
      cast( _User.UserDescription as crms4_created_by_user_lbl preserving type ) as UserDescription,


      // required 'technical' fields for access control (DCL)

      @Consumption.hidden: true
      ResponsibleEmployee                                                        as RespEmployeeBusinessPartnerId,
      @Consumption.hidden: true
      ServiceDocumentType,
      @Consumption.hidden: true
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,
      @Consumption.hidden: true
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOffice,
      @Consumption.hidden: true
      @ObjectModel.foreignKey.association: '_SalesGroup'
      SalesGroup,
      @Consumption.hidden: true
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      @Consumption.hidden: true
      @ObjectModel.foreignKey.association: '_Division'
      Division,
      @Consumption.hidden: true
      //      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit'

      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
      SalesOrganizationOrgUnitID,

      @Consumption.hidden: true
      //      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit'

      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
      SalesOfficeOrgUnitID,

      @Consumption.hidden: true
      //      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit'

      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
      SalesGroupOrgUnitID,
      @Consumption.hidden: true
      ServiceOrganization,

      _SalesOrganization,
      _SalesOffice,
      _SalesGroup,
      _ServiceDocumentType,
      _DistributionChannel,
      _Division,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesOrganizationOrgUnit_2'
      _SalesOrganizationOrgUnit,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesOfficeOrgUnit_2'
      _SalesOfficeOrgUnit,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesGroupOrgUnit_2'
      _SalesGroupOrgUnit,

      _SalesOrganizationOrgUnit_2,
      _SalesOfficeOrgUnit_2,
      _SalesGroupOrgUnit_2,
      // _RespEmployee,


      @Consumption.filter.hidden: true
      _User
}
where
      ServiceObjectType          = 'BUS2000117'
  and ServiceDocumentIsQuotation = ' '
  and RefInHouseRepairIsExisting = 'X'
  and ServiceDocumentIsOpen      = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTENHCD",
"I_USER"
],
"ASSOCIATED":
[
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_SALESGROUP",
"I_SALESOFFICE",
"I_SALESORGANIZATION",
"I_SALESORGANIZATIONUNIT",
"I_SERVICEDOCUMENTTYPE",
"I_SRVCMGMTORGANIZATIONUNIT",
"I_USER"
],
"BASE":
[
"I_SERVICEDOCUMENTENHCD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/