C_IT_TaxReturnBoxCube

@AbapCatalog.sqlViewName: 'CITTAXRETURNBOXC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Tax Items for Italy'
@VDM.viewType: #CONSUMPTION
@Analytics: { dataCategory: #CUBE }
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.allowExtensions: true
@AbapCatalog.preserveKey: true


define view C_IT_TaxReturnBoxCube 
   with parameters
    P_StatryRptgEntity      : srf_reporting_entity,
    P_StatryRptCategory     : srf_rep_cat_id,
    P_StatryRptRunID        : srf_report_run_id,
    P_ReportingCountry      : land1

                                            as select from I_StRpTaxReturnBoxCube(
                                                                                  P_TaxIsDeferredRelevant: 'N',    
                                                                                  P_TaxIsMossRelevant   :  'N',     
                                                                                  P_StatryRptgEntity     : $parameters.P_StatryRptgEntity , 
                                                                                  P_StatryRptCategory    : $parameters.P_StatryRptCategory,
                                                                                  P_StatryRptRunID       : $parameters.P_StatryRptRunID,
                                                                                  P_ReportingCountry     : $parameters.P_ReportingCountry,
                                                                                  P_TaxBoxConfiguration  : '1'                                               
                                                                                  )
                                                               
{
    
  key CompanyCode,
  key AccountingDocument,
  key FiscalYear,
  key TaxItem,
  key TaxCode,
  key TransactionTypeDetermination,
// Because TDT Customizing is a character field, in non-TDT in V_T007L/K is a  numc field      

  key case TaxBox 
      when '1'  then '01'      
      when '2'  then '02'
      when '3'  then '03'
      when '4'  then '04'                   
      when '5'  then '05'
      when '6'  then '06'
      when '7'  then '07'
      when '8'  then '08'
      when '9'  then '09'                               
      else TaxBox   
      end as TaxBox,       
  key Country,
  key TaxDeclnAmountType,
  key ValidFrom,
  key UnifiedTaxBoxStructureType,
  key StatryRptgEntity,
  key StatryRptCategory,
  key StatryRptRunID,    
    
      TaxItemGroupingVersion,
      TaxBoxStructureType, 
      ValidTo,
      DebitCreditCode,
      TaxCalculationProcedure,
      @DefaultAggregation:#MIN
      TaxRate,     
      TaxRateValidityStartDate,      
      GLAccount,
      TaxItemGroup,
      ReferenceDocumentType,
      AccountingDocumentType,
      PostingDate,
      DocumentDate,
      TaxReportingDate,
      ReportingDate,
      cast(substring( ReportingDate, 5, 2) as fiit_period ) as LegalReportingPeriod,         
      FiscalPeriod, 
      CompanyCodeCountry,
      ReportingCountry,
      TaxReturnCountry,
      @Semantics.currencyCode:true
      CompanyCodeCurrency,
      @Semantics.currencyCode:true
      DocumentCurrency,
      @Semantics.currencyCode:true
      ReportingCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      AmountInReportingCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      TaxBaseAmountInRptgCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      TaxAmountInRptgCrcy,     
      @DefaultAggregation:#SUM                                  
      @Semantics.amount.currencyCode: 'ReportingCurrency'       
      NonDeductibleInputTaxAmount,                           
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TaxBaseAmountInCoCodeCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TaxAmountInCoCodeCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      TaxBaseAmountInTransCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      TaxAmount,
      TaxType,     
      TargetTaxCode,
      CAReconciliationKey,
      StatryRptRun,
      TaxTypeName,
      TaxIsNotDeductible,
      TaxBoxStructure,
      TaxBoxStructureName,
      TaxBoxName,
      TaxBoxCondition,
      TaxGroup,
     
      _TaxTypeText
            
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_STRPTAXRETURNBOXCUBE"
],
"ASSOCIATED":
[
"I_TAXTYPETEXT"
],
"BASE":
[
"I_STRPTAXRETURNBOXCUBE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/